path: root/npc/024-6/talindra.txt

// TMW2 scripts.
// Authors:
//    Jesusalva
// Description:
//    Questmaker Handbook 14.0 (F = Favorable)

024-6,31,23,0	script	Talindra	NPC_ELF_F,{
    .@q = getq(FrostiaQuest_Talindra);
    if (BaseLevel < 65) {
        mesc l("The elf seems busy. She ignores you.");
        close;
    }
    if (.@q == 0) {
        if (frally()) goto L_Start_F;
        else goto L_Start_U;
    }
    else if (.@q == 1) {
        if (frally()) goto L_Submit_F;
        else goto L_Submit_U;
    }
    else if (.@q == 2) {
        if (frally()) goto L_Done_F;
        else goto L_Done_U;
    }
    Exception("Invalid quest state - "+str(.@q));
    end;

L_Start_F:
    mesn;
    mesq lg("Hey friend, could you do me a little favor?");
    next;
    mesn;
    mesq l("I want to prove exotic tea. More specifically, I'm looking for %s and %s. Bring me %d of each, and I'll reward you awesomely.", getitemlink(CelestiaTea), getitemlink(HerbalTea), 15);
    next;
    mesn;
    mesq l("Good luck!");
    setq FrostiaQuest_Talindra, 1;
    close;

L_Submit_F:
    mesn;
    mesq l("Did you got everything I've asked?");
    mes sprintf("- %d %s", 15, getitemlink(CelestiaTea));
    mes sprintf("- %d %s", 15, getitemlink(HerbalTea));
    next;
    if (askyesno() == ASK_YES) {
        if (countitem(CelestiaTea) < 15 ||
            countitem(HerbalTea) < 15) {
            mesn;
            mesq l("You've been spending too much time with humans. You are picking up bad habits from them like lying. Be careful.");
            close;
        }
        inventoryplace EquipmentBlueprintD, 1;
        delitem CelestiaTea, 15;
        delitem HerbalTea, 15;
        getitem EquipmentBlueprintD, 1;
        getexp 50000, 0;
        setq FrostiaQuest_Talindra, 2;
        mesn;
        mesq l("Yay! Many thanks! I'll enjoy it! Here is the promised reward.");
    }
    close;

L_Done_F:
    mesn;
    mesq l("I've heard Aethyr path was to the west, but I'm not sure west of where... %s", col(l("*sigh*"), 9));
    close;
/////////////////////////////////////////////////////////////////////////////////
L_Start_U:
    mesn;
    mesq l("Hey %s, could you do me a little favor?", get_race());
    next;
    mesn;
    mesq l("I want to prove exotic tea. More specifically, I'm looking for %s and %s. Bring me %d of each, and I'll reward you awesomely.", getitemlink(CelestiaTea), getitemlink(HerbalTea), 15);
    next;
    mesn;
    mesq l("Try to don't take too long!");
    setq FrostiaQuest_Talindra, 1;
    close;

L_Submit_U:
    mesn;
    mesq l("Did you got everything I've asked?");
    mes sprintf("%d %s", 15, getitemlink(CelestiaTea));
    mes sprintf("%d %s", 15, getitemlink(HerbalTea));
    next;
    if (askyesno() == ASK_YES) {
        if (countitem(CelestiaTea) < 15 ||
            countitem(HerbalTea) < 15) {
            mesn;
            mesq l("You liar, I'll teach you a lesson you won't forget!");
            mesc l("%s stabs you with a dagger!", .name$);
            percentheal -55, 0;
            close;
        }
        inventoryplace EquipmentBlueprintD, 1;
        delitem CelestiaTea, 15;
        delitem HerbalTea, 15;
        getitem EquipmentBlueprintD, 1;
        getexp 50000, 0;
        setq FrostiaQuest_Talindra, 2;
        mesn;
        mesq l("Thanks! I'll enjoy it! Here is the promised reward.");
    }
    close;

L_Done_U:
    mesn;
    mesq l("I've heard Aethyr path was to the west, but I'm not sure west of where... %s", col(l("*sigh*"), 9));
    next;
    mesn;
    mesq l("...Go mind your own business, %s.", get_race());
    close;

OnInit:
    .@npcId = getnpcid(.name$);
    setunitdata(.@npcId, UDT_HEADBOTTOM, CottonSkirt);
    setunitdata(.@npcId, UDT_HEADMIDDLE, LeatherShirt);
    setunitdata(.@npcId, UDT_HEADTOP, TrapperHat);
    setunitdata(.@npcId, UDT_HAIRSTYLE, 20);
    setunitdata(.@npcId, UDT_HAIRCOLOR, 17);
    npcsit;

    .sex = G_FEMALE;
    .distance = 5;
    end;
}