// TMW2 scripts.
// Authors:
// Jesusalva
// Description:
// Part of the Doctor's Quest. Lore Master. Saulc's Residence Gatekeeper.
004-3-1,37,23,0 script Falkrun NPC_INDIGENOUS_ANY,{
if (instance_id() >= 0) goto L_Episode;
mesn;
mesq l("Howdy! Lately I feel like a placeholder, just surviving on these harsh lands.");
next;
L_Main:
// He needs to explain the Civil War and the Great Fire for Doctor's Quest
mesn;
mesq l("Our clan has moved away from Tulimshar before the Civil War, almost was wiped off during the Great Fire, and when we thought we could finally life in peace, the Mana War and the Monster War broke out in rapid succession."); // Hence, TMW2
next;
mesn;
mesq l("I don't know if our clan will survive for much longer. Do you have any questions before we all die and our knowledge gets forgotten?");
next;
.@hist = 0;
do
{
select
l("No, none."),
l("Tell me about the Civil War."),
l("Tell me about the Great Fire."),
l("Tell me about the Mana War."),
l("Tell me about the Monster War."),
rif(.@hist == 15, l("What happened to the Wizard's Tower?"));
mes "";
switch (@menu) {
case 2:
mesn;
mesq l("The Civil War is one of the stuff which nearly everyone forgot about.");
next;
mesn;
mesq l("Jarret, Tulimshar's Founder, was a great man, but his successors were not. Specially the Red Queen. Eventually, our clan had enough and moved away from Tulim.");
next;
mesn;
mesq l("She was a tyrant who wanted to rule over not only Tulimshar, but the whole mana world, with an iron fist. She even charged her own premier of treason and tried to execute him.");
next;
mesn;
mesq l("The council, however, supported the premier. He might have accepted the death sentence quietly, but the council would hear none of it. Benjamin took over and incited a civil war.");
next;
mesn;
mesq l("The Red Queen was murdered, but her supporters prolonged the Civil War for at least six years after her death. The grudges were strong back then...");
next;
.@hist = .@hist | 1;
break;
case 3:
mesn;
mesq l("You see, Benjamin wanted to reshape the world. Very ambitious plans, which would have been great... If they had prospered.");
next;
mesn;
mesq l("Tulimshar spent trillions in research, and so did Hurnscald and Nivalis. Everything else was neglected. Eventually, some highly experimental tech experiment went haywire.");
next;
mesn;
mesq l("A fire broke out in Tulimshar's Academy, which quickly spread over the whole town... And you would think it would be all, but no. The fire was odd.");
next;
mesn;
mesq l("Instead of burning the town to a crisp, it moved to the canyon. Passed through the scarce vegetation until it arrived Hurnscald... And burned it down.");
next;
mesn;
mesq l("And by \"moved to the canyon\", I do mean it destroyed the little which kept our community alive back then. I heard the fire even moved to the icelands and burned everything on the path until it died at the frozen sea, but that would be too far for I know.");
next;
mesn;
mesq l("The great fire did very few causalities, but it destroyed a lot of infrastructure and ruined the economy. Famine and chaos ensued, we almost were wiped out back then. Maybe it would be best if we had indeed been wiped out...");
next;
.@hist = .@hist | 2;
break;
case 4:
mesn;
mesq l("As you might know, the Great Fire ruined the whole world. Many people wanted to escape the wastelands which the continent had became, so they made convoys and left to the great sea.");
next;
mesn;
mesq l("Such convoys had been made since the Civil War, after all, many feared the Red Queen and moving to the sea was a sure way to stay out of her reach. None had ever heard again of them...");
next;
mesn;
mesq l("...Until one day, past the sea, in Kolev's continent, they found a mana stone. Magic. This great breakthrough saved this continent, and saved our clan as well.");
next;
mesn;
mesq l("An academy was built north of Tulimshar, and later, the Land of Fire Village was also built, symbol of progress, development and research.");
next;
mesn;
mesq l("Which sound great in theory, but it was not. Greedy people found a way into power. They probably had good reasons, but they started confiscating Mana Stones, and storing them in a tower...");
next;
mesn;
mesq l("...A tower, on this canyon. People disliked it, humans and all other races. The Mana War happened, bloodshed, and... The Monster War.");
next;
.@hist = .@hist | 4;
break;
case 5:
mesn;
mesq l("The Monster War broke out on the very last day of the Mana War. A high council of Tulimshar had set a fortress and storage towers in the canyon, and a few populists went to war.");
next;
mesn;
mesq l("At the last day, an earthquake happened. And then, monsters started showing up everywhere. Immortal monsters, which come back after killed, as if they had touched the Soul Menhir.");
next;
mesn;
mesq l("And thus, the longest war begun... And our clan was wiped out. Pachua, Mirio, I, Melune and Darug are the last ones. Oh, and Andra, I guess?");
next;
mesn;
mesq l("The clan will end on this generation. And hopefully, the world will survive longer, things aren't looking well right now.");
next;
.@hist = .@hist | 8;
break;
case 6:
mesn;
mesq l("Mhm? I believe it was rebuilt, and the High Alliance took it over from the mage association for not paying taxes.");
next;
mesn;
mesq l("It is a magical tower, though, cloaked in the desert. You can't just walk there. The tower was north of here, you will find a sign near the gate... But you won't find the gate itself.");
next;
mesn;
mesq l("Maybe, if you had some sort of ancient artifact and touched the sign, it would allow you to see through the cloaking? Or if you were powerful enough. As if I would know!");
next;
break;
}
} while (@menu != 1);
close;
L_Episode:
if (getq(LoFQuest_EPISODE) != 11)
goto L_Main;
if (getq3(LoFQuest_EPISODE) &&
mobcount(getmap(), all) <= 0)
goto L_EpFinish;
if (getq3(LoFQuest_EPISODE) &&
mobcount(getmap(), all) > 0) {
npctalk l("Good luck, %s! There are more monsters nearby!", strcharinfo(0));
end;
}
setq3 LoFQuest_EPISODE, 1;
mesn;
mesq l("Uh? What are you doing here?!");
next;
select
l("I don't know?"),
l("How did I got here?"),
l("Who are you?");
mes "";
mesn;
mesq l("What have you done?! We're under attack!");
next;
mesn;
mesq l("Quick, battle position! They'll strike! I'll help you a tiny bit!");
mesc l("WARNING: You have a time limit!"), 1;
next;
instance_set_timeout(900, 900, getq2(LoFQuest_EPISODE));
SC_Bonus(90, SC_INCHITRATE, 50);
SC_Bonus(90, SC_INCMHPRATE, 65);
SC_Bonus(90, SC_KAIZEL, 80);
percentheal 100, 100;
.@m$ = getmap();
monster(.@m$, 42, 31, "Lost", BlueSlimeMother, 1);
monster(.@m$, 45, 31, "Lost", CopperSlimeMother, 1);
monster(.@m$, 43, 32, "Lost", YellowSlimeMother, 1);
monster(.@m$, 44, 32, "Lost", RedSlimeMother, 1);
monster(.@m$, 42, 33, "Lost", ChocolateSlimeMother, 1);
monster(.@m$, 45, 33, "Lost", WhiteSlimeMother, 1);
monster(.@m$, 43, 34, "Lost", AzulSlimeMother, 1);
monster(.@m$, 44, 34, "Lost", SeaSlimeMother, 1);
monster(.@m$, 45, 35, "Lost", GreenSlimeMother, 1);
//monster(.@m$, 47, 35, "Lost", LavaSlimeMother, 1);
monster(.@m$, 68, 30, "Lost", Thug, 1);
monster(.@m$, 70, 22, "Lost", Thug, 1);
monster(.@m$, 74, 42, "Lost", Thug, 1);
closeclientdialog;
close;
L_EpFinish:
// Cleanup
instance_set_timeout(900, 900, getq2(LoFQuest_EPISODE));
enablenpc instance_npcname("#004-3-1_70_25", getq2(LoFQuest_EPISODE));
enablenpc instance_npcname("#004-3-1_68_33", getq2(LoFQuest_EPISODE));
if (CHEST_MONEY) {
mesc l("You were refunded in %s GP!", fnum(CHEST_MONEY));
Zeny+=CHEST_MONEY;
CHEST_MONEY=0;
}
setq LoFQuest_EPISODE, 12;
getitem SacredLifePotion, 10;
getitem SacredImmortalityPotion, 5;
getexp 60000, 0;
// Final dialog
mesn;
mesq l("Phew... We should be safe now. Thanks, %s!", strcharinfo(0));
next;
mesn;
mesq l("...Even if this is your fault. Anyway, ##Breturn to whoever sent you here##b and begone.");
close;
OnInit:
.distance = 4;
.sex = G_OTHER;
end;
}
