path: root/npc/020-1/well.txt

020-1,99,83,0	script	#Well	NPC400,{
    if(QL_WELL == 2) goto L_Finished;
    
    mes "...";
    menu
        "Throw something in the well.", L_Throw,
        "Leave it alone.", L_close;

L_Throw:
    mes "What do you want to throw?";
    
    setarray @response_list$, "Yuck! Who threw that on me?", "Ouch! Who's hurting me?", "White powder!? What's going on up there?", "It's raining in Nivalis?!";
    setarray @item_list$, "MaggotSlime", "RawLog", "PileOfAsh", "BottleOfWater";
    menu
        "Maggot slime", L_CheckItem,
        "A raw log", L_CheckItem,
        "Pile of ash", L_CheckItem,
        "Bottle of water", L_CheckItem,
        "Leave it alone", L_close;

L_CheckItem:
    @index = @menu - 1;
    @response$ = @response_list$[@index];
    @item$ = @item_list$[@index];
    
    mes @item$;
    
    if(countitem(@item$) == 0)
        goto L_MissingItem;
    delitem @item$, 1;
    
    if(@item$ == "BottleOfWater")
        getitem "EmptyBottle", 1;
    
    mes "[Mysterious voice inside the well]";
    mes "\"" + @response$ + "\"";
    next;
    menu
        "Who are you?", L_Who,
        "How did you get down there?", L_How,
        "Do you need help?", L_Help;

L_Who:
    @response$ = "I'll talk about who I am after leaving the well. ";
    goto L_GetHelp;

L_How:
    @response$ = "Well, someone pushed me into the well, I'm not sure who. ";
    goto L_GetHelp;

L_Help:
    @response$ = "I certainly can't get out on my own. ";
    goto L_GetHelp;

L_GetHelp:
    mes "[Mysterious voice inside the well]";
    mes "\"" + @response$ + "So if you can get some help for me... please do so!\"";
    QL_WELL = 1;
    
    cleararray @response_list$, "", 4;
    cleararray @item_list$, "", 4;
    @index = 0;
    @response$ = "";
    
    goto L_close;

L_MissingItem:
    mes "You can't throw something you don't have.";
    goto L_close;

L_Finished:
    mes "This is a well.";
    goto L_close;

L_close:
    close;
}

020-2,100,28,0	script	Miler	NPC100,{
    mes "[Miler]";
    mes "\"Hello!\"";
    
    if(QL_WELL != 1) goto L_close;
    menu
        "Hello.", L_close,
        "Hello, Can you help me?", L_Help;

L_Help:
    mes "[Miler]";
    mes "\"What's the problem?\"";
    menu "Someone fell into the well.", L_Next;

L_Next:
    mes "[Miler]";
    mes "\"Ho! I'll help him!\"";
    getexp (BaseLevel * 111), 0;
    QL_WELL = 2;
    goto L_close;

L_close:
    close;
}