path: root/npc/003-1/well.txt

// TMW2 Script
// Author:
//    Saulc
//    Jesusalva

003-1,45,80,0	script	Well#003-1	NPC_NO_SPRITE,{
    if (countitem(Bucket) < 0) {
        mes col(l("This well is too deep and you don't have a bucket."), 9);
    } else {
        mes col(l("Hey you have a bucket! Too bad there are, you know, HOLES on it, so you can see."), 9);
        mes col(l("That's exactly why you can't use it to get water. Silly."), 9);
    }
    if (!Zeny)
        close;
    next;
    mes col(l("Throw a coin?"), 9);
   if (askyesno() != ASK_YES)
        close;

    mes "";
    Zeny=Zeny-1;
    mes col(l("You throw a coin on the well."), 9);
    next;

    .@n=rand(0, 10000);
    if (.@n <= 10) {
        getitem StrangeCoin, 1;
        mes l("##9Hey wait... Your coin turned on a @@!", getitemlink(StrangeCoin));
    } else if (.@n <= 50) {
        getitem CasinoCoins, 1;
        mes l("##9Hey wait... Your coin turned on a @@!", getitemlink(CasinoCoins));
    } else if (.@n <= 100) {
        Zeny=Zeny+2;
        mes col(l("Hey wait... You found 2 GP!"), 9);
    } else if (.@n <= 250) {
        percentheal 100, 100;
        mes col(l("Hey wait... You're enveloped by a bright light and fully healed!"), 9);
    } else if (.@n <= 300) {
        getexp rand(1,BaseLevel), rand(1,BaseLevel);
        mes col(l("Hey wait... You're enveloped by a bright light and gain experience!"), 9);
    } else if (.@n > 9900) {
        mes col(l("Hey wait... A monster!! Run for your life!!"), 9);
        getmapxy(.@m$, .@x, .@y, 0);
	    .@mobGID = monster(.@m$, .@x, .@y, "Croc", Croc, 1);
	    unitattack(.@mobGID, getcharid(CHAR_ID_ACCOUNT)); // Order the summoned monster to engage!!
    } else if (.@n > 9850) {
        mes col(l("Hey wait... A monster!! Run for your life!!"), 9);
        getmapxy(.@m$, .@x, .@y, 0);
	    .@mobGID = monster(.@m$, .@x, .@y, "Blub", Blub, 1);
	    unitattack(.@mobGID, getcharid(CHAR_ID_ACCOUNT)); // Order the summoned monster to engage!!
    } else if (.@n > 9800) {
        mes col(l("Hey wait... A monster!! Run for your life!!"), 9);
        getmapxy(.@m$, .@x, .@y, 0);
	    .@mobGID = monster(.@m$, .@x, .@y, "Red Scorpion", RedScorpion, 1);
	    unitattack(.@mobGID, getcharid(CHAR_ID_ACCOUNT)); // Order the summoned monster to engage!!
    } else if (.@n > 9700) {
        mes col(l("Hey wait... A monster!! Run for your life!!"), 9);
        getmapxy(.@m$, .@x, .@y, 0);
	    .@mobGID = monster(.@m$, .@x, .@y, "Bat", Bat, 1);
	    unitattack(.@mobGID, getcharid(CHAR_ID_ACCOUNT)); // Order the summoned monster to engage!!
    } else {
        mes col(l("Nothing happens."), 9);
        next;
        mes col(l("What did you expected, anyway?"), 9);
    }
    close;

OnInit:
    .sex = G_OTHER;
    .distance = 3;
    end;
}