path: root/npc/002-2/bakery.txt

002-2,21,22,0	script	Riskim	NPC148,{
    mes "[Riskim]";
    mes "";
    mes "\"Welcome to our bakery!\"";

    callfunc "KadiyaSubquestConsts";
    if ((@Q_kadiya_status == @Q_STATUS_WANTS_CHOCOCAKE)
        && (countitem ("MopoxCurePotion") > 0))
            goto L_lace_chococake;

    if ((@Q_kadiya_status == @Q_STATUS_WANTS_ORANGECUPCAKE)
        && (countitem ("MopoxCurePotion") > 0))
            goto L_lace_cupcake;

    mes "\"Would you mind bringing me ##B6 acorns##b please? I need them to make flour so I can bake some chocolate cakes. I will be so delicious!\"";
    next;
    mes "\"Uh... I mean... the cakes will be delicious...\" %%;";
    next;

    @dq_level = 15;
    @dq_cost = 3;
    @dq_count = 6;
    @dq_name$ = "Acorn";
    @dq_friendly_name$ = "acorns";
    @dq_money = 250;
    @dq_exp = 50;

    callfunc "DailyQuest";

    next;
    mes "\"Don't forget: our bakery is the best!\"";
    close;

L_lace_chococake:
    next;
    menu
        "Thanks! Let me have a look around...", L_End,
        "Can you put this potion into a Chocolate Cake?", L_Next,
        "Goodbye!", L_End;

L_Next:
    mes "[Riskim]";
    mes "";
    mes "You take the potion out and attempt to show it to Riskim, but he takes a step back.";
    mes "\"Oh! I remember that smell...\"";
    mes "\"Elanore's Mopox potion, right?  She made me drink that too...\"";
    mes "He chuckles.";
    mes "\"Yes. Well, you definitely want to hide that somehow.\"";
    next;
    mes "[Riskim]";
    mes "";
    mes "\"We'll need extra chocolate for that one. If you can give me ten pieces of chocolate, the Mopox potion, and a payment of 400 GP, I'll bake you a special Chocolate Cake that hides the taste.\"";
    next;
    menu
        "I will get them for you.", L_End,
        "Here you are!", L_Continue,
        "Maybe later.", L_End;

L_Continue:
    if (countitem("ChocolateBar") < 10)
        goto L_lacking_ingredients;
    if (countitem("MopoxCurePotion") < 1)
        goto L_lacking_ingredients;
    if (Zeny < 400)
        goto L_lacking_Zeny;
    delitem "MopoxCurePotion", 1;
    delitem "ChocolateBar", 10;
    getitem "LacedChocolateCake", 1;
    Zeny = Zeny - 400;

    mes "[Riskim]";
    mes "";
    mes "\"Please have a seat!\"";
    mes "You watch as Riskim melts the chocolate, stirs in the potion, and then glazes a cake with the mixture.";
    mes "\"It's a bit more chocolaty than your average chocolate cake, so it should help mask that awful taste.\"";
    next;
    mes "[Riskim]";
    mes "";
    mes "Riskim hands you the cake.";
    mes "\"Here you are! I hope this helps.\"";
    close;

L_lacking_Zeny:
    mes "[Riskim]";
    mes "";
    mes "\"I'm sorry, but I have to charge 400 GP. I've got to make a living somehow.\"";
    close;

L_lacking_ingredients:
    mes "[Riskim]";
    mes "";
    mes "\"Sorry, but I need both the ten Chocolate Bars and your potion for this. Please come back later when you have everything.\"";
    close;

L_lace_cupcake:
    next;
    menu
        "Thanks! Let me have a look around...", L_End,
        "Can mix a potion into an Orange Cupcake?", L_More,
        "Goodbye!", L_End;

L_More:
    mes "[Riskim]";
    mes "";
    mes "\"Orange Cupcakes? Oh dear... I'm sorry, but I have a very bad allergy to oranges.\"";
    next;
    mes "[Riskim]";
    mes "";
    mes "\"Perhaps the Chef at Dimond's Cove can help you. We get all of our cupcakes from him.\"";
    next;
    goto L_End;

L_End:
    close;
}

002-2,28,31,0	script	Sara	NPC108,{
    mes "[Sara]";
    mes "";
    mes "\"Hello!\"";
    mes "\"If you'd like to buy something, just ask Drabur.\"";
    mes "\"If you need something made-to-order, talk to Riskim.\"";
    close;
}

002-2,25,22,0	shop	Drabur	NPC112,736:100,737:125,738:150,739:150,513:15,519:50,534:45,527:150,508:10

002-2,21,28,0	script	Iormo	NPC160,{
    mes "[Iormo]";
    mes "";
    mes "\"The cake sure is good, but this room can get messy with all the flour.\"";
    close;
}

002-2,24,27,0	script	Rynoh	NPC159,{
    mes "[Rynoh]";
    mes "";
    mes "\"The cakes may be expensive, but they sure are delicious!\"";
    close;
}

002-2,26,27,0	script	Ontas	NPC154,{
    mes "[Ontas]";
    mes "";
    mes "\"We come here almost every week! This place has some of the best bread I've ever eaten!\"";
    close;
}