path: root/npc/003-1/hasan.txt

// TMW-2 Script
// Author:
//  Jesusalva
// Description:
//  Hasan is the city bully and steals the player. He lost his father to a Murderer
//  Scorpion. Will respect player if they kill one. His mother is Sorfina, whom
//  explains this and cries that he never touched a Soul Menhir. Allowing player
//  to kill scorpion on Mahoud's Basement.
//
//  Player must report theft first to Dausen, who will tell the player that's
//  normal and nobody messes with Hasan, and giving player pointer that he should
//  tell his mother, Sorfina.
//
//  Reward: Cotton Short, Hasan won't steal you anymore.
//
//  GETQ1 Variable Value;
//  0 - Never stolen by Hasan
//  1 - Already stolen by Hasan
//  2 - Dausen pointed player to Sorfina
//  3 - Sorfina unlocked Mahoud's Basement
//  4 - Player killed Murderer Scorpion
//  5 - Quest is complete

// Temporary sprite
003-1,62,148,0	script	Hasan	NPC_ELVEN_MAN_RED,2,2,{
    if (getq(TulimsharQuest_Hasan) == 0) goto L_Safe;
    if (getq(TulimsharQuest_Hasan) == 4) goto L_Finish;
    if (getq(TulimsharQuest_Hasan) == 5) goto L_Complete;
    mesn strcharinfo(0);
    mesq l("Give me back what you've stole, thief!");
    next;
    mesn;
    mesq l("I stole nothing from you. Do you have any proof?");
    next;
    menu
        l("I have a print screen!"), L_Print,
        l("No..."), L_Close;
    close;

L_Away:
    mesn;
    mesq l("Hey... Go bother someone else.");
    close;

L_Print:
    mes "";
    mesn;
    mesq l("Let me analyze that.");
    mes col("Hasan takes your print screen and analyzes it.",9);
    next;
    mesn;
    mesq l("Photoshopped. Definitely. Good luck convincing somebody with that! %%a");
    next;
    mesn;
    mesq l("If you go to Lieutenant Dausen, he'll say that you used Gimp. Just give up.");
    close;

// TODO
L_Finish:
    close;

L_Complete:
    mesn;
    mesq l("Thanks for avenging my father.");
    close;

L_TouchComplete:
    npctalk3 l("Hey there, @@! Good luck killing monsters!", strcharinfo(0));
    end;

L_Close:
    close;

OnTouch:
    if (getq(TulimsharQuest_Hasan) == 5) goto L_TouchComplete;
    if (Zeny > 15) goto L_Steal;
    end;

L_Steal:
    npctalk3("*whistle*");
    if (getq(TulimsharQuest_Hasan) == 0) goto L_DoSteal;
    if (getq(TulimsharQuest_Hasan) <= 4 && rand(0,100) < 20) goto L_DoSteal;
    end;

L_DoSteal:
    Zeny=Zeny-rand(3,12);
    if (getq(TulimsharQuest_Hasan) == 0)
        setq TulimsharQuest_Hasan, 1;
    dispbottom l("##BYou were stolen##b by an evil NPC.");
    end;

OnInit:
    .sex = G_MALE;
    .distance = 5;
    end;
}