path: root/npc/005-1/vincent.txt

// TMW2 scripts.
// Authors:
//    Saulc
// Variables:
//    CandorQuests_Vincent  - quest var


005-1,92,95,0	script	Vincent	NPC_MONA,{


    .BaitID = BugLeg;
    .BaitCount = 12;

    .@q = getq(CandorQuests_Vincent);
    if (.@q == 1) goto L_CheckItems;
    if (.@q == 2) goto L_QuestDone;

    speech S_LAST_BLANK_LINE,
        l("I made a figurin with Bug legs."),
        lg("Be a friend and bring me @@ @@.", "Be a friend and bring me @@ @@.", .BaitCount, getitemlink(.BaitID));

    switch (select(l("Ok, I'll be back in no time."),
                   l("Sorry, I'm doing other things at the moment.")))
    {
        case 1:
            setq CandorQuests_Vincent, 1;
            speech S_FIRST_BLANK_LINE,
                l("Thank you. I'll wait here.");
            close;
        case 2:
            speech S_FIRST_BLANK_LINE,
                l("But I'm almost out of @@...", getitemlink(.BaitID));
            close;
    }

L_CheckItems:
    if (countitem(.BaitID) < .BaitCount)
    {
        speech
            l("Sorry, but you don't have what I need."),
            l("I need @@ @@.", .BaitCount, getitemlink(.BaitID));
        close;
    }

    speech
        l("That's exactly what I needed!");

    delitem .BaitID, .BaitCount;
    Zeny = Zeny + 1000;
    message strcharinfo(0), l("You receive @@ GP!", 1000);
    setq CandorQuests_Vincent, 2;
    close;

L_QuestDone:
    speech
        l("Hey, @@!", strcharinfo(0)),
        l("My figurin is so nice!");
    close;

OnInit:
    .sex = G_MALE;
    .distance = 3;
    end;
}