path: root/npc/003-1/lieutenantdausen.txt

// TMW2 scripts.
// Authors:
//    Saulc
//    Jesusalva
//    acsvln
//    gnulinux
// Description:
//    Help Tulimshar guards
// Quest variable:
//    TulimsharQuests_Guards
// Quest stages:
//    0 - not started
//    1 - Lieutenant Dausen asked for help Tulimshar guards
//    2 - completed
//    3 - Reward given

003-1,111,84,0	script	Lieutenant Dausen	NPC_PLAYER,{
    // The Monster King guild have a special menu
    if (strcharinfo(2) == "Monster King") goto L_MKControl;

    .@has = getq(TulimsharQuest_WaterForGuard);

    switch (.@has) {
    case 0:
        callsub(L_Greetings);
        break;
    case 1:
        callsub(L_InProgress);
        break;
    case 2:
        callsub(L_Reward);
        break;
    case 3:
        callsub(L_QuestDone);
        break;
    default:
        end;
    }

    close;

    L_Greetings:
        speech S_LAST_BLANK_LINE, l("Greetings, wanderer. I am @@, chief of the Tulimshar guards. My wards are dying from dehydration in the sun. Bring them water and you will earn a reward.", .name$);

        select
            l("Yes sir. I will help them."),
            rif(getq(TulimsharQuest_Hasan) == 1, l("A guy named Hasan stole me!")),
            menuaction(l("Quit"));

        switch (@menu) {
        case 1:
            setq TulimsharQuest_WaterForGuard, 1;
            speech S_FIRST_BLANK_LINE, l("Good luck! Come for remuneration when you finish!");
            break;
        case 2:
            setq TulimsharQuest_Hasan, 2;
            speech S_FIRST_BLANK_LINE, lg("Ah, Hasan... Sorry pal, afraid I can't do anything for you. Try talking to his mother Sorfina, she is on Mahoud's house, near the Inn.");
            break;
        case 3:
            closedialog;
            goodbye;
            break;
        }
    return;

    L_InProgress:
        mesn;
        mesq l("Please help my wards!");
        if (getq(TulimsharQuest_Hasan) == 1) goto L_Hasan;
    return;

    L_Reward:
        mesn;
        mesq l("Thank you, here is your reward.");

        inventoryplace TulimsharGuardBoots, 1, TulimsharGuardCard, 1;
        getitem TulimsharGuardBoots, 1;
        getitem TulimsharGuardCard, 1;
        setq TulimsharQuest_WaterForGuard, 3;

        next;

        speech 0x0,
            l("Wait a minute..."),
            l("The Tulimshar guards needs an freelance employee who would help us in our work. We are searching for people as you."),
            l("Take this badge, so you can get access to the guard house. You will find more work there. Bye, and good luck!");
    return;

    L_QuestDone:
        mesn;
        mesq l("Thank you for your help.");
        if (getq(TulimsharQuest_Hasan) == 1) goto L_Hasan;
    return;

    L_Hasan:
        select
            rif(getq(TulimsharQuest_Hasan) == 1, l("A guy named Hasan stole me!")),
            menuaction(l("Quit"));

        switch (@menu) {
        case 1:
            setq TulimsharQuest_Hasan, 2;
            speech S_FIRST_BLANK_LINE, lg("Ah, Hasan... Sorry pal, afraid I can't do anything for you. Try talking to his mother Sorfina, she is on Mahoud's house, near the Inn.");
            break;
        default:
            closedialog;
            goodbye;
            break;
        }
    return;

L_MKControl:
    mesn;
    mes l("Oh noes! You've found the Tulimshar control panel!");
    menu
        l("Initiate small siege (lv. 20)"), L_MKSmall,
        l("Initiate medium siege (lv. 30)"), L_MKMedium,
        l("Initiate huge siege (lv. 40)"), L_MKHuge,
        l("Abort"), -;
    close;

L_MKSmall:
    addmapmask "003-1", 2;
    addmapmask "004-1", 2;
    changemusic "003-1", "mythica.ogg";
    disablenpc("Mana Stone");
    $@SIEGE_TULIM=0; // factor zero
    pvpon("003-1");
    pvpon("004-1");
    announce(l("##1WARNING! WARNING! Siege starting at Tulimshar!!"), bc_all);
    areamonster("004-1", 0, 0, 79, 81, l("Black Scorpion"), 1074, 10, "Lieutenant Dausen::OnBlackScorpionDeath");
    initnpctimer;
    close;

L_MKMedium:
    addmapmask "003-1", 2;
    addmapmask "004-1", 2;
    changemusic "003-1", "eric_matyas_ghouls.ogg";
    disablenpc("Mana Stone");
    $@SIEGE_TULIM=1; // factor one
    pvpon("003-1");
    pvpon("004-1");
    announce(l("##1WARNING! WARNING! Siege starting at Tulimshar!!"), bc_all);
    areamonster("004-1", 0, 0, 79, 81, l("Black Scorpion"), 1074, 15, "Lieutenant Dausen::OnBlackScorpionDeath");
    initnpctimer;
    close;

L_MKHuge:
    addmapmask "003-1", 2;
    addmapmask "004-1", 2;
    changemusic "003-1", "misuse.ogg";
    disablenpc("Mana Stone");
    $@SIEGE_TULIM=5; // factor five
    pvpon("003-1");
    pvpon("004-1");
    announce(l("##1WARNING! WARNING! Siege starting at Tulimshar!!"), bc_all);
    areamonster("004-1", 0, 0, 79, 81, l("Black Scorpion"), 1074, 30, "Lieutenant Dausen::OnBlackScorpionDeath");
    initnpctimer;
    close;

OnBlackScorpionDeath:
    areamonster("004-1", 0, 0, 79, 81, l("Black Scorpion"), 1074, 1, "Lieutenant Dausen::OnBlackScorpionDeath");
    if (rand(10000) <= 90+($@SIEGE_TULIM*10))
        getitem StrangeCoin, 1;
    end;

OnBlackScorpion2Death:
    areamonster("003-1", 0, 0, 120, 155, l("Black Scorpion"), 1074, 1, "Lieutenant Dausen::OnBlackScorpion2Death");
    if (rand(10000) <= 850+($@SIEGE_TULIM*100))
        getitem StrangeCoin, 1;
    end;

OnGreenSlimeDeath:
    areamonster("003-1", 0, 0, 120, 155, l("Green Slime"), 1085, 1, "Lieutenant Dausen::OnGreenSlimeDeath");
    if (rand(10000) <= 200+($@SIEGE_TULIM*100))
        getitem StrangeCoin, 1;
    end;

OnCandiedSlimeDeath:
    areamonster("003-1", 0, 0, 120, 155, l("Candied Slime"), 1089, 1, "Lieutenant Dausen::OnCandiedSlimeDeath");
    if (rand(10000) <= 150+($@SIEGE_TULIM*100))
        getitem StrangeCoin, 1;
    end;

OnManaGhostDeath:
    areamonster("003-1", 0, 0, 120, 155, l("Mana Ghost"), 1068, 1, "Lieutenant Dausen::OnManaGhostDeath");
    if (rand(10000) <= 900+($@SIEGE_TULIM*100))
        getitem StrangeCoin, 1;
    end;

OnLieutenantDeath:
    getitem StrangeCoin, 1;
    Karma=Karma+1;
    mapannounce("003-1", l("##2The Monster Lieutenant was defeated by @@!", strcharinfo(0)), bc_map);
    end;

OnColonelDeath:
    getitem StrangeCoin, 1;
    Karma=Karma+1;
    $MOST_HEROIC$=strcharinfo(0);
    mapannounce("003-1", l("##2The Monster Colonel was defeated by @@!", strcharinfo(0)), bc_map);
    end;

OnTimer5000:
    areamonster("004-1", 0, 0, 79, 81, "Black Scorpion", 1074, 5+$@SIEGE_TULIM, "Lieutenant Dausen::OnBlackScorpionDeath");
    areamonster("003-1", 0, 0, 120, 155, "Black Scorpion", 1074, 5+$@SIEGE_TULIM, "Lieutenant Dausen::OnBlackScorpion2Death");
    mapannounce("003-1", "##2Message to all Tulimshar NPCs: Take shelter!", bc_map);
    disablenpc "Ched";
    disablenpc "Aahna";
    disablenpc "Constable Perry";
    disablenpc "Cyndala";
    disablenpc "Eomie";
    disablenpc "Eugene";
    disablenpc "Gladys";
    disablenpc "Inac";
    disablenpc "Ishi";
    disablenpc "Itka";
    disablenpc "Jakod";
    disablenpc "Jerican";
    disablenpc "Mahoud";
    disablenpc "Marius The Bard";
    disablenpc "Michel";
    disablenpc "Neko";
    disablenpc "Nina The Traveler";
    disablenpc "Sarah";
    disablenpc "Silvia";
    disablenpc "Tamiloc";
    disablenpc "Tinris";
    disablenpc "#water_animation0";
    disablenpc "Sailors#003-1";
    end;

OnTimer15000:
    areamonster("004-1", 0, 0, 79, 81, ("Black Scorpion"), 1074, 5, "Lieutenant Dausen::OnBlackScorpionDeath");
    areamonster("003-1", 0, 0, 120, 155, ("Black Scorpion"), 1074, 10, "Lieutenant Dausen::OnBlackScorpion2Death");
    disablenpc "Aidan";
    disablenpc "Inar";
    disablenpc "Malivox";
    disablenpc "Estard";
    disablenpc "Malindou";
    disablenpc "Jhedia";
    disablenpc "Swezanne";
    disablenpc "Luca";
    disablenpc "Colin";
    end;

OnTimer60000:
    if ($@SIEGE_TULIM == 1) {
        mapannounce("003-1", "##1The Monster Lieutenant arrived!", bc_map);
        areamonster("003-1", 0, 0, 120, 155, ("Monster Lieutenant"), 1077, 1, "Lieutenant Dausen::OnLieutenantDeath");
    }
    areamonster("003-1", 0, 0, 120, 155, ("Black Scorpion"), 1074, 3, "Lieutenant Dausen::OnBlackScorpion2Death");
    areamonster("003-1", 0, 0, 120, 155, ("Green Slime"), 1085, 10+$@SIEGE_TULIM, "Lieutenant Dausen::OnGreenSlimeDeath");
    areamonster("003-1", 0, 0, 120, 155, ("Candied Slime"), 1089, 1+$@SIEGE_TULIM, "Lieutenant Dausen::OnCandiedSlimeDeath");
    end;

OnTimer120000:
    if ($@SIEGE_TULIM == 5) {
        mapannounce("003-1", "##1The Monster Colonel arrived!", bc_map);
        areamonster("003-1", 0, 0, 120, 155, ("Monster Colonel"), 1036, 1, "Lieutenant Dausen::OnColonelDeath");
    }
    areamonster("003-1", 0, 0, 120, 155, ("Slime Blast"), 1090, 15);
    areamonster("003-1", 0, 0, 120, 155, ("Black Scorpion"), 1074, 1, "Lieutenant Dausen::OnBlackScorpion2Death");
    areamonster("003-1", 0, 0, 120, 155, ("Green Slime"), 1085, 10, "Lieutenant Dausen::OnGreenSlimeDeath");
    areamonster("003-1", 0, 0, 120, 155, ("Mana Ghost"), 1068, 2, "Lieutenant Dausen::OnManaGhostDeath");
    end;

OnTimer180000:
    areamonster("003-1", 0, 0, 120, 155, ("Slime Blast"), 1090, 25);
    areamonster("003-1", 0, 0, 120, 155, ("Black Scorpion"), 1074, 1, "Lieutenant Dausen::OnBlackScorpion2Death");
    areamonster("003-1", 0, 0, 120, 155, ("Candied Slime"), 1089, 10, "Lieutenant Dausen::OnCandiedSlimeDeath");
    areamonster("003-1", 0, 0, 120, 155, ("Mana Ghost"), 1068, 2, "Lieutenant Dausen::OnManaGhostDeath");
    end;

OnTimer240000:
    areamonster("003-1", 0, 0, 120, 155, ("Slime Blast"), 1090, 25);
    areamonster("003-1", 0, 0, 120, 155, ("Black Scorpion"), 1074, 1, "Lieutenant Dausen::OnBlackScorpion2Death");
    areamonster("003-1", 0, 0, 120, 155, ("Mana Ghost"), 1068, 2, "Lieutenant Dausen::OnManaGhostDeath");
    end;

OnTimer300000:
    areamonster("003-1", 0, 0, 120, 155, ("Slime Blast"), 1090, 5);
    areamonster("003-1", 0, 0, 120, 155, ("Candied Slime"), 1089, 1, "Lieutenant Dausen::OnCandiedSlimeDeath");
    areamonster("003-1", 0, 0, 120, 155, ("Mana Ghost"), 1068, 1, "Lieutenant Dausen::OnManaGhostDeath");
    end;

OnTimer360000:
OnTimer420000:
OnTimer480000:
    areamonster("003-1", 0, 0, 120, 155, ("Slime Blast"), 1090, 5+$@SIEGE_TULIM);
    areamonster("003-1", 0, 0, 120, 155, ("Red Slime"), 1092, 1+$@SIEGE_TULIM);
    end;

OnTimer540000:
    mapannounce("003-1", "##1The Monster Army is getting tired of resistance!", bc_map);
    areamonster("003-1", 0, 0, 120, 155, ("Slime Blast"), 1090, 5+$@SIEGE_TULIM);
    areamonster("003-1", 0, 0, 120, 155, ("Mana Ghost"), 1068, 1, "Lieutenant Dausen::OnManaGhostDeath");
    end;

OnTimer600000:
    mapannounce("003-1", "##1The Monster King army is preparing to withdraw!", bc_map);
    end;

OnTimer630000:
    removemapmask "003-1", 2;
    removemapmask "004-1", 2;
    changemusic "003-1", "bartk_adventure.ogg"; // Restore to default
    enablenpc("Mana Stone");
    $@SIEGE_TULIM$=0;
    killmonsterall("003-1", 0);
    killmonsterall("004-1", 0);
    pvpoff("003-1");
    pvpoff("004-1");
    announce(("Tulimshar siege is over!"), bc_all);
    enablenpc "Ched";
    enablenpc "Aahna";
    enablenpc "Constable Perry";
    enablenpc "Cyndala";
    enablenpc "Eomie";
    enablenpc "Eugene";
    enablenpc "Gladys";
    enablenpc "Inac";
    enablenpc "Ishi";
    enablenpc "Itka";
    enablenpc "Jakod";
    enablenpc "Jerican";
    enablenpc "Mahoud";
    enablenpc "Marius The Bard";
    enablenpc "Michel";
    enablenpc "Neko";
    enablenpc "Nina The Traveler";
    enablenpc "Sarah";
    enablenpc "Silvia";
    enablenpc "Swezanne";
    enablenpc "Tamiloc";
    enablenpc "Tinris";
    enablenpc "#water_animation0";
    enablenpc "Aidan";
    enablenpc "Inar";
    enablenpc "Malivox";
    enablenpc "Luca";
    enablenpc "Colin";
    enablenpc "Estard";
    enablenpc "Malindou";
    enablenpc "Jhedia";
    enablenpc "Sailors#003-1";
    stopnpctimer;
    end;

OnInit:
    .sex = G_MALE;
    .distance = 4;
    end;
}
// Debug - purpose NPC
003-1,110,84,0	script	LieutenantDausenDebug	NPC_MONA,{
    showavatar NPC_MONA;  // this is handled by avatars.xml
    mesn;
    mesq l("Reset?");
    next;
    menu
        l("Yes."),  L_Reset,
        l("No."),   L_Close;

L_Reset:
    GUARDS_DONE_BITARRAY=0;
    setq TulimsharQuest_WaterForGuard, 0;
    mes l("Reset!");
    goto L_Close;

L_Close:
    //showavatar;  // Use this to hide the showavatar
    close;

// Use @shownpc to enable AyashaDebug
OnInit:
    if (!debug)
        disablenpc .name$;
    end;
}

// Render random guard answer after bringing him water
function	script	GuardsGratitude	{

    switch (rand(6))
    {
        case 0:
            .@message$ = l("God bless you! You have saved me from sweltering!");
            break;
        case 1:
            .@message$ = l("I am happy that such responsible citizens live in Tulimshar. Thank you for your help. It's really hot nowdays!");
            break;
        case 2:
            .@message$ = l("Thanks, this is very handy.");
            break;
        case 3:
            .@message$ = l("Our service is dangerous and difficult. But I would not want any other. Thanks for the help.");
            break;
        case 4:
            .@message$ = l("My mother told me, do not go work like a guard. You will die from overheating in the sun during the summer time.");
            break;
        case 5:
            .@message$ = l("Who are you? Thanks for the help.");
            break;
        default:
            .@message$="Thank you!";
            break;
    }

    // TODO: Maybe we should see the guard gender too, and if it's matching, pat. Otherwise, air kiss.
    if (Sex == SEX_FEMALE)
    {
        .@narrator_message$ = l("The Guard sends an air kiss to you.");
    } else {
        .@narrator_message$ = l("The Guard patted you on the back.");
    }

    speech S_LAST_BLANK_LINE, .@message$;
    narrator S_LAST_BLANK_LINE, .@narrator_message$;

    return;
}

// Do TulimsharQuest_WaterForGuard quest
function	script	CheckGuard	{
    .@guard_id = getarg(0);
    .@guard_count = 0;
    .@count_tmp = 0;

    if (debug)
        npctalk3 l("Hello, I am G-@@, of the @@ order.", .@guard_id, $@GuardBits[.@guard_id]);

    if (GUARDS_DONE_BITARRAY & $@GuardBits[.@guard_id])
    {
        mesn;
        mesq l("Thanks for help! Other guards may need help too!");
        close;
    } else {
        while (.@count_tmp < 18)
        {
            if (GUARDS_DONE_BITARRAY & $@GuardBits[.@count_tmp])
               .@guard_count = (.@guard_count + 1);

            .@count_tmp = (.@count_tmp + 1);
        }

        if ( countitem(BottleOfTonoriWater) == 0 ) {
            legiontalk;
        } else {
            delitem BottleOfTonoriWater, 1;
            getitem EmptyBottle, 1;

            getexp 30, 0;
            Zeny = (Zeny + 30);

            GUARDS_DONE_BITARRAY = GUARDS_DONE_BITARRAY | $@GuardBits[.@guard_id];
            setq2 TulimsharQuest_WaterForGuard, .@guard_count; // Update questlog

            if (.@guard_count >= 17) {
                message strcharinfo(0), "That must have been the last guard.";
                setq TulimsharQuest_WaterForGuard, 2;
            }

            GuardsGratitude();
            narrator("You receive 30 exp and 50 GP.");
            close;
        }
    }

    return;
}

// Handle Guard's logic
function	script	GuardHandler	{
    if (getq(TulimsharQuest_WaterForGuard) == 1) {
        CheckGuard(getarg(0));
    } else {
        legiontalk;
    }

    return;
}

003-1,98,100,0	script	Guard Philip	NPC_GUARD1,{
    GuardHandler(0);

    end;

OnTimer1000:
    domovestep;

OnInit:

    // Check items.xml for info about this.
    // NOTE: Why Dausen item list is on Philip...?
    .@npcId = getnpcid(0, "Lieutenant Dausen");
    setunitdata(.@npcId, UDT_HEADTOP, Bull);
    setunitdata(.@npcId, UDT_HEADMIDDLE, LegionTrainingShirt);
    setunitdata(.@npcId, UDT_HEADBOTTOM, RaidTrousers);
    setunitdata(.@npcId, UDT_SHIELD, LousyMoccasins);    // TODO FIXME: Display Boots
    setunitdata(.@npcId, UDT_WEAPON, ArtisBacksword);
    setunitdata(.@npcId, UDT_HAIRSTYLE, 7);
    setunitdata(.@npcId, UDT_HAIRCOLOR, 17);

    initpath "move", 98, 104,
             "dir", DOWN, 0,
             "wait", 60, 0,
             "move", 84, 100,
             "dir", DOWN, 0,
             "wait", 45, 0,
             "move", 93, 110,
             "dir", DOWN, 0,
             "wait", 70, 0,
             "move", 101, 106,
             "dir", RIGHT, 0,
             "wait", 12, 0,
             "move", 98, 104,
             "dir", DOWN, 0,
             "wait", 68, 0,
             "move", 93, 110,
             "dir", DOWN, 0,
             "wait", 90, 0,
             "move", 111, 109,
             "dir", DOWN, 0,
             "wait", 11, 0;
    initialmove;
    initnpctimer;
    .distance = 5;

    setarray $@GuardBits, 1, (1 << 1), (1 << 2), (1 << 3), (1 << 4), (1 << 5), (1 << 6), (1 << 7), (1 << 8), (1 << 9), (1 << 10), (1 << 11), (1 << 12), (1 << 13), (1 << 14), (1 << 15), (1 << 16), (1 << 17);
}
003-1,98,121,0	script	Guard Defou	NPC_GUARD1,{
    GuardHandler(1);
    end;
OnInit:
    .sex = G_OTHER;
    .distance = 3;
    end;
}
003-1,102,121,0	script	Guard Avou	NPC_GUARD1,{
    GuardHandler(2);
    end;
OnInit:
    .sex = G_OTHER;
    .distance = 3;
    end;
}
003-1,58,158,0	script	Guard Benji	NPC_GUARD1,{
    GuardHandler(3);
    end;
OnInit:
    .sex = G_OTHER;
    .distance = 3;
    end;
}
003-1,62,158,0	script	Guard Valou	NPC_GUARD1,{
    GuardHandler(4);
    end;
OnInit:
    .sex = G_OTHER;
    .distance = 3;
    end;
}
003-1,71,138,0	script	Guard Nutelo	NPC_GUARD1,{
    GuardHandler(5);
    end;
OnInit:
    .sex = G_OTHER;
    .distance = 3;
    end;
}
003-1,58,128,0	script	Guard Moustacha	NPC_GUARD1,{
    GuardHandler(6);
    end;
OnInit:
    .sex = G_OTHER;
    .distance = 3;
    end;
}
003-1,58,100,0	script	Guard Popaul	NPC_GUARD1,{
    GuardHandler(7);
    end;

OnTimer1000:
    domovestep;

OnInit:
    initpath "move", 58, 100,
             "dir", DOWN, 0,
             "wait", 100, 0,
             "move", 62, 100,
             "dir", DOWN, 0,
             "wait", 35, 0,
             "move", 62, 93,
             "dir", DOWN, 0,
             "wait", 48, 0,
             "move", 58, 104,
             "dir", DOWN, 0,
             "wait", 55, 0,
             "move", 54, 102,
             "dir", RIGHT, 0,
             "wait", 82, 0;

    initialmove;
    initnpctimer;
    .distance = 5;
}
003-1,51,73,0	script	Guard Yen	NPC_GUARD1,{
    GuardHandler(8);
    end;
OnInit:
    .sex = G_OTHER;
    .distance = 3;
    end;
}
003-2,41,37,0	script	Guard Yuna	NPC_GUARD2,{
    if (getq(TulimsharQuest_WaterForGuard) == 1)
    {
        CheckGuard(9);
    } else {
        npctalkonce l("I like to sing.");
    }
    end;
OnInit:
    .sex = G_FEMALE;
    .distance = 3;
    end;
}
003-1,54,52,0	script	Guard Maxim	NPC_GUARD1,{
    GuardHandler(10);
    end;

OnTimer1000:
    domovestep;

OnInit:
    initpath "move", 54, 52,
             "dir", DOWN, 0,
             "wait", 85, 0,
             "move", 54, 45,
             "dir", DOWN, 0,
             "wait", 70, 0,
             "move", 67, 30,
             "dir", LEFT, 0,
             "wait", 11, 0,
             "move", 49, 46,
             "dir", DOWN, 0,
             "wait", 55, 0,
             "move", 31, 41,
             "dir", LEFT, 0,
             "wait", 6, 0,
             "move", 35, 36,
             "dir", UP, 0,
             "wait", 9, 0,
             "move", 49, 52,
             "dir", DOWN, 0,
             "wait", 70, 0;
    initialmove;
    initnpctimer;
    .distance = 5;

}
003-1,50,36,0	script	Guard Totor	NPC_GUARD1,{
    GuardHandler(11);
    end;

OnTimer1000:
    domovestep;

OnInit:
    initpath "move", 50, 36,
             "dir", DOWN, 0,
             "wait", 45, 0,
             "move", 50, 39,
             "dir", DOWN, 0,
             "wait", 35, 0,
             "move", 35, 40,
             "dir", UP, 0,
             "wait", 1, 0,
             "move", 33, 34,
             "dir", DOWN, 0,
             "wait", 12, 0;
    initialmove;
    initnpctimer;
    .distance = 5;
}
003-1,53,36,0	script	Guard Roukin	NPC_GUARD1,{
    GuardHandler(12);
    end;

OnTimer1000:
    domovestep;

OnInit:
    initpath "move", 53, 36,
             "dir", DOWN, 0,
             "wait", 60, 0,
             "move", 56, 59,
             "dir", DOWN, 0,
             "wait", 1, 0,
             "move", 61, 76,
             "dir", RIGHT, 0,
             "wait", 5, 0,
             "move", 61, 105,
             "dir", RIGHT, 0,
             "wait", 8, 0,
             "move", 59, 129,
             "dir", LEFT, 0,
             "wait", 4, 0,
             "move", 60, 103,
             "dir", UP, 0,
             "wait", 1, 0,
             "move", 56, 82,
             "dir", LEFT, 0,
             "wait", 7, 0,
             "move", 56, 59,
             "dir", UP, 0,
             "wait", 1, 0,
             "move", 53, 39,
             "dir", DOWN, 0,
             "wait", 25, 0;
    initialmove;
    initnpctimer;
    .distance = 5;
}
003-1,35,34,0	script	Guard Falko	NPC_GUARD1,{
    GuardHandler(13);
    end;

OnTimer1000:
    domovestep;

OnInit:
    initpath "move", 35, 34,
             "dir", DOWN, 0,
             "wait", 60, 0,
             "move", 51, 38,
             "dir", DOWN, 0,
             "wait", 10, 0;
    initialmove;
    initnpctimer;
    .distance = 5;
}
003-3,39,37,0	script	Guard Malindax	NPC_GUARD1,{
    GuardHandler(14);
    end;
OnInit:
    .sex = G_OTHER;
    .distance = 3;
    end;
}
003-1,111,101,0	script	Guard Froma	NPC_GUARD1,{
    GuardHandler(15);
    end;
OnInit:
    .sex = G_OTHER;
    .distance = 3;
    end;
}
003-1,102,80,0	script	Guard Tetric	NPC_GUARD1,{
    GuardHandler(16);
    end;

OnTimer1000:
    domovestep;

OnInit:
    initpath "move", 110, 84,
             "dir", RIGHT, 0,
             "wait", 1, 0,
             "move", 110, 101,
             "dir", RIGHT, 0,
             "wait", 0, 0,
             "move", 99, 121,
             "dir", LEFT, 0,
             "wait", 1, 0,
             "move", 89, 136,
             "dir", DOWN, 0,
             "wait", 1, 0,
             "move", 65, 152,
             "dir", DOWN, 0,
             "wait", 1, 0,
             "move", 71, 139,
             "dir", RIGHT, 0,
             "wait", 1, 0,
             "move", 59, 128,
             "dir", LEFT, 0,
             "wait", 1, 0,
             "move", 47, 79,
             "dir", LEFT, 0,
             "wait", 1, 0,
             "move", 80, 73,
             "dir", RIGHT, 0,
             "wait", 1, 0,
             "move", 53, 52,
             "dir", RIGHT, 0,
             "wait", 1, 0,
             "move", 52, 37,
             "dir", RIGHT, 0,
             "wait", 1, 0,
             "move", 35, 35,
             "dir", RIGHT, 0,
             "wait", 1, 0,
             "move", 62, 105,
             "dir", DOWN, 0,
             "wait", 1, 0;
    initialmove;
    initnpctimer;
    .distance = 5;
}
003-1,107,80,0	script	Guard Biscop	NPC_GUARD1,{
    if (getq(TulimsharQuest_WaterForGuard) == 1)
    {
        CheckGuard(17);
    } else {
        npctalkonce l("No one is allowed past this point.");
    }
    end;
OnInit:
    .sex = G_OTHER;
    .distance = 3;
    end;
}


003-1,114,83,0	script	#tulim-guardhouse	NPC_HIDDEN,0,0,{
    end;

OnTouch:
    if (countitem(TulimsharGuardCard) >= 1) goto L_Warp;
    dispbottom l("Only Tulimshar Guards are allowed in this building.");
    end;

L_Warp:
    warp "003-10", 42, 79;
    end;
}