path: root/npc/re/jobs/3-2/wanderer.txt

//================= Hercules Script =======================================
//=       _   _                     _
//=      | | | |                   | |
//=      | |_| | ___ _ __ ___ _   _| | ___  ___
//=      |  _  |/ _ \ '__/ __| | | | |/ _ \/ __|
//=      | | | |  __/ | | (__| |_| | |  __/\__ \
//=      \_| |_/\___|_|  \___|\__,_|_|\___||___/
//================= License ===============================================
//= This file is part of Hercules.
//= http://herc.ws - http://github.com/HerculesWS/Hercules
//=
//= Copyright (C) 2012-2020 Hercules Dev Team
//= Copyright (C) Euphy
//= Copyright (C) Joseph
//= Copyright (C) Masao
//= Copyright (C) Meyraw
//= Copyright (C) Muad_Dib
//=
//= Hercules is free software: you can redistribute it and/or modify
//= it under the terms of the GNU General Public License as published by
//= the Free Software Foundation, either version 3 of the License, or
//= (at your option) any later version.
//=
//= This program is distributed in the hope that it will be useful,
//= but WITHOUT ANY WARRANTY; without even the implied warranty of
//= MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
//= GNU General Public License for more details.
//=
//= You should have received a copy of the GNU General Public License
//= along with this program.  If not, see <http://www.gnu.org/licenses/>.
//=========================================================================
//= Wanderer Job Quest
//================= Description ===========================================
//= Job change Quest from Dancer / Gypsy -> Wanderer.
//================= Current Version =======================================
//= 1.4
//=========================================================================

xmas,162,209,5	script	Aspiring Wanderer, Soy	4_F_06,{
	if (job_wan == 0) {
		mes "[Soy]";
		mes "Mimi, what should I do?";
		mes "My heart is beating so fast. Ahhh~";
		next;
		mes "[Mimi]";
		mes "Why is you face so flushed? Ha ha ha.";
		next;
		mes "[Soy]";
		mes "Don't make fun of me Mimi~";
		mes "I have dreamed of being at Dancer Kim's stage for a very long time!";
		emotion e_shy,0,"Aspiring Wanderer, Soy";
		next;
		mes "[Soy]";
		mes "I might lose my senses if I really see her dancing like a beautiful angel sent from above.";
		next;
		mes "[Mimi]";
		mes "Calm down, Soy.";
		mes "You are going to faint even before the performance starts. Ha ha.";
		next;
		mes "[Mimi]";
		mes "But I understand you.";
		mes "Many people are looking forward to meeting the best Wanderer in the world.";
		if (BaseJob != Job_Dancer || BaseLevel < 99) close;
		next;
		select("Dancer Kim?", "Wanderer?");
		emotion e_omg,0,"Aspiring Wanderer, Soy";
		mes "[Soy]";
		mes "What? You don't know the famous Wanderer, Dancer Kim?";
		mes "Oh my, oh my!!!";
		mes "You seem to know the art of dancing but how come you don't know her?";
		mes "Oh, no!";
		next;
		mes "[Mimi]";
		mes "A Wanderer is a free-spirited person who wanders about the world with the wind and the stars.";
		mes "Rhythm and Music accompany them wherever they go.";
		next;
		mes "[Mimi]";
		mes "Dancer Kim is the most famous Wanderer who tours the world with the Maestro Guitar Dong as the team <Nollio>.";
		next;
		mes "[Mimi]";
		mes "Soy and myself are Aspiring Wanderers, and there will be a performance of <Nollio> in this town soon, so we are eagerly looking forward to see it.";
		next;
		mes "[Soy]";
		mes "If you are a true Dancer, you must be struck with her Dance!";
		mes "Will I ever meet a Maestro like Guitar Song someday, Mimi?";
		next;
		emotion e_heh,0,"Aspiring Wanderer, Soy";
		mes "[Mimi]";
		mes "Just hang in there, Soy. Ha ha.";
		next;
		switch(select("Where is the performance?", "End the conversation.")) {
		case 1:
			mes "[Soy]";
			mes "Right in front of the Christmas tree!";
			mes "White snow, beautiful melody, and my captivating dance.";
			mes "Don't you think it would be a great performance?";
			job_wan = 1;
			close;
		case 2:
			mes "[Mimi]";
			mes "If you are interested in becoming a Wanderer, just come back to me anytime. Although I'm not perfect, I will try my best to help you.";
			close;
		}
	} else if (job_wan == 1) {
		if (strnpcinfo(NPC_NAME) == "Aspiring Wanderer, Soy") {
			mes "[Soy]";
			mes "The performance will be held in front of the Christmas tree here in Lutie.";
			mes "I can't wait! Ah~ I'm losing my senses, Mimi.";
		} else {
			mes "[Mimi]";
			mes "A Wanderer's dancing charm is higher than that of a dancer or gypsy, everyone will lose their souls when they see their performance.";
			next;
			mes "[Mimi]";
			mes "I want to become a Wanderer, but I'm still a dancer.";
			mes "But I think^3131FF it's better to learn Gypsy's unique skills first, and then become a Wanderer^000000. Soy can't wait to become a Wanderer.";
		}
		close;
	} else if (job_wan == 10) {
		mes "[Soy]";
		mes "<Nollio> is the best!!";
		close;
	} else {
		if (strnpcinfo(NPC_NAME) == "Aspiring Wanderer, Soy") {
			mes "[Soy]";
			mes "I want to become an famous Wanderer too, Mimi.";
		} else {
			mes "[Mimi]";
			mes "Not sure if I'm greedy, but I need to learn all Dancer and Gypsy skills before I can become a Wanderer.";
		}
		close;
	}
}
xmas,163,209,3	duplicate(Aspiring Wanderer, Soy)	Aspiring Wanderer, Mimi	4_F_06

xmas,132,143,5	script	Performance Manager#wnd	4_M_06,{
	mes "[Performance Manager]";
	if (job_wan == 0) {
		mes "Oh, what should I do?";
		close;
	} else if (job_wan == 1) {
		mes "Oh, what should I do?";
		mes "Why did they do this?";
		next;
		emotion e_shy,0,"Aspiring Wanderer, Soy";
		mes "[Performance Manager]";
		mes "Hey, you there!";
		mes "Please listen to my story.";
		mes "Actually, I shouldn't tell anyone.";
		mes "But I'm so overwhelmed that I might go crazy. Ahhhh~~!";
		next;
		while (1) {
			.@loop = 0;
			switch(select("Sorry, I don't care.", "What's the matter?", "Why are you telling me this?")) {
			case 1:
				mes "[Performance Manager]";
				mes "That's a bit harsh don't you think?";
				close;
			case 2:
				mes "[Performance Manager]";
				mes "The performance is supposed to be soon!";
				next;
				mes "[Performance Manager]";
				mes "Those people don't feel any responsibility..";
				mes "We're all expecting them and I've promoted them a lot.";
				next;
				.@loop = 1;
				break;
			case 3:
				emotion e_ag;
				mes "[Performance Manager]";
				mes "I told you that I'm overwhelmed!";
				mes "You don't understand me!";
				next;
				break;
			}
			if (.@loop) break;
		}
		while (1) {
			.@loop = 0;
			switch(select("Is there a problem?", "Who do you mean?", "It has nothing to do with me.")) {
			case 1:
				mes "[Performance Manager]";
				mes "How could they do that?";
				mes "People will throw snowballs!";
				mes "Maybe they will even throw a big snowman, no!";
				next;
				emotion e_wah;
				mes "[Performance Manager]";
				mes "People might grab me by the collar!!";
				mes "Swing swing, dangling dangling!!";
				mes "This is awful.";
				next;
				.@loop = 1;
				break;
			case 2:
				mes "[Performance Manager]";
				mes "Who?!";
				mes "It's <Nollio>!";
				mes "You call that a question?";
				mes "They are the worst people in the world.";
				next;
				break;
			case 3:
				mes "[Performance Manager]";
				mes "What a heartless thing to say!";
				close;
			}
			if (.@loop) break;
		}
		while (1) {
			.@loop = 0;
			switch(select("Are you afraid of people?", "The performers caused trouble?", "Ignore him.")) {
			case 1:
				mes "[Performance Manager]";
				mes "Wouldn't you be afraid of all the eyes of people if you were me?";
				mes "I am in charge of this performance! A lot of people are looking forward to see it and there are many sponsors who are supporting us! I'm so stressed.";
				next;
				break;
			case 2:
				mes "[Performance Manager]";
				mes "Yes!";
				mes "<Nollio> has cancelled their performance!";
				next;
				mes "[Performance Manager]";
				mes "And they didn't give me any reason whatsoever!";
				next;
				mes "[Performance Manager]";
				mes "Besides the money I spent for promoting and setting up the stage..";
				mes "How can I handle all the angry people?";
				next;
				.@loop = 1;
				break;
			case 3:
				mes "[Performance Manager]";
				mes "Hey, where are you going!";
				close;
			}
			if (.@loop) break;
		}
		mes "[" + strcharinfo(PC_NAME) + "]";
		mes "I see that you are worried that the performance is going down the drain.";
		mes "You wanted to make a successful performance to meet the fan's expectations.";
		next;
		mes "[Performance Manager]";
		mes "I really don't know how I should manage this.";
		mes "Why did they suddenly cancel the performance?";
		mes "Do you know?";
		next;
		mes "[Performance Manager]";
		mes "Why is <Nollio> taking this kind of attitude towards me?";
		mes "Did I make any mistakes? After making a contract with them, I did everything they demanded of me!";
		next;
		mes "[" + strcharinfo(PC_NAME) + "]";
		mes "It's because...";
		input(.@inputstr$);
		mes "^3131FF" + .@inputstr$ + "^000000";
		mes "......";
		next;
		emotion e_ag;
		mes "[Performance Manager]";
		mes "What the hell are you talking about?";
		mes "Are you teasing me because I'm emotionally unstable?";
		next;
		mes "[Performance Manager]";
		mes "Oh, I'm so worried that I'm having heart palpitations and I'm starting to feel dizzy!";
		next;
		mes "[Performance Manager]";
		mes "Hey! Can you please go out and find the Maestro Guitar Song?";
		next;
		switch(select("Ah, okay.", "Why should I do that?", "I won't!")) {
		case 1:
			break;
		case 2:
			emotion e_an;
			mes "[Performance Manager]";
			mes "You're asking me why!?";
			mes "Ahh, no.....";
			mes "It's because you seem like a similar artist.";
			mes "You also wanted to watch the performance, didn't you?";
			next;
			break;
		case 3:
			mes "[Performance Manager]";
			mes "You are so cold-hearted....";
			close;
		}
		mes "[Performance Manager]";
		mes "I would grab them by their collars if I could!";
		mes "I would tell them Why are you spoiling the performance? but for now, dealing with the angry sponsors is hard enough... Oh, no!";
		next;
		mes "[Performance Manager]";
		mes "I don't know where Guitar Song is, but it is clear that he likes to visit the Comodo Casino!";
		mes "Hu, Hurry up!! Oh, I really feel dizzy! Guitar Song!!!";
		job_wan = 2;
		setquest 2218;
		close;
	} else if (job_wan == 2) {
		mes "I am not sure if Guitar Song is in Comodo, you should go there and find him!";
		close;
	} else if (job_wan == 9) {
		mes "They came back!!";
		close;
	} else if (job_wan == 10) {
		mes "Thanks to you, the performance was successful.";
		mes "You are so competent!";
		mes "In return, I will prepare the stage for you someday.";
		close;
	}
	mes "Ahhh, so distracting!";
	close;
}

comodo,140,86,5	script	Cheerless Maestro	4_M_MINSTREL,{
	if (job_wan < 2) {
		mes "[Cheerless Maestro]";
		mes "You can dance ~";
		mes "You can do your work ~";
		mes "You are the dancing Queen ~";
		mes "I am the tambourine King ~";
		next;
		mes "[Cheerless Maestro]";
		mes "Whew...";
		close;
	} else if (job_wan == 2) {
		mes "[Cheerless Maestro]";
		mes "You can dance ~";
		mes "You can do your work ~";
		mes "You are the dancing Queen ~";
		mes "I am the tambourine King ~";
		next;
		mes "- You found a Maestro -";
		mes "- singing a weird song. -";
		next;
		if(select("That's a weird song.", "Ignore it.") == 2) {
			mes "- What a weird person, I better stay away. -";
			close;
		}
		emotion e_omg;
		mes "[Cheerless Maestro]";
		mes "What?!";
		mes "Are you ignoring my immortal masterpiece <Tambourine King>? You are the first person who's ever slapped me in the face.";
		next;
		select("I didn't slap you.");
		emotion e_gasp;
		mes "[Cheerless Maestro]";
		mes "Oh! Lady, looking at your appearance you must be a dancer, right?";
		next;
		mes "[Cheerless Maestro]";
		mes "Do you have a Bard or Minstrel traveling together with you?";
		mes "If you don't, how about making a traveling troupe with me?";
		next;
		mes "[Cheerless Maestro]";
		mes "The name of the team is <Guitar Song's Agony>.";
		mes "This name expresses the excruciating pain it takes to create art works.";
		next;
		mes "[Cheerless Maestro]";
		mes "It has an edgy kind of name So I think that it will be a very popular group.";
		next;
		select("Are you Guitar Song?");
		emotion e_shy;
		mes "[Guitar Song]";
		mes "Huh... I'm a bit disappointed that you finally recognize me now.";
		mes "Yes, I am the handsome Guitar Song in the famous group <Nollio>.";
		mes "Ha ha ha!";
		next;
		mes "[Guitar Song]";
		mes "So how about it? Isn't that a tempting offer to you?";
		mes "I'm a really famous Maestro at the peak of my popularity. People are dying to work with me, but you are indifferent to me lady.";
		next;
		select("Where is Dancer Kim?", "Why'd you cancel the performance?");
		mes "[Guitar Song]";
		mes "Why are you asking me that question so suddenly?";
		mes "Come on, let's just talk about a pleasant matter.";
		mes "Dancer Kim and the performance have nothing to do with me.";
		next;
		select("What do you mean?");
		mes "[Guitar Song]";
		mes "Hey, I told you to stop talking about this matter....";
		mes "I don't want to think about it. It just hurts my feelings.";
		next;
		mes "- Guitar Song is adamantly refusing to talk. What should I do to hear the story about <Nollio>? -";
		job_wan = 3;
		close;
	} else if (job_wan == 3) {
		mes "[" + strcharinfo(PC_NAME) + "]";
		mes "(Would it be possible for me to make him tell me what happened with Nollio?)";
		next;
		switch(select("Use Dazzler", "Use Lullaby", "Use Lucky Luck")) {
		case 1:
			if (getskilllv("DC_UGLYDANCE") == 5 || rand(100) >= 80) {
				mes "- You get closer to Song's ear. -";
				next;
				mes "[" + strcharinfo(PC_NAME) + "]";
				mes "Okay-";
				next;
				mes "[" + strcharinfo(PC_NAME) + "]";
				mes "Oi-!!!!!";
				specialeffect EF_STUNATTACK;
				next;
				mes "[Guitar Song]";
				mes "Wh...what!! What are you doing?!?";
				mes "You almost damaged my eardrum.";
				emotion e_an;
				next;
				mes "[" + strcharinfo(PC_NAME) + "]";
				mes "Hey, cheer up!!!";
				next;
				mes "[Guitar Song]";
				mes "What are you talking about?";
				next;
				mes "[" + strcharinfo(PC_NAME) + "]";
				mes "You should know, people are addicted to your music?";
				mes "So many people are supporting you with anticipation.";
				mes "Would you break your promise and let people down? Not giving people any reason?";
				next;
			} else {
				mes "[" + strcharinfo(PC_NAME) + "]";
				mes "Okay-";
				next;
				mes "[" + strcharinfo(PC_NAME) + "]";
				mes "Aaaaahhh!!!!!";
				next;
				mes "[Guitar Song]";
				mes "What... what are you doing?!! What's wrong with you!";
				mes "Security!!!";
				next;
				mes "[Black-suit Guards]";
				mes "Please stop this.";
				close2;
				warp "comodo",117,98;
				end;
			}
			break;
		case 2:
			if (getskilllv("BD_LULLABY") == 0) {
				mes "- You cannot use this skill without learning it. -";
				close;
			}
			mes "[" + strcharinfo(PC_NAME) + "]";
			mes "Looks like I will not get answer even if I force him.";
			close;
		case 3:
			if (getskilllv("DC_FORTUNEKISS") == 0) {
				mes "- You cannot use this skill without learning it. -";
				close;
			}
			emotion e_what,1;
			mes "[" + strcharinfo(PC_NAME) + "]";
			mes "Ah, ah my Guitar Song~";
			next;
			mes "[Guitar Song]";
			mes "What? I've got goose bumps.";
			next;
			emotion e_what,1;
			mes "[" + strcharinfo(PC_NAME) + "]";
			mes "I've been watching <Nollio> for years.";
			next;
			mes "[Guitar Song]";
			mes "I know that we are that popular! Ha ha ha!";
			next;
			emotion e_what,1;
			mes "[" + strcharinfo(PC_NAME) + "]";
			mes "I've seen other Maestro's performances but there was no one better then Guitar Song.";
			next;
			mes "[Guitar Song]";
			mes "He he he! Yes, I know I am super great!";
			next;
			emotion e_no1,1;
			mes "[" + strcharinfo(PC_NAME) + "]";
			mes "Oh... When I hear Guitar Song's performance for the first time I has a crush on you immediately.";
			next;
			mes "[" + strcharinfo(PC_NAME) + "]";
			mes "It felt like hearing mommy's lullaby~ It was so beautiful and moving... You are the best artist of our time.";
			next;
			specialeffect EF_STEAL;
			mes "[Guitar Song]";
			mes "Ha ha ha. I know that well, but it feels good to hear a compliment from you!";
			next;
			mes "[" + strcharinfo(PC_NAME) + "]";
			mes "So I was looking forward to seeing your performance in Lutie this time.";
			mes "But after I heard the performance got cancelled, I felt so sad.";
			next;
			emotion e_sob,1;
			mes "[" + strcharinfo(PC_NAME) + "]";
			mes "Now I can't hear Guitar Song's melody~~";
			mes "I wanted to dance to your music like a beautiful butterfly.";
			mes "Is there no way for my dream to be true now? Sob sob...";
			next;
			mes "[Guitar Song]";
			mes "Huh huh! No, that is not...";
			next;
			emotion e_sob,1;
			mes "[" + strcharinfo(PC_NAME) + "]";
			mes "I am really happy to meet you in person, but I hope to see your performance in the beautiful snowy town, Lutie.. Sob sob...";
			next;
			emotion e_sob,1;
			mes "[" + strcharinfo(PC_NAME) + "]";
			mes "Why in the world don't you show us the performance, Guitar Song?";
			mes "Don't you like me? Sob sob..";
			next;
			emotion e_omg;
			mes "[Guitar Song]";
			mes "No, it's not that kind of reason!";
			next;
			mes "[" + strcharinfo(PC_NAME) + "]";
			mes "Then please tell me, I really love your music... but now I feel so blue...";
			emotion e_what;
			next;
			break;
		}
		mes "[Guitar Song]";
		mes "Oh, no! You know...";
		mes "I want to have a performance, too!";
		mes "But I cannot do it all by myself!";
		next;
		emotion e_ag;
		mes "[Guitar Song]";
		mes "It's all because of Dancer Kim!";
		mes "One day, she suddenly got mad and told me that she would quit <Nollio>!";
		mes "I was also tired of here unpredictable feelings, too!";
		next;
		mes "[Guitar Song]";
		mes "Pshaw.";
		next;
		mes "[" + strcharinfo(PC_NAME) + "]";
		mes "Why did she get mad so suddenly?";
		next;
		emotion e_swt;
		mes "[Guitar Song]";
		mes "I don't know! She must be holding a grudge for something.";
		mes "That's what she's like.";
		mes "She suddenly disappeared and sent me a letter telling me that the team would be disbanded.";
		next;
		mes "[" + strcharinfo(PC_NAME) + "]";
		mes "Where is Dancer Kim now?";
		next;
		mes "[Guitar Song]";
		mes "Well, the letter was sent from Hugel.";
		mes "I guess she might be back at her hometown.";
		mes "That's where I met her for the first time.";
		next;
		emotion e_dots;
		mes "[Guitar Song]";
		mes "Although she loses her temper easily, her dance is so wonderful....";
		mes "I don't know what I am doing wrong.";
		job_wan = 4;
		changequest 2218,2219;
		next;
		mes "[Guitar Song]";
		mes "She smiled so happily that she likes the new song so much..";
		mes "Who can dance to my music so wonderfully as she did?";
		mes "Now my music and my life is history... (muttering).";
		close;
	} else if (job_wan > 3 && job_wan < 8) {
		mes "[Guitar Song]";
		mes "Dancer Kim is probably addicted to the monster races in Hugel again!";
		mes "Back in the day when she was addicted to the monster races, who do you think got her out of it?";
		close;
	} else if (job_wan == 8) {
		emotion e_gasp;
		mes "- You tell him what happened in Hugel and ask him to go back to Lutie. -";
		next;
		mes "[Guitar Song]";
		mes "Oh oh~";
		mes "You are silly Dancer Kim~";
		mes "Without me, who else can take care of such a lady like you~";
		next;
		mes "[Guitar Song]";
		mes "I'll go there right away and scold her.";
		job_wan = 9;
		close;
	} else if (job_wan == 9) {
		mes "[Guitar Song]";
		mes "Okay, I will go to the Christmas tree in Lutie where the performance is supposed to be held.";
		close;
	}
	mes "[Cheerless Maestro]";
	mes "Where is my partner...";
	close;
}

hu_in01,305,251,5	script	Vacant Looking Lady#wnd	4_F_CAPEGIRL,{
	if (job_wan < 4) {
		mes "[Vacant Looking Lady]";
		mes "(blank...)";
		close;
	} else if (job_wan == 4) {
		mes "[Vacant Looking Lady]";
		mes "Sob... sob...";
		next;
		select("Why are you crying?");
		emotion e_sob;
		mes "[Vacant Looking Lady]";
		mes "I gave up my dream...";
		mes "*Sob *Sob.";
		next;
		select("What do you mean?");
		mes "[Vacant Looking Lady]";
		mes "I said goodbye to my partner who had been working with me for a long time.";
		next;
		select("Why did you say goodbye?");
		emotion e_sob;
		mes "[Vacant Looking Lady]";
		mes "it's because... sob... sob!";
		next;
		select("You can tell me everything.");
		mes "[Vacant Looking Lady]";
		mes "When Wanderers and Maestro's get together, their abilities become stronger.";
		next;
		mes "[Vacant Looking Lady]";
		mes "So when they travel, they often get together and perform duets.";
		mes "They have a good time dancing and playing music.";
		next;
		mes "[Vacant Looking Lady]";
		mes "A few days ago, with my partner Guitar Song. I showed a beautiful dance to his music to many people as we usually do.";
		next;
		mes "[Vacant Looking Lady]";
		mes "I was really proud of being a Wanderer after I drew all of that enthusiastic applause.";
		mes "Guitar Song also praised me.";
		mes "I was so happy that day.";
		next;
		mes "[Vacant Looking Lady]";
		mes "But...";
		next;
		select("What happened next?");
		mes "[Vacant Looking Lady]";
		mes "The following morning, I woke up and washed my fave and was looking for something to eat in my room..";
		next;
		emotion e_omg;
		mes "[Vacant Looking Lady]";
		mes "Then Guitar Song suddenly opened the door of my room for some reason and said ^3131FFHey! What the hell are.. you doing here?^000000 and then he threw me out of my room!";
		next;
		mes "[Vacant Looking Lady]";
		mes "We've been together for a long time but how can he do such a thing to me?";
		mes "At first, I thought he was kidding around with me! But when he kicked me out of my room...";
		next;
		emotion e_sob;
		mes "[Vacant Looking Lady]";
		mes "Why didn't he recognize my face?";
		mes "Do you think he doesn't want to see my face without makeup?";
		mes "Boo hoo hoo!";
		next;
		select("So you disbanded the team?");
		emotion e_sob;
		mes "[Vacant Looking Lady]";
		mes "Are you also ignoring my wounded self-respect as a woman?";
		next;
		mes "[" + strcharinfo(PC_NAME) + "]";
		mes "No! He is really a caring man!";
		mes "But I don't think you disbanded your precious team just because of that.";
		next;
		mes "[Vacant Looking Lady]";
		mes "You're right.";
		mes "It's not just because of that.";
		mes "The real reason why I disbanded the team is...";
		next;
		mes "[Vacant Looking Lady]";
		mes "After that day, I went to my hometown, Hugel and I just stayed indoors.";
		mes "It was then when Shide comforted me with sweet cakes.";
		next;
		emotion e_shy;
		mes "[Vacant Looking Lady]";
		mes "Shide's cake is so wonderful!";
		mes "It is the most famous cake in Hugel with soft sponge cake and fresh fruits and sweet chocolate cream!";
		next;
		mes "[Vacant Looking Lady]";
		mes "It felt like all the angels of happiness came to comfort me when I tasted that sweet cake.";
		next;
		mes "[Vacant Looking Lady]";
		mes "So I ate it every morning and every night.";
		next;
		select("Oh, you wouldn't...");
		emotion e_sob;
		mes "[Vacant Looking Lady]";
		mes "The angel of happiness took back my sadness and gave me a lot of belly fat!";
		mes "Boo hoo hoo hoo!!";
		next;
		mes "[Vacant Looking Lady]";
		mes "Now I can't wear my dancing clothes!";
		mes "I am not a dancer who dances like a beautiful butterfly anymore!";
		next;
		mes "[Vacant Looking Lady]";
		mes "What is worse, it became hard to bend my waist forward!";
		mes "Boo hoo hoo!";
		next;
		mes "[Vacant Looking Lady]";
		mes "The performance day is approaching, but the angel of happiness brought me a big obstacle.";
		mes "Now I've fallen into despair again!";
		mes "I can't let Guitar Song and my fans see me like this!";
		next;
		mes "[Vacant Looking Lady]";
		mes "<Nollio> is over! Boo hoo hoo!";
		job_wan = 5;
		close;
	} else if (job_wan == 5) {
		emotion e_sob;
		mes "[Vacant Looking Lady]";
		mes "Not long ago, I was like a beautiful dove, but now I am just a fat chicken.";
		mes "Sob sob...!";
		mes "I think the life of Wanderer Dancer Kim is over now.";
		mes "Boo hoo hoo hoo!";
		next;
		if(select("Hey, don't give up.", "I feel sorry for you.") == 2) {
			mes "[Dancer Kim]";
			mes "My life cannot get out of abyss now......";
			close;
		}
		mes "[Dancer Kim]";
		mes "But I already told Guitar Song that it's all over.";
		mes "Even if it's not over, I cannot do anything right now.";
		next;
		select("If you give up, it will be over.");
		mes "[Dancer Kim]";
		mes "But in this situation...";
		mes "Do I really have a way to change it?";
		next;
		mes "[" + strcharinfo(PC_NAME) + "]";
		mes "Exercise is the best way!";
		mes "If you work hard, your bossy will be lighter than before!";
		next;
		mes "[Dancer Kim]";
		mes "But I get tired and give up easily.";
		mes "I think I am going to give up.";
		next;
		if(select("Well, there's no other way.", "Let's work together.") == 1) {
			mes "[Dancer Kim]";
			mes "No dreams and no hope...";
			close;
		}
		emotion e_omg;
		mes "[Dancer Kim]";
		mes "Will you exercise together with me?";
		mes "Really?";
		next;
		mes "[Dancer Kim]";
		mes "I'm sure that I would try harder if I had someone to workout with.";
		next;
		mes "[Dancer Kim]";
		mes "I feel better now!";
		mes "I think I'm gaining strength again!";
		mes "Let's work together!";
		next;
		select("What should we do first?");
		mes "[Dancer Kim]";
		mes "I have a good idea!";
		next;
		mes "[Dancer Kim]";
		mes "Meet me at Abyss Lake.";
		mes "I'll see you there.";
		mes "Just go one field South and one field West from here in Hugel.";
		mes "I'll meet you there.";
		job_wan = 6;
		changequest 2219,2220;
		close;
	} else if (job_wan == 6 || job_wan == 7) {
		mes "[Dancer Kim]";
		mes "I'll meet you at Abyss Lake.";
		close;
	} else if (job_wan == 8) {
		mes "[Dancer Kim]";
		mes "Please tell Guitar Song to go to Lutie";
		mes "I'll go there after I've packed my luggage!";
		close;
	}
	mes "[Vacant Looking Lady]";
	mes "Where is my partner......";
	close;
}

hu_fild05,342,130,5	script	Dancer Kim#fild	4_F_CAPEGIRL,{
	if (job_wan == 6) {
		mes "[Dancer Kim]";
		mes "Exercising together is good but if we compete for it, I think we'll get a better effect!";
		next;
		mes "[Dancer Kim]";
		mes "From now on, let's compete to see who defeats the Yellow Novus first!";
		next;
		mes "[Dancer Kim]";
		mes "You need to defeat 50 Yellow Novus!";
		mes "Are you ready?";
		next;
		if(select("No.", "Yes.") == 1) {
			mes "[Dancer Kim]";
			mes "Hurry up before I lose interest!";
			close;
		}
		mes "[Dancer Kim]";
		mes "Good! Then ready, set~~";
		mes "Go!";
		job_wan = 7;
		changequest 2220,2221;
		close;
	} else if (job_wan == 7) {
		if (questprogress(2221,PLAYTIME) == 1) {
			if (questprogress(2221,HUNTING) == 2) {
				mes "[Dancer Kim]";
				mes "Whew!";
				mes "Looks like I've lost!";
				next;
				mes "[Dancer Kim]";
				mes "This feeling reminds me of the past where I've crossed the borders of many continents.";
				next;
				mes "[Dancer Kim]";
				mes "Ah! Look at this!";
				mes "I'm getting slimmer, can you see it?";
				next;
				mes "[Dancer Kim]";
				mes "I feel that my body is full of power.";
				mes "I suddenly want to see my good partner Guitar Song.";
				mes "I want to start dancing again.";
				next;
				select("How about dancing in Lutie?");
				emotion e_gasp;
				mes "[Dancer Kim]";
				mes "Ah! Christmas Village! Yes! Yes!";
				mes "My dream to dance in Lutie will finally come true.";
				next;
				mes "[Dancer Kim]";
				mes "I want to dance and jump all day to bring people happiness!";
				mes "So I will go to Lutie.";
				next;
				mes "[Dancer Kim]";
				mes "Ah, do me a favor, please.";
				mes "Can you bring Guitar Song to Lutie?";
				mes "Say that his partner is waiting for him.";
				next;
				select("No problem!");
				mes "[Dancer Kim]";
				mes "You're a good person. I'm really happy that I met you.";
				mes "Thank god for sending such a stubborn person to me!";
				job_wan = 8;
				changequest 2221,2222;
				close;
			} else {
				mes "[Dancer Kim]";
				mes "Does it look easy to you?";
				mes "But I'm sure I have a better chance to win.";
				close;
			}
		} else if (questprogress(2221,PLAYTIME) == 2) {
			mes "[Dancer Kim]";
			mes "Oh, you came back to me.";
			mes "I'm so tired. I don't give up halfway. It's a good exercise for me. I will have to give up Nollio to another Wanderer, it's all over....";
			next;
			mes "- Dancer Kim dropped down by grief and fatigue -";
			job_wan = 6;
			changequest 2221,2220;
			close;
		} else {
			mes "[Dancer Kim]";
			mes "Huh...?";
			job_wan = 6;
			close;
		}
	} else if (job_wan == 8) {
		mes "[Dancer Kim]";
		mes "Please tell Song, I will be waiting for him at the Christmas tree.";
		close;
	}
	mes "[Dancer Kim]";
	mes "Hunting Novus is the best exercise, I think.";
	close;
}

-	script	#fildshout00::wandererjcq	FAKE_NPC,{
OnTouch:
	if (job_wan == 7) {
		switch(rand(3)) {
		case 0:
			mapannounce "hu_fild05","Dancer Kim: Hey, how did you get so fast? I've only got few myself...",bc_map,"0xffff00"; //FW_NORMAL 12 0 0
			break;
		case 1:
			mapannounce "hu_fild05","Dancer Kim: Errrgghh! Hey Novus! I'm gonna get you~",bc_map,"0xffff00"; //FW_NORMAL 12 0 0
			break;
		case 2:
			mapannounce "hu_fild05","Dancer Kim: Oh, are you tired already? Is this my victory? Ho ho ho.",bc_map,"0xffff00"; //FW_NORMAL 12 0 0
			break;
		}
	}
	end;
}
hu_fild05,81,111,0	duplicate(wandererjcq)	#fildshout01	HIDDEN_WARP_NPC,20,20
hu_fild05,193,98,0	duplicate(wandererjcq)	#fildshout02	HIDDEN_WARP_NPC,20,20
hu_fild05,252,74,0	duplicate(wandererjcq)	#fildshout03	HIDDEN_WARP_NPC,20,20
hu_fild05,323,175,0	duplicate(wandererjcq)	#fildshout04	HIDDEN_WARP_NPC,20,20
hu_fild05,334,225,0	duplicate(wandererjcq)	#fildshout05	HIDDEN_WARP_NPC,20,20
hu_fild05,301,287,0	duplicate(wandererjcq)	#fildshout06	HIDDEN_WARP_NPC,20,20
hu_fild05,229,315,0	duplicate(wandererjcq)	#fildshout07	HIDDEN_WARP_NPC,20,20
hu_fild05,146,309,0	duplicate(wandererjcq)	#fildshout08	HIDDEN_WARP_NPC,20,20
hu_fild05,80,239,0	duplicate(wandererjcq)	#fildshout09	HIDDEN_WARP_NPC,20,20
hu_fild05,69,147,0	duplicate(wandererjcq)	#fildshout10	HIDDEN_WARP_NPC,20,20

xmas,148,131,0	script	#wandergogo	HIDDEN_WARP_NPC,3,3,{
OnTouch:
	if (job_wan == 9) {
		enablenpc "Dancer Kim#xmas";
		enablenpc "Guitar Song#xmas";
		enablenpc "Spectator#xmas1";
		enablenpc "Spectator#xmas2";
		enablenpc "Spectator#xmas3";
		enablenpc "Spectator#xmas4";
		enablenpc "Soy#xmas";
		enablenpc "Mimi#xmas";
	}
	end;
}

xmas,147,135,5	script	Dancer Kim#xmas	4_F_WANDERER,{
	if (job_wan == 9) {
		if (BaseJob != Job_Dancer && BaseLevel < 99 && JobLevel < 50) {
			mes "- You can't continue the quest because the condition for the quest is not appropriate. -";
			close;
		}
		if (SkillPoint) {
			mes "- You can't continue the quest because you have remaining skill points. -";
			close;
		}
		if (checkweight(Knife,2) == 0) {
			mes "- You need to empty your inventory if you want to continue the quest. -";
			close;
		}
		if (hascashmount()) {
			mes "[Dancer Kim]";
			mes "Please get off of that creature you're riding on.";
			mes "Then talk to me again.";
			close;
		}
		mes "- <Nollio> is performing. -";
		next;
		emotion e_ho,0,"Guitar Song#xmas";
		emotion e_ho;
		mes "[Guitar Song]";
		mes "One! Two! Three!";
		mes "Blue fish dancing~";
		mes "Fan! Fan! Fan! I am your fan~";
		mes "With a strong mind and strong will, I complete fishing~";
		next;
		emotion e_ho,0,"Spectator#xmas1";
		emotion e_ho,0,"Spectator#xmas2";
		emotion e_ho,0,"Spectator#xmas3";
		emotion e_ho,0,"Spectator#xmas4";
		emotion e_ho,0,"Soy#xmas";
		emotion e_ho,0,"Mimi#xmas";
		mes "[Spectators]";
		mes "AAAAhhhhhhhhh - - !!!";
		mes "So cool! Nollio is the best!!!";
		next;
		mes "[Guitar Song]";
		mes "Hello, ladies and gentlemen!";
		next;
		emotion e_lv,0,"Spectator#xmas1";
		emotion e_lv,0,"Spectator#xmas2";
		emotion e_lv,0,"Spectator#xmas3";
		emotion e_lv,0,"Spectator#xmas4";
		emotion e_lv,0,"Soy#xmas";
		emotion e_lv,0,"Mimi#xmas";
		mes "[Spectators]";
		mes "Hello!!!!!";
		next;
		mes "[Guitar Song]";
		mes "We are the romantic Wanderer team <Nollio> who stroll along the world following love and wind!";
		next;
		emotion e_lv,0,"Spectator#xmas1";
		emotion e_lv,0,"Spectator#xmas2";
		emotion e_lv,0,"Spectator#xmas3";
		emotion e_lv,0,"Spectator#xmas4";
		emotion e_lv,0,"Soy#xmas";
		emotion e_lv,0,"Mimi#xmas";
		mes "[Spectators]";
		mes "Wowwwww~!";
		next;
		emotion e_no1;
		mes "[Dancer Kim]";
		mes "It's so fascinating that I can dance in a snowy, beautiful village,";
		mes "I'm so glad that I came here, Lutie.";
		next;
		mes "[Spectators]";
		mes "Yayyyy~";
		next;
		mes "[Dancer Kim]";
		mes "In fact, this wonderfull performance would have been cancelled because of my carelessness.";
		next;
		mes "[Guitar Song]";
		mes "I unintentionally made her upset.";
		mes "Let me take this opportunity to say to her that I'm sorry.";
		next;
		mes "[Dancer Kim]";
		mes "It's okay.";
		mes "I'm sorry for behaving as I did.";
		next;
		mes "[Dancer Kim]";
		mes "In fact there is a friend who cheered me up and helped me get through the hardships I faced when I was depressed in my hometown.";
		next;
		mes "[Dancer Kim]";
		mes "You may love my friend's dance more than mine in the future.";
		mes "She has a great talent.";
		next;
		mes "[Dancer Kim]";
		mes "Introducing!";
		next;
		mes "[Dancer Kim]";
		mapannounce "xmas","Dancer Kim: Introducing the rising Wanderer! " + strcharinfo(PC_NAME) + "!",bc_map,"0xffff00"; //FW_NORMAL 12 0 0
		mes "This rising Wanderer star, " + strcharinfo(PC_NAME) + "!";
		jobchange roclass(eaclass()|EAJL_THIRD);
		job_wan = 10;
		getitem Green_Apple_Ring,1;
		getitem Dying_Swan,1;
		completequest 2222;
		next;
		mes "[Dancer Kim]";
		mes "Ha ha ha, are you surprised?";
		mes "Don't look so puzzled?";
		mes "You led me here, you deserve it.";
		next;
		mes "[Dancer Kim]";
		mes "Oh! You are like a beautiful swan!";
		mes "The goddess must be jealous to see your beauty.";
		next;
		mes "[Dancer Kim]";
		mes "" + strcharinfo(PC_NAME) + "! I hope to see your beautiful exploits in the future.";
		mes "Also, I hope you to meet your precious Maestro.";
		mes "Let's perform together later, shall we? Ha ha.";
		next;
		mes "[Guitar Song]";
		mes "Thanks to you, I didn't lose my precious partner.";
		mes "Thank you a lot.";
		mes "Soon I will make a song for you, so wait for it.";
		close2;
		disablenpc "Dancer Kim#xmas";
		disablenpc "Guitar Song#xmas";
		disablenpc "Spectator#xmas1";
		disablenpc "Spectator#xmas2";
		disablenpc "Spectator#xmas3";
		disablenpc "Spectator#xmas4";
		disablenpc "Soy#xmas";
		disablenpc "Mimi#xmas";
		end;
	}
OnInit:
	disablenpc "Dancer Kim#xmas";
	end;
}

-	script	#wander_xmas	FAKE_NPC,{
	end;
OnInit:
	disablenpc strnpcinfo(NPC_NAME);
	end;
}
xmas,149,135,3	duplicate(#wander_xmas)	Guitar Song#xmas	4_M_MINSTREL
xmas,142,130,7	duplicate(#wander_xmas)	Spectator#xmas1	4_F_05
xmas,145,127,7	duplicate(#wander_xmas)	Spectator#xmas2	4_M_05
xmas,148,127,7	duplicate(#wander_xmas)	Soy#xmas	4_F_06
xmas,149,127,1	duplicate(#wander_xmas)	Mimi#xmas	4_F_06
xmas,151,127,1	duplicate(#wander_xmas)	Spectator#xmas3	4_M_KID2
xmas,154,129,1	duplicate(#wander_xmas)	Spectator#xmas4	4_M_NFLOSTMAN