path: root/npc/000-1/chest.txt

// Evol scripts.
// Authors:
//    4144
//    Hal9000
//    Reid
// Description:
//    A treasure chest, with... Treasures inside!
// Variable:
//    x   ShipQuests_Darlin
// Values: 
//    0   Never talked with Darlin.
//    1   Spoke, and received quest.
//    2   Opened the treasure chest.
//    3   Get back to Darlin.

000-1.gat,83,70,0	script	Chest#1	316;2,{

    set @q, getq(ShipQuests_Darlin);
    if (getnpcdir ("") == 4) goto l_Give;

    setnpcdir 2;
    initnpctimer;
    startnpctimer;
    close;

l_Give:
    if (@q > 1) goto l_Close;

    set @item, 515;
    set @count, 3;
    callfunc "InventoryPlace", @item, @count;

    setq ShipQuests_Darlin, 2;

    set zeny, zeny + 100;
    getitem "SeaDrops", 1;
    getitem "Aquada", 1;
    getitem "OldBook", 1;
    message strcharinfo(0), l("You open the treasure chest.");

l_Close:
    setnpcdir 6;
    initnpctimer;
    startnpctimer;
    close;

OnTimer160:
    stopnpctimer;
    if (getnpcdir ("") == 2) setnpcdir 4;
    if (getnpcdir ("") == 6) setnpcdir 0;
    end;

}