// A professor at Tulimshar's magic academy
024-1.gat,72,94,0 script Eomie 164,{
set @month, 4;
set @start_day, 15;
set @end_day, 30;
if (gettime(6) == @month && gettime(5) >= @start_day && gettime(5) <= @end_day && QUEST_Easter11 == 4) goto L_Grass;
if (gettime(6) == @month && gettime(5) >= @start_day && gettime(5) <= @end_day && QUEST_Easter11 == 5) goto L_MakeGrass;
if (gettime(6) == @month && gettime(5) >= @start_day && gettime(5) <= @end_day && QUEST_Easter11 == 6) goto L_SeeBunny;
L_Greeting:
mes "[Eomie]";
mes "";
mes "\"I maintain this little spot of grass in the desert.\"";
close;
L_Grass:
mes "[Eomie]";
mes "";
mes "\"I maintain this little spot of grass in the desert.\"";
next;
menu
"It looks beautiful. I wish I could find a [Grass Liner] like this.", -;
mes "\"A [Grass Liner]? Last year I helped the Easter Bunny with a [Grass Liner] for his basket... It was really easy... Is this liner for yourself?\"";
next;
menu
"No. Actually, it is for the Easter Bunny again...", -;
mes "\"Why didn't you say so before? I can help you make the [Grass Liner] for the basket if you wish.\"";
menu
"I would really appreciate that!", -,
"Nah, I decided not to do that stupid quest.", L_End;
set QUEST_Easter11, 5;
L_MakeGrass:
mes "[Eomie]";
mes "";
mes "\"I will need you to bring me some [Grass Seed]s.\"";
mes "\"I think 5 seeds should be enough.\"";
mes "\"Squirrels tend to pick those up as they gather food.\"";
menu
"I have some seeds...", -,
"Ok, I will be back soon.", L_End,
"I changed my mind, forget about it.", L_End;
if(countitem("GrassSeed") < 5) goto L_EasterNotEnough;
if(countitem("GrassSeed") >= 5) goto L_EasterEnough;
close;
L_EasterNotEnough:
mes "[Eomie]";
mes "";
mes "\"You do not have enough [Grass Seed]s for me to work with yet.\"";
mes "\"Please go get more.\"";
close;
L_EasterEnough:
getinventorylist;
if (@inventorylist_count == 100 && countitem("GrassSeed") > 10) goto L_EasterTooMany;
if(countitem("GrassSeed") < 5) goto L_EasterNotEnough;
delitem "GrassSeed", 5;
getitem "GrassLiner", 1;
set QUEST_Easter11, 6;
mes "[Eomie]";
mes "";
mes "\"You have gathered enough [Grass Seed]s for me to grow the liner.\"";
mes "She plants the seeds and murmurs a spell over them.";
mes "You both watch the grass grow tall and when it's done growing,";
mes "she deftly gathers it for you.";
mes "\"Here is your [Grass Liner].\"";
close;
L_EasterTooMany:
mes "[Eomie]";
mes "";
mes "\"You don't have enough room for the [Grass Liner]. Come back later.\"";
close;
L_SeeBunny:
mes "[Eomie]";
mes "";
mes "\"You need to return to the Easter Bunny now.\"";
close;
L_End:
close;
}
