path: root/npc/012-2/door.txt

// TMW-2 Script.
// Author:
//    Jesusalva
// Notes:
//    Sponsor Area Only

012-2,59,38,0	script	Sponsors Inn	NPC_HIDDEN,0,0,{
    end;

OnTouch:
    if (!getgmlevel())
        goto L_Unauthorized;
    if (SP_WARN)
        SP_WARN=0;
    slide 59, 82;
    end;

L_Unauthorized:
    // Per r8.0 Apane Invasion, there's a moment on main storyline you'll be allowed in
    .@n=getq(General_Narrator);
    if (.@n == 5 || .@n == 6) {
        slide 59, 82;
        end;
    }
    if (.@n == 7) {
        dispbottom col(l("Seems like my access was revoked. I probably should talk to Airlia instead."), 9);
    }

    if (@sp_notrespass > 0)
        goto L_Warning;
    dispbottom col(l("Only Sponsors are allowed past this area."),1);
    slide 59,39;
    @sp_notrespass=1;
    end;

L_Warning:
    if (@sp_kick > 0)
        goto L_Kick;
    dispbottom col(l("Only Sponsors are allowed past this area."),1);
    dispbottom col(l("Do not attempt to go there again."),1);
    slide 60,40;
    @sp_kick=1;
    end;

L_Kick:
    if (SP_WARN > 5)
        goto L_Ban;
    dispbottom col(l("You cannot visit the Sponsor's Inn!"),1);
    slide 36,46;
    // Force user to disconnect
    atcommand "@kick "+strcharinfo(0);
    SP_WARN=SP_WARN+1;
    end;

L_Ban:
    dispbottom col(l("You cannot visit the Sponsor's Inn!"),1);
    slide 36,46;
    // Prevent abuse and possible vulnerabilities.
    atcommand "@ban 20mn "+strcharinfo(0);
    SP_WARN=0;
    end;
}