path: root/npc/020-7-1/ensio.txt

// TMW2 scripts.
// Authors:
//    Jesusalva
//    TMW Org.
// Description:
//    Responsible for recovering the lost pages (SpellBookPage)
//    helperBookpages*
//
// NivalisQuest_BlueSagePagefinder STRUCTURE
//  FIELD 1:
//      MAIN STATE
//  FIELD 2:
//      nº of pages found (0~31)
//  FIELD 3:
//      nº of duplicates found (for randomness control - capped at 60)

020-7-1,36,39,4	script	Ensio	NPC_BLUESAGEWORKER_MB,{
    function askQuestion;
    function helpLogic;

    .@qt=getq2(NivalisQuest_BlueSagePagefinder);
    mesn;
    if (.@qt == 31)
        mesq l("We'd never be able to recover our books so quickly without your help. Thanks!");
    else if (.@qt >= 27)
        mesq l("There are only a few pages missing.");
    else if (.@qt >= 19)
        mesq l("Wow, you already found quite a lot of bookpages. Please keep it up!");
    else if (.@qt >= 9)
        mesq l("Thanks for the pages you brought. There are still some missing.");
    else if (.@qt)
        mesq l("So many bookpages are still missing...");
    else
        mesc l("*sigh*");
    if (getq(NivalisQuest_BlueSagePagefinder))
        close;

    next;
    mesn;
    mesq l("Hello. Did you come here to see the library? There isn't much left... But we're working on recovering the books by collecting the ripped out book pages, sorting them and recreating the books.");
    askQuestion();
    close;

function askQuestion {
    do {
        .@q=getq(NivalisQuest_BlueSage);
        .@q2=getq2(NivalisQuest_BlueSage);
        .@q3=getq3(NivalisQuest_BlueSage);
        .@qs=BSQuestion(getq(NivalisQuest_BlueSage));
        .@qo=getq(NivalisQuest_BlueSagePagefinder);
        .@qt=getq2(NivalisQuest_BlueSagePagefinder);
        next;
        mes "";
        select
            rif(!.@qo, "Can I help you somehow?"),
            rif(.@qs & BS_QVISITOR, l("Do you know anything about the strange visitor?")),
            rif(.@qs & BS_QHELPER, l("What's your opinion of Peetu and his work?")),
            any(l("I need to leave."), l("See you."), l("Bye."), l("Good luck with that. See you in ten years or something."));
        mes "";
        switch (@menu) {
            case 1:
                mesn;
                mesq l("Oh, would you? That'd be great! You see, the slimes ate most of the books and it is difficult to retrieve the bookpages. If you feel capable of this task, you could go out to hunt the Blue and White Slimes, to get the @@ back from them.", getitemlink(SpellBookPage));
                if (!countitem(SpellBookPage))
                    break;
                helpLogic();
                break;
            case 2:
                mesn;
                mesq l("Visitor with a mask? Ah, I think I know who are you talking about. Black clothes and a golden mask. Rather strange guy.");
                next;
                mesn;
                mesq l("He was looking around in the library a while, and then came to ask about our research. He seemed to be particularly interested in our experiments with the slimes.");
                next;
                mesn;
                mesq l("Heh, I wonder what he would've said if he'd have visited us a little bit later. Mh, now that I think about it, the accident with the slimes happened just the night after he was here.");
                if (!(.@q2 & .bsId))
                    setq2 NivalisQuest_BlueSage, .@q2 | .bsId;
                break;
            case 3:
                mesn;
                mesq l("Oh, I can't really tell. I'm mostly working in the library, while he's very involved in the research.");
                break;
        }
    } while (@menu != 4);
    close;
}

function helpLogic {
    do {
        inventoryplace ThetaBook, 1;
        .@qt=getq2(NivalisQuest_BlueSagePagefinder);
        .@qx=getq3(NivalisQuest_BlueSagePagefinder);
        next;
        mesc l("Donate 1/@@ @@ to Ensio?", countitem(SpellBookPage), getitemlink(SpellBookPage));
        mes "";
        // break(); works, right?
        if (askyesno() == ASK_NO)
            break;

        delitem SpellBookPage, 1;
        if (rand(90 - .@qt) < 36 && .@qx < 60) {
            // Old Page
            setq3 NivalisQuest_BlueSagePagefinder, .@qx+1;
            mesn;
            mesq "%%f " + l("Mh, let me see. We already have a copy of this page, but it's helpful nevertheless. Thank you.");
        } else {
            // Original Page
            setq2 NivalisQuest_BlueSagePagefinder, .@qt+1;
            mesn;
            mesq "%%H " + l("Ah, wonderful! This is a page we haven't found yet!");
        }
        getexp 525, 32; // about 3% of exp table.

        // Maybe you've completed the requeriment?
        .@qt=getq2(NivalisQuest_BlueSagePagefinder);
        if (.@qt >= 31) {
            next;
            mesn;
            mesq l("Amazing. I think you found all the missing pages of which we didn't have a copy. This is a great help! I'll mention this to Nikolai.");
            next;
            mesn;
            mesq l("For now, please accept this @@ as my gratitude.", getitemlink(ThetaBook));
            getitem ThetaBook, 1;
            setq1 NivalisQuest_BlueSagePagefinder, 1;
            // Get any experience below the 60 failed pages threshold
            // But you'll get only ~1% per success because it took you no page
            // And you'll always get at least 1% bonus for... reasons.
            .@x=60-.@qx;
            .@x+=1;
            getexp 175*.@x, 10*.@x;
            break;
        }

    } while (countitem(SpellBookPage));
    return;
}

OnInit:
    .bsId=BS_NPC07;
    .sex=G_MALE;
    .distance=5;
    npcsit;
    end;
}