path: root/npc/000-2-0/julia.txt

// Evol scripts.
// Authors:
//    Vasily_Makarov
//    4144
// Description:
//    Allows to change language and talks about what happened to him.
// 2 Bits Array:
//    ShipQuests
// Variable:
//    ShipQuests_Julia
// Values:
//    0   First touch.
//    1   Already touched.

000-2-0.gat,27,24,0,0	script	Julia	304,2,10;5,{

    mesn;
    mesq lg("Hello dear!");
    next;
    mesq l("What do you want today?");
    next;

  set @s$, l("I don't want to change my language, sorry.");

l_Menu:
    menu
        lg("I made a mistake, I would like to change my language."), l_ChooseLang,
        l("Could you explain to me where I am?"), l_WhereIam,
        l("What happened to me?"), l_What,
        l("Can I read these rules again?"), l_Rules,
        l("Nothing, sorry."), l_Close;

    mes "";
    mesn;
    mesq l("Of course! Tell me which language you speak and I will change the note on the ship board list.");

    goto l_ChooseLang;

l_First:

    callfunc "CheckClientVersion";

    mesn;
    mesq l("Hi, nice to see you!");
    next;
    mesq l("My name is Julia, it is me who took care of you after we found you in the sea.");
    next;
    mesq lg("I'm glad to see you're okay.");
    next;
    mesq lg("Could I ask you what your native language is? A sailor told me you're russian, but another one told me you're french... I'm a bit lost. I will register you on the ship boarding list just after that.");
    next;
    set @s$, "";
    goto l_ChooseLang;

  l_ChooseLang:
    menu
        l("I speak English") + ". (English)", -,
        l("I speak French") + ". (Français)", -,
        l("I speak Russian") + ". (Русский)", -,
        l("I speak Spanish") + ". (Español)", -,
        l("I speak Portuguese") + ". (Português)", -,
        l("I speak German") + ". (Deutsch)", -,
        l("I speak Flemish") + ". (Vloams)", -,
        l("I speak Polish") + ". (Polski)", -,

    @s$, l_NoChanges;
    set @lang, @menu-1;
    if (@lang < 0 || @lang > 7) close;
    setlang @lang;

    mes "";
    mesn;
    mesq l("Ok, done.");

    set @q, getq(ShipQuests_Julia);
    if (@q == 1) goto l_NoRules;

    next;
    mesq l("I'm sure that you've got some questions for me, feel free to ask them, but firstly I need to tell you the rules of proper social conduct on board.");
    
    mesq l("Here they are.");
    next;

    mesn "Narrator";
    mes col(l("There is a paper with some rules written on it."), 9);
    next;
    mesq col(l("1. Do not bot, this means that you won't run any automated tasks (Also included keyboard tricks). Any away from keyboard activity is considered botting does not include standing still)"), 9);
    next;
    mesq col(l("2, Do not spam (includes trade spam)"), 9);
    next;
    mesq col(l("3, Do not multibox, this mean that you cannot have more than one active character logged in or any other active clients used for attacking in group."), 9);
    next;
    mesq col(l("4, Don't trashtalk, beg or use rude language in your character name and in the chat, at the exception of roleplay purposes."), 9);
    next;
    mesq col(l("5, Don't speak any other language other than English in the public areas. You are free to speak any language you want in private chats and when alone with groups of friends."), 9);
    next;
    mesq col(l("6, Follow the social convention listed on the RFC1855."), 9);    next;
    next;

    mesn;
    mesq l("Oh, and it's not written there but don't give the password of your room to anybody, I'm the only one who has the other key and I won't ask for yours, so keep it secret and try not to use the same one in any other room in the future.");
    next;
    mesq l("If you want to read this page again, there is a copy up on the left wall.");
    next;
    mesq l("I think I'm done with that now. Do you have any questions?");
    next;

    setq ShipQuests_Julia, 1;
    goto l_Menu;

l_NoRules:
    next;
    mesq l("Do you have any other questions for me?");
    next;

    goto l_YNMenu;

l_NoChanges:
    mes "";
    mesn;
    mesq l("No problem, do you have any other questions for me?");
    next;

l_YNMenu:
    menu
        l("Yes, I do."), l_Menu,
        l("No, none."), l_Close;

l_WhereIam:
    mes "";
    mesn;
    mesq l("You're on a ship, we're on our way to the commercial capital of Artis.");
    next;
    mesq l("We should be there in a few days, once we arrive, I will warn the warrior guild about what happened, I'm sure they can help.");
    next;
    mesq l("But for now, you can relax on the ship, or visit the island we're docked at! Its a small island, but a good place to get some exercise and stretch your legs.");
    next;
    mesq l("Do you have any other questions for me?");
    next;

    goto l_YNMenu;

l_What:
    mes "";
    mesn;
    mesq l("We thought that you could help us understand this, all we know is that we found you back in the sea, adrift on your raft.");
    next;
    mesq lg("You were in bad shape, you should be happy we found you before the sea killed you.");
    next;
    mesq l("Oh, and there was this inscription on your raft. It represents one of the warrior guild of Esperia, the largest and biggest guild of the whole new world. Does that make you remember anything, anything at all?");
    next;
    goto l_EsperiaMenu;

l_EsperiaMenu:
    menu
        l("Sorry, but I can't tell you anything about that."), l_NoChanges,
        l("Nothing, sorry."), l_NoChanges;

l_Close:
    mes "";
    mesn;
    mesq l("Bye!");

    close;

l_Rules:
    mes "";
    mesn;
    mesq l("Of course, they are on the left wall, go have a look at them.");
    next;
    mesq l("Do you have any other questions for me?");
    next;

    goto l_YNMenu;

OnTouch:
    set @q, getq(ShipQuests_Julia);
    if (@q == 0) goto l_First;

    close;

}