path: root/npc/000-2-3/elmo.txt

// Evol scripts.
// Author:
//    Reid
// Description:
//    Elmo's second dialog.

000-2-3.gat,27,27,0,1	script	Elmo	309;5,{

    set @q, getq(ShipQuests_ArpanMoney);
    if (@q == 1) goto l_GotMoney;

    mesn;
    mesq l("Hey you, sorry for leaving your room so quickly, I needed to... speak with the captain about... The reserve. You know, now that we got a new mouth to feed, we need to check what we have.");
    next;
    mesq l("So, how is it going? Did you meet any other crew members yet?");
    next;

    menu
        l("Yes, Arpan gave me these clothes."), l_OhGood,
        l("No."), -;

    mes "";
    mesn;
    mesq l("You should go see them.");
    next;
    mesq l("You still got a few days before we arrive at the port, maybe you can learn something from them?");

    close;

l_OhGood:
    mes "";
    mesn;
    mesq l("Oh good! Did he give you your money back as well?");
    next;

    menu
        l("Yes he did."), l_OhHeDid,
        l("He told me nothing about that."), -;

    mes "";
    mesn;
    mesq l("Hehe, sometimes he gets his head in the clouds, You should go ask him about that.");

    close;

l_OhHeDid:
    mes "";
    mesn;
    mesq l("Ok, be patient a little while longer, in the next few days we will arrive at the port of Artis...");

    close;

l_GotMoney:
    mesn;
    mesq l("Be patient a little while longer, in the next few days we will arrive at the port of Artis...");
    next;
    mesq l("If you feel bored or like turning in circles, you may want to talk with the other sailors around here to get some tasks.");
    next;
    mesq l("From what I know, Gugli, my brother, needs the help of as many people as possible to collect all of the new things found on the island.");
    next;
    mesq l("Other than that, I don't know much about what else is going on, so directly asking the Cap'tain about it could be a good idea.");

    close;

}