path: root/npc/commands/motd.txt

// TMW2 Script
function	script	displayMOTD	{
    .@size = getvariableofnpc(.size, "@motd");

    // generic MOTD
    for (.@i = 0; .@i < .@size; ++.@i) {
        dispbottom $MOTD_Messages$[.@i];
    }

    return;
}

function	script	MOTDConfig	{

    function toggleMOTD {
        $MOTD_Disabled = !($MOTD_Disabled);
            logmes "MOTD modified: toogled: enable/disable", LOGMES_ATCOMMAND;
    }

    function addNewLine {
        clear;
        mes l("Please enter the new line.");
        input .@s$;
        .@s$ = strip(.@s$);
        if (.@s$ != "") {
            .@size = getvariableofnpc(.size, "@motd");
            $MOTD_Messages$[.@size] = .@s$;
            set getvariableofnpc(.size, "@motd"), getarraysize($MOTD_Messages$);
            logmes "MOTD modified: line added", LOGMES_ATCOMMAND;
        }
    }

    function modifyLine {

        function removeLine {
            .@l = getarg(0);
            deletearray $MOTD_Messages$[.@l], 1; // remove and shift
            mes l("Line @@ has been removed.", .@l);
            set getvariableofnpc(.size, "@motd"), getarraysize($MOTD_Messages$);
            logmes "MOTD modified: line removed", LOGMES_ATCOMMAND;
        }

        function moveUp {
            .@l = getarg(0);
            .@top$ = $MOTD_Messages$[.@l - 1];
            $MOTD_Messages$[.@l - 1] = $MOTD_Messages$[.@l];
            $MOTD_Messages$[.@l] = .@top$;
        }

        function moveDown {
            .@l = getarg(0);
            .@bottom$ = $MOTD_Messages$[.@l + 1];
            $MOTD_Messages$[.@l + 1] = $MOTD_Messages$[.@l];
            $MOTD_Messages$[.@l] = .@bottom$;
        }

        function editLine {
            .@l = getarg(0);
            clear;
            mes l("Old line:");
            mes "---";
            mes $MOTD_Messages$[.@l];
            mes "---";
            mes "";
            mes l("Enter new line:");
            next;
            input .@s$;
            .@s$ = strip(.@s$);
            if (.@s$ != "") {
                $MOTD_Messages$[.@l] = .@s$;
                logmes "MOTD modified: line edited", LOGMES_ATCOMMAND;
            }
        }

        .@max = (getarg(0) - 1);

        do
        {
            mes l("Enter line number:");
            next;
            input .@n;
            if ($MOTD_Messages$[.@n] != "") {
                clear;
                mes l("line @@: "+"##0"+$MOTD_Messages$[.@n], .@n);
                next;
                select
                    menuimage("actions/back", l("Modify another line")),
                    menuimage("actions/edit", l("Modify this line")),
                    menuimage("actions/remove", l("Remove this line")),
                    rif(.@n > 0, menuimage("actions/raise", l("Move this line up"))),
                    rif(.@n < .@max, menuimage("actions/lower", l("Move this line down"))),
                    menuimage("actions/home", l("Return to main menu"));

                switch (@menu) {
                    case 2: editLine .@n; return;
                    case 3: removeLine .@n; return;
                    case 4: moveUp .@n; return;
                    case 5: moveDown .@n; return;
                    case 6: return;
                }
            }
        } while (1);
    }

    do
    {
        clear;
        setnpcdialogtitle l("MOTD Config");
        mes l("This menu allows you to modify the generic message that is sent to players when they log in.");
        mes "";

        mes "---";
        .@size = getvariableofnpc(.size, "@motd");
        for (.@i = 0; .@i < .@size; ++.@i) {
            mes l("line @@: "+"##0"+$MOTD_Messages$[.@i], .@i);
        }
        if (.@size == 0) {
            mes "(" + l("no active MOTD") + ")";
        }
        mes "---";
        .@d = $MOTD_Disabled;
        mes l("Enabled: @@", (.@d ? l("no") : l("yes")));
        next;

        select
            menuimage("actions/toggle", (.@d ? l("Enable") : l("Disable"))),
            menuimage("actions/add", l("Add a new line")),
            rif(.@size, menuimage("actions/manage", l("Modify, move, or remove a line"))),
            rif(.@size, menuimage("actions/test", l("Test MOTD"))),
            rif(getarg(0,0), menuimage("actions/home", l("Return to Super Menu"))),
            rif(!getarg(0,0), menuimage("actions/home", l("Close")));

        switch (@menu) {
            case 1: toggleMOTD; break;
            case 2: addNewLine; break;
            case 3: modifyLine .@size; break;
            case 4: displayMOTD; break;
            case 6: close; break;
            default: return;
        }
    } while (1);
}



-	script	@motd	32767,{
    end;

OnCall:
    if (!is_master()) {
        end;
    }

    MOTDConfig;
    closedialog;
    end;

OnClock0003:
    // Reset TMW2 Login Bonus on February and April
    if (!$@TMW2_357GDQST) {
        if (gettime(6) == FEBRUARY || gettime(6) == APRIL) {
            DelAccRegFromEveryPlayer("#TMW2_LOGINBONUS");
            $@TMW2_357GDQST=1;
        }
    }
    end;

OnInit:
    /*
    .login_ref=gettime(5);
    .daylength=(60*60*24);
    */
    .size = getarraysize($MOTD_Messages$);
    bindatcmd "motd", "@motd::OnCall", 99, 99, 1;
}




function	script	MOTDHandler	{
    // Handle events
    if ($@GM_EVENT)
        dispbottom l("An event is happening at Aeros! Hurry up!");
    if ($EVENT$ != "")
        dispbottom l("It's @@ (day)!", $EVENT$);

    // Handle MOTD
    if (!$MOTD_Disabled)
        displayMOTD;
    if (debug)
        dispbottom "##7<<##B @@help://test-server|" + col(l("This is the test server."),6) + "@@ ##7>>";
    return;
}