path: root/npc/006-2-5/dusk.txt

// TMW-2 scripts.
// Original Authors: Hal9000 & Qwerty Dragon
// TMW-2 Authors:
//   +seeds
//   dangerduck
// Description:
//   Piou captain who gives information about the war, and the piou queen.

006-2-5,36,25,0	script	Captain Dusk	NPC_PIOU_KNIGHT_R,{
	function duskHello;
	function duskAboutQueen;
	function duskAboutWar;

	switch (getq(PiouQuest_Pouf)) {
	case 0:
	case 1:
	case 2:
		switch (rand2(3)) {
		case 0:
			npctalk3 l("Don't think you'll sneak anything by me. I'm watching you...");
			break;
		case 1:
			npctalk3 l("I don't tolerate a piou, or %s, who is afraid of hard work.", get_race());
			break;
		default:
			npctalk3 l("Best steer clear of the Princess, %s. It won't go well if you upset her.", strcharinfo(0));
			break;
		}
		break;
	default:
		duskHello();
		break;
	}
	close;

function duskHello {
	mesn;
	mesq l("Welcome to the Order of the Piou Knights, %s.", strcharinfo(0));
	next;
	select
		l("Where is the Piou Queen?"),
		l("How is the war going?"),
		l("I just wanted to say hi.");
	mes "";
	switch (@menu) {
	case 1:
		duskAboutQueen();
		break;
	case 2:
		duskAboutWar();
		break;
	case 3:
		close;
		break;
	}
	return;
}

function duskAboutQueen {
	mesn;
	mesq l("Queen +seeds of Piou Isles is busy coordinating war efforts at the front.");
	next;
	mesn;
	mesq l("She's a fierce piou, leading our troops into the heart of each battle. I admire her bravery.");
	next;
	mesn;
	mesq l("Princess Pouf has been given leadership until our Queen returns. Should Queen +seeds perish, Princess Pouf will take the crown.");
	next;
	mesn;
	mesq l("Fight bravely and well, %s, and perhaps our Queen will survive to return to her beloved isles.", strcharinfo(0));
	return;
}

function duskAboutWar {
	mesn;
	mesq l("So far neither the Duck Side or the Piou Knights have gained the upper hand in the war.");
	next;
	mesn;
	mesq l("However, our mages have recently sensed something dark stirring.");
	next;
	mesn;
	mesq l("I fear something terrible is rising, and I do not know if we can weather the coming storm.");
	next;
	mesc l("The captain falls quiet, and appears to be lost in thought.");
	next;
	return;
}

OnInit:
	.sex = G_OTHER;
	.distance = 4;
	end;
}