summaryrefslogtreecommitdiff
path: root/npc/029-1
diff options
context:
space:
mode:
Diffstat (limited to 'npc/029-1')
-rw-r--r--npc/029-1/_import.txt21
-rw-r--r--npc/029-1/_mobs.txt7
-rw-r--r--npc/029-1/_warps.txt7
-rwxr-xr-xnpc/029-1/aahna.txt9
-rwxr-xr-xnpc/029-1/barrier.txt21
-rwxr-xr-xnpc/029-1/dock.txt42
-rwxr-xr-xnpc/029-1/ferry_master.txt19
-rwxr-xr-xnpc/029-1/hasan.txt197
-rwxr-xr-xnpc/029-1/hideandseek.txt369
-rwxr-xr-xnpc/029-1/kaan.txt114
-rwxr-xr-xnpc/029-1/liana.txt38
-rwxr-xr-xnpc/029-1/mapflags.txt1
-rwxr-xr-xnpc/029-1/monster_guide.txt46
-rwxr-xr-xnpc/029-1/rewards_master.txt146
-rwxr-xr-xnpc/029-1/soul-menhir.txt15
-rwxr-xr-xnpc/029-1/traveler.txt7
-rwxr-xr-xnpc/029-1/tutorial.txt52
-rwxr-xr-xnpc/029-1/valon.txt137
-rwxr-xr-xnpc/029-1/vincent.txt134
-rwxr-xr-xnpc/029-1/zegas.txt94
20 files changed, 1476 insertions, 0 deletions
diff --git a/npc/029-1/_import.txt b/npc/029-1/_import.txt
new file mode 100644
index 00000000..b24b0973
--- /dev/null
+++ b/npc/029-1/_import.txt
@@ -0,0 +1,21 @@
+// Map 029-1: Candor Island
+// This file is generated automatically. All manually added changes will be removed when running the Converter.
+"npc/029-1/_mobs.txt",
+"npc/029-1/_warps.txt",
+"npc/029-1/aahna.txt",
+"npc/029-1/barrier.txt",
+"npc/029-1/dock.txt",
+"npc/029-1/ferry_master.txt",
+"npc/029-1/hasan.txt",
+"npc/029-1/hideandseek.txt",
+"npc/029-1/kaan.txt",
+"npc/029-1/liana.txt",
+"npc/029-1/mapflags.txt",
+"npc/029-1/monster_guide.txt",
+"npc/029-1/rewards_master.txt",
+"npc/029-1/soul-menhir.txt",
+"npc/029-1/traveler.txt",
+"npc/029-1/tutorial.txt",
+"npc/029-1/valon.txt",
+"npc/029-1/vincent.txt",
+"npc/029-1/zegas.txt",
diff --git a/npc/029-1/_mobs.txt b/npc/029-1/_mobs.txt
new file mode 100644
index 00000000..a1a75148
--- /dev/null
+++ b/npc/029-1/_mobs.txt
@@ -0,0 +1,7 @@
+// This file is generated automatically. All manually added changes will be removed when running the Converter.
+// Map 029-1: Candor Island mobs
+029-1,46,48,2,0 monster Alizarin Plant 1037,1,10000,120000
+029-1,73,93,7,6 monster Piou 1002,8,100000,30000
+029-1,90,35,7,5 monster Gold Vein 1046,16,100000,30000
+029-1,93,100,10,9 monster Gold Vein 1046,8,100000,30000
+029-1,43,43,15,11 monster Piousse 1003,2,100000,30000
diff --git a/npc/029-1/_warps.txt b/npc/029-1/_warps.txt
new file mode 100644
index 00000000..dd68e552
--- /dev/null
+++ b/npc/029-1/_warps.txt
@@ -0,0 +1,7 @@
+// This file is generated automatically. All manually added changes will be removed when running the Converter.
+// Map 029-1: Candor Island warps
+029-1,40,88,0 warp #029-1_40_88 0,0,029-2,29,61
+029-1,44,83,0 warp #029-1_44_83 0,0,029-2,22,92
+029-1,52,84,0 warp #029-1_52_84 0,0,029-2,103,61
+029-1,58,79,0 warp #029-1_58_79 0,0,029-2,94,30
+029-1,49,77,0 warp #029-1_49_77 0,0,029-2,24,123
diff --git a/npc/029-1/aahna.txt b/npc/029-1/aahna.txt
new file mode 100755
index 00000000..3ae76a28
--- /dev/null
+++ b/npc/029-1/aahna.txt
@@ -0,0 +1,9 @@
+029-1,71,52,0 script Aahna NPC404,{
+ @npc_distance = 3;
+ callfunc "PCtoNPCRange";
+ if(@npc_check) end;
+
+ mes "[Aahna]";
+ mes "\"Hello, What a lovely day for a stroll.\"";
+ close;
+}
diff --git a/npc/029-1/barrier.txt b/npc/029-1/barrier.txt
new file mode 100755
index 00000000..825f2d0c
--- /dev/null
+++ b/npc/029-1/barrier.txt
@@ -0,0 +1,21 @@
+029-1,69,61,0 script #CandorBarrier NPC45,0,0,{
+ if ($@FIGHT_CAVE_STATUS == 1) goto L_Block;
+ if (BaseLevel < 40) goto L_Block;
+ warp "029-3", 49, 53;
+ end;
+
+L_Block:
+ message strcharinfo(0), "Some force seems to be blocking you from entering.";
+ end;
+}
+
+029-1,69,61,0 script #CandorAnnouncer NPC32767,{
+ end;
+OnTalk:
+ if (BaseLevel >= 40) announce "Parua : " + $@candor_npctalk$, 3; // do not show these to newbies
+ end;
+
+OnCommandTalk:
+ areatimer 0, "029-1", 61, 61, 69, 73, 0, "#CandorAnnouncer::OnTalk";
+ end;
+}
diff --git a/npc/029-1/dock.txt b/npc/029-1/dock.txt
new file mode 100755
index 00000000..c40f3646
--- /dev/null
+++ b/npc/029-1/dock.txt
@@ -0,0 +1,42 @@
+
+029-1,46,111,0 script Candor Dock NPC400,1,0,{
+ @npc_distance = 1;
+ callfunc "PCtoNPCRange";
+ if(@npc_check) end;
+ callfunc "BoardCandorFerry";
+ end;
+}
+
+029-1,51,118,0 script Candor Koga NPC395,8,7,{
+ @npc_distance = 8;
+ callfunc "PCtoNPCRange";
+ if(@npc_check) end;
+ callfunc "BoardCandorFerry";
+ end;
+
+OnTouch:
+ addtimer get(.warp_delay, "#FerryConfig"), strnpcinfo(0)+"::OnBoard";
+ end;
+
+OnBoard:
+ callfunc "BoardCandorFerry";
+ end;
+}
+
+029-1,55,110,0 script #CandorDock NPC32767,{
+ end;
+OnCommandArrive:
+ disablenpc "Candor Dock";
+ enablenpc "Candor Koga";
+ areatimer 0, "029-1", 39, 111, 53, 113, get(.warp_delay, "#FerryConfig"), strnpcinfo(0)+"::OnAreaWarp"; // warp players on dock
+ end;
+
+OnAreaWarp:
+ callfunc "BoardCandorFerry";
+ end;
+
+OnCommandWarp:
+ disablenpc "Candor Koga";
+ enablenpc "Candor Dock";
+ end;
+}
diff --git a/npc/029-1/ferry_master.txt b/npc/029-1/ferry_master.txt
new file mode 100755
index 00000000..8828ee71
--- /dev/null
+++ b/npc/029-1/ferry_master.txt
@@ -0,0 +1,19 @@
+
+029-1,45,107,0 script Ferry Master#candor NPC138,{
+ mes "[Ferry Master]";
+ mes "\"Hello! Do you need something?\"";
+ goto L_Main;
+
+L_Main:
+ menu
+ "How do I use the ferry?", L_Explain,
+ "Nothing I guess", L_close;
+
+L_Explain:
+ mes "[Ferry Master]";
+ callfunc "FerryHelp";
+ goto L_Main;
+
+L_close:
+ close;
+}
diff --git a/npc/029-1/hasan.txt b/npc/029-1/hasan.txt
new file mode 100755
index 00000000..0a3dde08
--- /dev/null
+++ b/npc/029-1/hasan.txt
@@ -0,0 +1,197 @@
+
+029-1,35,33,0 script Scared Man NPC160,{
+ callfunc "PCtoNPCRange";
+ if(@npc_check) end;
+
+ if (QL_BEGIN >= 13)
+ goto L_TutDone;
+ message strcharinfo(0), "He looks too afraid to say anything.";
+ goto L_End;
+
+L_TutDone:
+ message strcharinfo(0), "Thanks. Hasan has been much nicer to me now";
+ goto L_End;
+
+L_End:
+ end;
+}
+029-1,33,33,0 script Hasan NPC189,3,3,{
+ callfunc "PCtoNPCRange";
+ if(@npc_check) end;
+ goto L_Main;
+
+L_Main:
+ if ((getcharid(3) == $@ScorpionFighter) || ($@ScorpionFighter && $@ScorpionFighter != getcharid(3)))
+ goto L_Afraid;
+ if (QL_BEGIN == 14)
+ goto L_TutDone;
+ if (QL_BEGIN == 13)
+ goto L_Thank;
+ if (QL_BEGIN == 12)
+ goto L_Trick;
+ if ((QL_BEGIN == 9) || (QL_BEGIN == 10) || (QL_BEGIN == 11))
+ goto L_FightAgain;
+
+ mes "You over hear some people nearby.";
+ mes "[Unfriendly Guy]";
+ mes "\"I told you if you didn't get the money, I'd give you swimming lessons, Haha!\"";
+ mes "[Scared Man]";
+ mes "\"But the only person I need protection from is you.\"";
+ mes "[Unfriendly Guy]";
+ mes "\"Thats why the price is so high.\"";
+ mes "\"Because I'm the toughest person in all of Candor\"";
+ mes "[Scared Man]";
+ mes "\"No, your just a mean bully. Wait till I tell the guards about this!\"";
+ mes "[Unfriendly Guy]";
+ mes "\"You do that and the next swimming lesson will be sleeping with the fishes.\"";
+ mes "[Scared Man]";
+ mes "\"No, please don't. *sob*\"";
+ mes "Sounds like this person is in trouble.\"";
+ QL_BEGIN = 9;
+ mes "[Unfriendly Guy]";
+ mes "\"What are you looking at?\"";
+ menu
+ "What ever you call maggot slime scrapped off a boat after a walk through the sewers.", L_Fight,
+ "Who me? I saw nothing, just passing by.", L_close;
+
+L_FightAgain:
+ mes "[Hasan]";
+ mes "\"Have you come back for a thrashing?\"";
+ menu
+ "No.", L_close,
+ "Yes.", L_Fight;
+
+L_Fight:
+ mes "[Hasan]";
+ mes "\"Do you really think you can beat me?\"";
+ mes "He pulls out a nasty looking dagger and stabs it in your direction.";
+ Hp = 1;
+ mes "That hurt! You begin to think searching for a different solution might be healthier.";
+ mes "Maybe Kaan can help?";
+ goto L_close;
+
+L_Trick:
+ mes "[Hasan]";
+ mes "\"Have you come back for another thrashing?\"";
+ menu
+ "No.",L_close,
+ "Yes, yours! (Scratch your head.)",L_ScratchHead;
+
+L_ScratchHead:
+ if ($@ScorpionFighter)
+ goto L_Wait;
+ $@ScorpionTimer = 0;
+ $@ScorpionFighter = getcharid(3);
+ $@ScorpDeath = PC_DIE_COUNTER;
+ donpcevent "#ScorpionTrigger::OnCommandHasanSpawn";
+ specialeffect 22;
+ mes "While you're scratching your head, a scorpion appears.";
+ close;
+
+L_Thank:
+ mes "[Hasan]";
+ mes "\"You - you saved me!";
+ mes "I was mean to people, but you still saved me!\"";
+ mes "\"Hey, you're a really cool person.";
+ mes "I mean, the way you finished that ghastly scorpion!";
+ mes "Amazing!\"";
+ mes "\"Let me tell you something, I will no longer bully people.";
+ mes "And you can have my Sharp Knife.\"";
+ getitem "SharpKnife", 1;
+ QL_BEGIN = 14;
+ mes "\"You want to go to Hurnscald, right? Shall I tell you how to get there?\"";
+ menu
+ "Sure, thanks.",L_HasanThanks,
+ "I'll try to find the way myself.",L_Explore;
+
+L_HasanThanks:
+ mes "[Hasan]";
+ mes "\"Ok, when you leave here go back to the city. Wait on the south end of";
+ mes "the city for the ferry to arrive at the docks. It will take you to Hurnscald.\"";
+ goto L_close;
+
+L_Explore:
+ mes "[Hasan]";
+ mes "\"Alright. Take care!\"";
+ goto L_close;
+
+L_TutDone:
+ mes "[Hasan]";
+ mes "\"You didn't see anything. I tell you what I'll be nicer if you don't tell anyone?\"";
+ menu
+ "As long as you learned your lesson.", L_TutCont;
+
+L_TutCont:
+ mes "\"I have, I promise not to bully people anymore. It's not fun being scared.\"";
+ goto L_close;
+
+L_Wait:
+ mes "There is a scorpion near Hasan already. I think Kaan is helping someone else... Maybe I should try the plan later.";
+ goto L_close;
+
+L_Afraid:
+ message strcharinfo(0), "Hasan: \"" + strcharinfo(0) + "! Please help me!\"";
+ end;
+
+L_close:
+ close;
+
+OnTouch:
+ if (QL_BEGIN >= 13)
+ end;
+ goto L_Main;
+}
+029-1,0,0,0 script #ScorpionTrigger NPC32767,{
+ end;
+
+OnCommandHasanSpawn:
+ goto L_Summon;
+
+L_Summon:
+ monster "029-1",33,33,"WeakScorpion",1046,1, "#ScorpionTrigger::OnScorpionDeath";
+ initnpctimer;
+ end;
+
+L_SummonAgain:
+ message strcharinfo(0), "Kaan is mad at you for your interference! He summons a rock above your head, then summons another scorpion near Hasan!";
+ heal -Hp, 0;
+ goto L_Summon;
+
+OnTimer5000:
+ if (attachrid($@ScorpionFighter) == 0)
+ goto L_Clean;
+ $@ScorpionTimer = $@ScorpionTimer + 5;
+ if ($@ScorpionTimer >= 300)
+ goto L_TimeOut;
+ if (PC_DIE_COUNTER > $@ScorpDeath)
+ goto L_MessageDeath;
+ setnpctimer 0;
+ end;
+
+OnScorpionDeath:
+ if (getcharid(3) != $@ScorpionFighter)
+ goto L_SummonAgain;
+ if (QL_BEGIN != 12)
+ goto L_Clean;
+ QL_BEGIN = 13;
+ message strcharinfo(0), "You saved Hasan.";
+ @mobId = 1003;
+ callfunc "MobPoints";
+ goto L_Clean;
+
+L_TimeOut:
+ message strcharinfo(0), "Hasan, with his eyes almost closed, trembling with fear, runs toward the scorpion and stabs it with all his strength!";
+ goto L_Clean;
+
+L_MessageDeath:
+ message strcharinfo(0), "Ouch... I should be more careful when fighting these monsters.";
+ goto L_Clean;
+
+L_Clean:
+ killmonster "029-1", "#ScorpionTrigger::OnScorpionDeath";
+ $@ScorpionFighter = 0;
+ $@ScorpionTimer = 0;
+ $@ScorpDeath = 0;
+ stopnpctimer;
+ end;
+}
diff --git a/npc/029-1/hideandseek.txt b/npc/029-1/hideandseek.txt
new file mode 100755
index 00000000..cc7f0dbf
--- /dev/null
+++ b/npc/029-1/hideandseek.txt
@@ -0,0 +1,369 @@
+
+- script #hideandseekNTconfig NPC32767,{
+ end;
+
+OnInit:
+ $@hideandseekNT_started = (1 << 0);
+ $@hideandseekNT_found1 = (1 << 1);
+ $@hideandseekNT_found2 = (1 << 2);
+ $@hideandseekNT_found3 = (1 << 3);
+ $@hideandseekNT_found4 = (1 << 4);
+ $@hideandseekNT_found5 = (1 << 5);
+ $@hideandseekNT_ended = (1 << 6);
+ end;
+}
+function script CountHideNSeek {
+ @hidden_kid_cnt = 0;
+ if (QL_HIDENSEEK & $@hideandseekNT_found1)
+ @hidden_kid_cnt = (@hidden_kid_cnt + 1);
+ if (QL_HIDENSEEK & $@hideandseekNT_found2)
+ @hidden_kid_cnt = (@hidden_kid_cnt + 1);
+ if (QL_HIDENSEEK & $@hideandseekNT_found3)
+ @hidden_kid_cnt = (@hidden_kid_cnt + 1);
+ if (QL_HIDENSEEK & $@hideandseekNT_found4)
+ @hidden_kid_cnt = (@hidden_kid_cnt + 1);
+ if (QL_HIDENSEEK & $@hideandseekNT_found5)
+ @hidden_kid_cnt = (@hidden_kid_cnt + 1);
+ return;
+}
+029-1,64,90,0 script AyashaDebug NPC258,{
+ mes "[Ayasha Debug]";
+ menu
+ "Show", L_Show,
+ "Reset", L_Reset,
+ "Close.", L_close;
+
+L_Show:
+ mes "State: " + QL_HIDENSEEK;
+ if (QL_HIDENSEEK & $@hideandseekNT_started)
+ mes "Start set";
+ if (QL_HIDENSEEK & $@hideandseekNT_found1)
+ mes "Found 1 set";
+ if (QL_HIDENSEEK & $@hideandseekNT_found2)
+ mes "Found 2 set";
+ if (QL_HIDENSEEK & $@hideandseekNT_found3)
+ mes "Found 3 set";
+ if (QL_HIDENSEEK & $@hideandseekNT_found4)
+ mes "Found 4 set";
+ if (QL_HIDENSEEK & $@hideandseekNT_found5)
+ mes "Found 5 set";
+ if (QL_HIDENSEEK & $@hideandseekNT_ended)
+ mes "Complete set";
+ goto L_close;
+
+L_Reset:
+ QL_HIDENSEEK = 0;
+ goto L_close;
+
+L_close:
+ close;
+
+OnInit:
+ if (!debug)
+ disablenpc "AyashaDebug";
+ end;
+}
+029-1,62,90,0 script Ayasha NPC258,{
+ @child_number = 0;
+ callfunc "XmasList";
+
+ @Exp = 75;
+
+ if (QL_HIDENSEEK > 63) goto L_Done;
+ if (QL_HIDENSEEK == 63) goto L_Reward;
+ if (QL_HIDENSEEK > 0) goto L_Doing;
+
+ mes "You see a girl who is holding her hands in front of her face.";
+ mes "[Ayasha]";
+ mes "\"98... 99... 100!\"";
+ mes "She takes away her hands and looks up.";
+ menu
+ "Hello, what are you doing?",L_Next,
+ "(Leave)",L_close;
+
+L_Next:
+ mes "[Ayasha]";
+ mes "\"I'm playing hide and seek with my friends!";
+ mes "Do you want to play with us?\"";
+ menu
+ "Sure, sounds like fun.",L_Next1,
+ "I'm busy with more important things!",L_close;
+
+L_Next1:
+ mes "[Ayasha]";
+ mes "\"Great! You can take my turn with searching. You need to find all five of my friends.";
+ mes "They're hiding somewhere on the island, you will have to explore to find them. They could be hiding anywhere.\"";
+
+ QL_HIDENSEEK = QL_HIDENSEEK | $@hideandseekNT_started;
+ goto L_close;
+
+L_Doing:
+ callfunc "CountHideNSeek";
+ mes "[Ayasha]";
+ mes "\"You still need to find some of my friends. You have found " + @hidden_kid_cnt + " out of 5 of my friends.\"";
+ mes "\"Remember, they're hiding somewhere on the island, you will have to explore to find them. They could be hiding anywhere.\"";
+ goto L_close;
+
+L_Reward:
+ mes "[Ayasha]";
+ mes "\"Oh, you found them all! Good job! Now it's my turn with searching again. Go and hide!\"";
+ getexp @Exp, 0;
+ QL_HIDENSEEK = QL_HIDENSEEK | $@hideandseekNT_ended;
+ menu
+ "I think I need to do other things now.",L_Next2;
+
+L_Next2:
+ mes "[Ayasha]";
+ mes "\"Oh, ok.";
+ mes "Have you already seen Hurnscald? It's a very exciting place! I love the entertainer. She can make so many funny faces.\"";
+ goto L_close;
+
+L_Done:
+ mes "[Ayasha]";
+ mes "\"Hello! It was fun to play with you.";
+ mes "When you go to the Hurnscald, you can say hello to Mikhail. He's very nice! But very shy.\"";
+ goto L_close;
+
+L_close:
+ @Exp = 0;
+ close;
+}
+
+029-1,50,105,0 script Latif NPC262,{
+ @child_number = 1;
+ callfunc "XmasList";
+ @Exp = 15;
+
+ if (QL_HIDENSEEK > 63) goto L_Done;
+ if ((QL_HIDENSEEK > 0) && !(QL_HIDENSEEK & $@hideandseekNT_found1)) goto L_Find;
+ if (QL_HIDENSEEK > 0) goto L_Doing;
+
+ mes "You see a kid hiding behind a box.";
+ menu
+ "What are you doing there?",L_Next,
+ "(Leave)",L_close;
+
+L_Next:
+ mes "[Latif]";
+ mes "\"Hiding. We're playing hide and seek. Don't say that is boring. It's fun.\"";
+ menu
+ "I agree, it's fun.",L_Agree,
+ "Hide and seek? Lame.",L_Next1;
+
+L_Next1:
+ mes "[Latif]";
+ mes "\"My friend Vincent thinks so too. He doesn't join us playing.";
+ mes "Do you know what he does instead? He builds action figures out of Bug Legs! That is lame.\"";
+ goto L_close;
+
+L_Agree:
+ mes "[Latif]";
+ mes "\"Yeah, right? My friend Vincent doesn't thinks so. He doesn't join us playing.";
+ mes "Do you know what he does instead? He builds action figures out of Bug Legs! That is lame.\"";
+ goto L_close;
+
+L_Find:
+ mes "[Latif]";
+ mes "\"Hey! Ah, you found me. Well done. But my hiding place wasn't that difficult this time.\"";
+ getexp @Exp, 0;
+ QL_HIDENSEEK = QL_HIDENSEEK | $@hideandseekNT_found1;
+ mes "\"Here, do you want a candy?\"";
+ getitem "Candy", 1;
+ goto L_close;
+
+L_Doing:
+ callfunc "CountHideNSeek";
+ mes "[Latif]";
+ mes "\"You didn't find all of us yet? Seems like the other ones found a better place to hide.\"";
+ mes "\"" + @hidden_kid_cnt + " out of 5 have been found.\"";
+ goto L_close;
+
+L_Done:
+ mes "[Latif]";
+ mes "\"The northeastern most building of town is a workshop. My father works there and wants me to do that too when I'm grown up. But I don't want do that! I want to go on an adventure! Just like you.\"";
+ goto L_close;
+
+L_close:
+ @Exp = 0;
+ close;
+}
+
+029-1,48,67,0 script Charda NPC260,{
+ @child_number = 2;
+ callfunc "XmasList";
+ @Exp = 15;
+
+ if (QL_HIDENSEEK > 63) goto L_Done;
+ if ((QL_HIDENSEEK > 0) && !(QL_HIDENSEEK & $@hideandseekNT_found2)) goto L_Find;
+ if (QL_HIDENSEEK > 0) goto L_Doing;
+
+ mes "[Charda]";
+ mes "\"Hello. Psht, be careful. I'm playing hide and seek with Ayasha. You'll draw attention to my hiding place.\"";
+ mes "\"They will never find me here.\"";
+ goto L_close;
+
+L_Find:
+ mes "[Charda]";
+ mes "\"Oh! Got me! You're good at this.\"";
+ getexp @Exp, 0;
+ QL_HIDENSEEK = QL_HIDENSEEK | $@hideandseekNT_found2;
+ mes "She takes something out of her pocket.";
+ mes "\"I'm hungry now. Do you want chocolate too?\"";
+ getitem "ChocolateBar", 1;
+ mes "\"My mom doesn't want me to eat so much chocolate, but I got it from the trader at the Hurnscald Market. He sells many different things";
+ mes "when we goto vacation in Hurnscald. I convinced him to teach me how to trade. It's fun.\"";
+ goto L_close;
+
+L_Doing:
+ callfunc "CountHideNSeek";
+ mes "[Charda]";
+ mes "\"Did you find the others yet?\"";
+ mes "\"Hrmm, no looks like only " + @hidden_kid_cnt + " out of 5 have been found.\"";
+ goto L_close;
+
+L_Done:
+ mes "[Charda]";
+ mes "\"Hey! We're still playing hide and seek. What are you going to do? Will you go to Hurnscald with the ferry? The mother of my friends Rossy and Julia come from there. They are on a vacation there at the moment.\"";
+ mes "\"Rossy told me that it's a very beautiful place. Lots of trees and flowers and grass, everything's green.\"";
+ mes "She sighs.";
+ mes "[Charda]";
+ mes "\"Sounds wonderful.\"";
+ goto L_close;
+
+L_close:
+ @Exp = 0;
+ close;
+}
+
+029-1,100,36,0 script Faris NPC259,{
+ @child_number = 3;
+ callfunc "XmasList";
+ @Exp = 25;
+
+ if (QL_HIDENSEEK > 63) goto L_Done;
+ if ((QL_HIDENSEEK > 0) && !(QL_HIDENSEEK & $@hideandseekNT_found3)) goto L_Find;
+ if (QL_HIDENSEEK > 0) goto L_Doing;
+
+ mes "[Faris]";
+ mes "\"Oh, hi there. What are you doing here on the beach?\"";
+ menu
+ "I'm just having a look around.",L_Next,
+ "It's nice place here, isn't it?",L_Next;
+
+L_Next:
+ mes "[Faris]";
+ mes "\"Hey, you're cool. I'm hiding here from Ayasha, we're playing hide and seek. This is the best hiding place ever.\"";
+ goto L_close;
+
+L_Find:
+ mes "[Faris]";
+ mes "\"You found me! Well done. You look a bit thirsty, here.\"";
+ getexp @Exp, 0;
+ getitem "CactusDrink", 1;
+ QL_HIDENSEEK = QL_HIDENSEEK | $@hideandseekNT_found3;
+ mes "\"It's really cool you're playing with us. I'm sure you have a lot of other things to do.";
+ mes "You're an adventurer, right? I want to become an adventurer too when I'm grown up. I'll talk to Aidan then.\"";
+ mes "\"Aidan is outside Sorfina's place and you can register there for monster points. That's something the Wizard's Council made up. They reward you for slaying monsters. It's so cool.\"";
+ goto L_close;
+
+L_Doing:
+ callfunc "CountHideNSeek";
+ mes "[Faris]";
+ mes "\"Are you still searching for the others? Nobody else is here.\"";
+ mes "\"It seems you found " + @hidden_kid_cnt + " out of 5 of my friends.\"";
+ goto L_close;
+
+L_Done:
+ mes "[Faris]";
+ mes "\"I'll go to Hurnscald's Inn and ask Bernard for some soup when we're done with playing. His soup is delicious!\"";
+ goto L_close;
+
+L_close:
+ @Exp = 0;
+ close;
+}
+
+029-1,28,52,0 script Rasin NPC263,{
+ @child_number = 4;
+ callfunc "XmasList";
+
+ @Exp = 15;
+
+ if (QL_HIDENSEEK > 63) goto L_Done;
+ if ((QL_HIDENSEEK > 0) && !(QL_HIDENSEEK & $@hideandseekNT_found4)) goto L_Find;
+ if (QL_HIDENSEEK > 0) goto L_Doing;
+
+ mes "[Rasin]";
+ mes "\"The harbor is to the south from here. There you can take a ferry to other places.";
+ mes "And now go away, I'm playing hide and seek and Ayasha shouldn't see me here. You'll draw her attention when you talk to me.\"";
+ goto L_close;
+
+L_Find:
+ mes "[Rasin]";
+ mes "\"Ah, you found me. I need to find a better place to hide next time.\"";
+ getexp @Exp, 0;
+ QL_HIDENSEEK = QL_HIDENSEEK | $@hideandseekNT_found4;
+ goto L_close;
+
+L_Doing:
+ callfunc "CountHideNSeek";
+ mes "[Rasin]";
+ mes "\"Hehe, I'm curious when you'll have found all of us.\"";
+ mes "\"There are " + @hidden_kid_cnt + " out of 5 found.\"";
+ goto L_close;
+
+L_Done:
+ mes "[Rasin]";
+ mes "\"Thanks for playing with us! It was fun!";
+ mes "Will you leave Candor to go on an adventure in other places of the world?\"";
+ goto L_close;
+
+L_close:
+ @Exp = 0;
+ close;
+}
+
+029-1,79,99,0 script Ghada NPC265,{
+ @child_number = 5;
+ callfunc "XmasList";
+
+ @Exp = 15;
+
+ if (QL_HIDENSEEK > 63) goto L_Done;
+ if ((QL_HIDENSEEK > 0) && !(QL_HIDENSEEK & $@hideandseekNT_found5)) goto L_Find;
+ if (QL_HIDENSEEK > 0) goto L_Doing;
+
+ mes "You see a girl standing behind the wheat. She has a look of intense concentration on her face.";
+ menu
+ "Hi, what are you doing there?",L_Next,
+ "(Leave)",L_close;
+
+L_Next:
+ mes "[Ghada]";
+ mes "\"Oh, hello. I'm hiding. We're playing hide and seek.\"";
+ goto L_close;
+
+L_Find:
+ mes "[Ghada]";
+ mes "\"Oh no! You found me! You must be very clever.";
+ mes "My friend Sandra is clever too, but she said it's a waste of time to play hide and seek.\"";
+ getexp @Exp, 0;
+ QL_HIDENSEEK = QL_HIDENSEEK | $@hideandseekNT_found5;
+ goto L_close;
+
+L_Doing:
+ callfunc "CountHideNSeek";
+ mes "[Ghada]";
+ mes "\"Are you still searching for the others? I'm sure you'll find them soon.\"";
+ mes "\"You found " + @hidden_kid_cnt + " out of 5 us.\"";
+ goto L_close;
+
+L_Done:
+ mes "[Ghada]";
+ mes "\"It's so nice that you played with us! You're about the same age as my older sister, but she never plays with us. Her name is Sarah.\"";
+ goto L_close;
+
+L_close:
+ @Exp = 0;
+ close;
+}
diff --git a/npc/029-1/kaan.txt b/npc/029-1/kaan.txt
new file mode 100755
index 00000000..5684906c
--- /dev/null
+++ b/npc/029-1/kaan.txt
@@ -0,0 +1,114 @@
+
+029-1,46,95,0 script Kaan NPC160,{
+ callfunc "PCtoNPCRange";
+ if(@npc_check) end;
+
+ @kaan_talked = (STARTAREA & $@SpokeToKaan);
+ if (!(@kaan_talked)) goto L_Tanisha;
+ if (QL_BEGIN >= 13) goto L_TutDone;
+ if (QL_BEGIN == 12) goto L_Plan;
+ if (QL_BEGIN == 11) goto L_TrickKnown;
+ if (QL_BEGIN == 10) goto L_Trick;
+ if (QL_BEGIN == 9) goto L_Hasan;
+ goto L_Out;
+
+L_Tanisha:
+ STARTAREA = STARTAREA | $@SpokeToKaan;
+ mes "[Young Man]";
+ mes "\"You're the person I brought here, right?";
+ mes "My name is Kaan, I'm Tanisha's brother.\"";
+ mes "\"She was babbling at me about it all the morning until I sent her to take care of the maggots in the cafe.\"";
+ mes "Kaan grins mischieviously.";
+ mes "[Kaan]";
+ mes "\"She hates maggots.\"";
+ mes "\"Did you already talk to Tanisha?\"";
+ menu
+ "Yes, I helped her with the maggots.",L_Tanisha1,
+ "Yeah, and she's done with the maggots.",L_Tanisha1;
+
+L_Tanisha1:
+ mes "[Kaan]";
+ mes "\"Ah, that is good news.";
+ mes "You know, we have a lot of problems with bugs here.\"";
+ mes "\"I've slain many bugs here to keep them out of our fields.\"";
+ mes "\"If we don't watch out the maggots will eat all of our stocks.";
+ mes "And the island is crawling with scorpions.\"";
+ mes "\"Are you going to visit Hurnscald?";
+ mes "Hurnscald is a wondeful place! Traders, entertainers, adventurers - it's very exciting.\"";
+ mes "\"And Ian the trainer is hanging around there often. You should talk to him, he's a smart guy.\"";
+ mes "\"The ferry to the south takes your there for free.\"";
+ goto L_close;
+
+L_Out:
+ mes "[Kaan]";
+ mes "\"Hello! How are you? Did you already visit Hurnscald?\"";
+ menu
+ "Yes.", L_close,
+ "Not yet.",L_close;
+
+L_Hasan:
+ mes "[Kaan]";
+ mes "\"Hello! How are you? Did you already visit Hurnscald?\"";
+ menu
+ "A guy named Hasan is bullying someone.",L_Next1,
+ "Yes.", L_close,
+ "Not yet.",L_close;
+
+L_Next1:
+ mes "\"Hasan! That's crazy. He becomes more cheeky with every day.";
+ mes "I'd like to help you, but - I won't risk an open confrontation with him.\"";
+ mes "\"Sometimes he just freaks out and then he's dangerous.";
+ mes "He might listen to one of the adult men, but they're all off to work in Hurnscald during the day.\"";
+ mes "\"We should think about some kind of trick. Ah, if only I knew his weak point.\"";
+ QL_BEGIN = 10;
+ goto L_Trick;
+
+L_Trick:
+ mes "[Kaan]";
+ mes "\"Do you have any idea what Hasan's weakness could be?";
+ mes "I wonder if Sorfina know something about him that could help us.\"";
+ menu
+ "No idea.",L_close;
+
+L_TrickKnown:
+ mes "[Kaan]";
+ mes "\"Do you have any idea what Hasan's weakness could be?";
+ menu
+ "He's afraid of scorpions.",L_Next2,
+ "No idea.",L_close;
+
+L_Next2:
+ mes "[Kaan]";
+ mes "\"Scorpions?! Right! How could I forget?";
+ mes "When he was a child, he nearly died because he fell into a scorpion nest.\"";
+ QL_BEGIN = 12;
+ next;
+ goto L_Explain;
+
+L_Explain:
+ mes "\"Ok, then here's the plan:";
+ mes "\"You'll go to Hasan and give me a sign when you're ready.";
+ mes "Lets say the sign is that you're scratching your head.";
+ mes "I'll watch you from this point.\"";
+ mes "\"When you give me the sign, I'll summon a scorpion on him.";
+ mes "I bet that will show him for the coward he really is.\"";
+ mes "\"How's that? We can start as soon as you're ready.\"";
+ goto L_close;
+
+L_Plan:
+ mes "[Kaan]";
+ mes "\"I'm ready. Just give me the sign when you're down there.";
+ mes "Or do you want me to explain the plan again?\"";
+ menu
+ "Yes please.",L_Explain,
+ "No, everything's alright.",L_close;
+
+L_TutDone:
+ mes "[Kaan]";
+ mes "\"Hi there. I hope you enjoy your time in Hurnscald.";
+ mes "Hasan can be a real troublemaker, but it seems like he has calmed down for now.\"";
+ goto L_close;
+
+L_close:
+ close;
+}
diff --git a/npc/029-1/liana.txt b/npc/029-1/liana.txt
new file mode 100755
index 00000000..d4816cea
--- /dev/null
+++ b/npc/029-1/liana.txt
@@ -0,0 +1,38 @@
+
+029-1,62,96,0 script Liana NPC205,{
+ callfunc "PCtoNPCRange";
+ if(@npc_check) end;
+ goto L_Talk;
+
+L_Talk:
+ mes "[Liana]";
+ mes "\"Hurnscald is a large city. I'm sure glad I live in Candor because I know where everything's at.\"";
+ if (QL_BEGIN == 10) goto L_Hasan;
+ goto L_close;
+
+L_Hasan:
+ mes "[Liana]";
+ mes "\"Are you enjoying yourself in Candor? Do you have any questions?\"";
+ menu
+ "A guy named Hasan is bullying people.",L_Next,
+ "No, thanks.",L_close;
+
+L_Next:
+ mes "\"Ah, Hasan. He's causing trouble again?\"";
+ mes "She shakes her head.";
+ mes "\"This guy has been a plague ever since he could walk. He's always causing trouble.\"";
+ mes "\"And his father... Well, one day his father thought he should teach Hasan a lesson.\"";
+ mes "\"He took him into the desert and then left him there!";
+ mes "Hasan was only seven years old!\"";
+ mes "\"I never understood how someone could do something like that to a child, even if it's a rascal like Hasan.\"";
+ mes "\"Anyway, Hasan tried to find his way back home, but stumbled into a nest of scorpions!\"";
+ mes "She shakes her head.";
+ mes "\"If Lieutenant Dausen hadn't have come along that moment, Hasan would have died that day.\"";
+ mes "\"However, the scorpions poison caused a bad fever and once Hasan had recovered from that, he was even more malicious than before.\"";
+ mes "She sighs.";
+ QL_BEGIN = 11;
+ goto L_close;
+
+L_close:
+ close;
+}
diff --git a/npc/029-1/mapflags.txt b/npc/029-1/mapflags.txt
new file mode 100755
index 00000000..afdfd030
--- /dev/null
+++ b/npc/029-1/mapflags.txt
@@ -0,0 +1 @@
+//029-1 mapflag resave 029-1,39,102
diff --git a/npc/029-1/monster_guide.txt b/npc/029-1/monster_guide.txt
new file mode 100755
index 00000000..4f19bee9
--- /dev/null
+++ b/npc/029-1/monster_guide.txt
@@ -0,0 +1,46 @@
+
+029-1,45,97,0 script Aidan NPC102,{
+ if (MPQUEST == 0)
+ goto L_Register;
+ mes "[Aidan the Monster Guide]";
+ mes "You currently have " +Mobpt+ " Monster Points. These points are acquired while killing monsters";
+ close;
+
+L_Register:
+ mes "[Aidan the Monster Guide]";
+ mes "Oh my, you don't seem to be registered as a Quest Participant. Would you like to register?";
+ next;
+ goto L_Choice;
+
+L_Choice:
+ menu
+ "Register",L_R,
+ "Not at the moment",
+ L_N,"Information",L_I;
+
+L_R:
+ mes "[Aidan the Monster Guide]";
+ mes "Give me a second to look over your paperwork.";
+ next;
+ mes "[Monster Guide]";
+ mes "Well, looks like you qualify!";
+ mes "Welcome to the questing world!";
+ MPQUEST = 1;
+ close;
+
+L_N:
+ mes "[Aidan the Monster Guide]";
+ mes "Very well, you don't know what you're missing.";
+ close;
+
+L_I:
+ mes "[Aidan the Monster Guide]";
+ mes "Here in The Mana World, there are certain rewards for your vanquishing of foes.";
+ mes "For example, there are Monster Points; every monster you kill has a certain amount of points that get added to your account.";
+ mes "The more points you have, the more expensive things you can buy using them.";
+ next;
+ mes "[Monster Guide]";
+ mes "So whaddaya say, sign up won't you?";
+ next;
+ goto L_Choice;
+}
diff --git a/npc/029-1/rewards_master.txt b/npc/029-1/rewards_master.txt
new file mode 100755
index 00000000..a945f479
--- /dev/null
+++ b/npc/029-1/rewards_master.txt
@@ -0,0 +1,146 @@
+
+029-1,47,97,0 script Ishi NPC106,{
+ if (MPQUEST == 0) goto L_Register;
+ if (tvis == 0) set tvis, 1;
+ if (Mobpt < tvis) goto L_NotEnough;
+
+ setarray @items$, "AppleCake", "Arrow", "Beer", "Boots", "BugLeg", "CactusDrink", "CactusPotion", "Cake", "Candy", "CasinoCoins", "CherryCake", "ChickenLeg", "ChocolateBar", "ChocolateCake", "CottonBoots", "CottonCloth", "CottonShirt", "CottonShorts", "FancyHat", "GreenApple", "HardSpike", "IronOre", "Lifestone", "LightBlueDye", "MaggotSlime", "Milk", "Orange", "OrangeCake", "OrangeCupcake", "PinkPetal", "PileOfAsh", "PinkAntenna", "PoltergeistPowder", "RawLog", "RedApple", "RedDye", "ScorpionStinger", "SerfHat", "SmallHealingPotion", "SmallMushroom", "SnakeSkin", "SpectrePowder", "Steak", "TinyHealingPotion", "WhiteCake", "WhiteFur", "WispPowder", "YellowDye", "Coal";
+
+ mes "[Ishi the Rewards Master]";
+ mes "\"Welcome! I see you have " + Mobpt + " Monster Points. Would you like to exchange some of those for items?\"";
+ next;
+
+ @i = 0;
+ setarray @Menu$, "", "", "", "", "", "", "", "", "", "", "", "";
+ callsub S_prep_menu;
+
+ menu
+ @Menu$[0], L_MenuItems,
+ @Menu$[1], L_MenuItems,
+ @Menu$[2], L_MenuItems,
+ @Menu$[3], L_MenuItems,
+ @Menu$[4], L_MenuItems,
+ @Menu$[5], L_MenuItems,
+ @Menu$[6], L_MenuItems,
+ @Menu$[7], L_MenuItems,
+ @Menu$[8], L_MenuItems,
+ @Menu$[9], L_MenuItems,
+ @Menu$[10], L_MenuItems,
+ @Menu$[11], L_MenuItems;
+
+L_MenuItems:
+ // this is for the last entry "No thanks":
+ if (@menu > @i) goto L_close;
+ // this is for the "Give all" entry:
+ if (@menu == 11) goto L_Give_all;
+
+ @req = @menu;
+ @rec = 0;
+ goto L_Item_Loop;
+
+L_Item_Loop:
+ if (@rec == @req || Mobpt < tvis) goto L_Item_Done;
+
+ callsub S_give_item;
+ @rec = @rec + 1;
+ goto L_Item_Loop;
+
+L_Item_Done:
+ if (@rec < @req) mes "It looks like your Monster Points were over estimated.";
+ goto L_close;
+
+L_Register:
+ mes "[Ishi the Rewards Master]";
+ mes "\"Hey, it seems like you didn't register as a quest participant yet! You can sign up with Aidan.\"";
+ goto L_close;
+
+L_NotEnough:
+ mes "[Ishi the Rewards Master]";
+ mes "\"You don't have enough Monster Points for a reward. You'll need to kill some more monsters first.\"";
+ goto L_close;
+
+L_Give_all:
+ // we need to count how many loop iterations are done there,
+ // since the server complains about more than 250 (70 according to Jaxad0127)
+ // gotos without interrupting next statement.
+ @gotocounter = 50;
+ goto L_Give_all_loop;
+
+L_Give_all_loop:
+ @gotocounter = @gotocounter - 1;
+ if (@gotocounter < 1) goto L_Give_all_next;
+ @itemgiveerror = 0;
+ callsub S_give_item;
+ if (@itemgiveerror != 0) goto L_close;
+ goto L_Give_all_loop;
+
+L_Give_all_next:
+ next;
+ mes "[Ishi the Rewards Master]";
+ mes "\"You have received a lot of items. You still have " + Mobpt + " monster points. Shall we continue?\"";
+ menu
+ "Yes", L_Give_all,
+ "No", L_close;
+
+L_close:
+ @gotocounter = 0;
+ @itemgiveerror = 0;
+ @pts = 0;
+ @dif = 0;
+ @i = 0;
+ cleararray @Menu$[0], "", 10;
+ cleararray @items$[0], "", 10;
+ close;
+
+
+S_prep_menu:
+ @pts = Mobpt;
+ @dif = tvis;
+ goto L_Menu_Loop;
+
+L_Menu_Loop:
+ if (@pts < @dif || @i == 10) goto L_Menu_Check;
+
+ @Menu$[@i] = @i + 1;
+
+ @i = @i + 1;
+ @pts = @pts - @dif;
+ @dif = @dif + 1;
+
+ goto L_Menu_Loop;
+
+L_Menu_Check:
+ // if we are able to give 10, we can enable the option to give all we can have
+ if (@i != 10) goto L_Menu_Done;
+ @Menu$[@i] = "Please give me as many as I deserve!";
+ @i = @i + 1;
+ goto L_Menu_Done;
+
+L_Menu_Done:
+ @Menu$[@i] = "No thanks";
+ return;
+
+S_give_item:
+ @itemgiveerror = 0;
+ getinventorylist;
+ if (@inventorylist_count == 100) goto S_give_noinv;
+ if (Mobpt < tvis) goto S_give_nomobpts;
+ Mobpt = Mobpt - tvis;
+ tvis = tvis + 1;
+ @item$ = @items$[rand(getarraysize(@items$))];
+
+ getitem @item$, 1;
+
+ mes "You received one " + getitemlink(@item$) + "!";
+ return;
+
+S_give_noinv:
+ mes "Your inventory is full!";
+ @itemgiveerror = 1;
+ return;
+
+S_give_nomobpts:
+ mes "It looks like your Monster Points were over estimated.";
+ @itemgiveerror = 1;
+ return;
+}
diff --git a/npc/029-1/soul-menhir.txt b/npc/029-1/soul-menhir.txt
new file mode 100755
index 00000000..0c7d4a77
--- /dev/null
+++ b/npc/029-1/soul-menhir.txt
@@ -0,0 +1,15 @@
+
+029-1,39,101,0 script Soul Menhir#candor NPC344,{
+ @map$ = "029-1";
+ setarray @Xs, 38, 39, 40, 38, 40, 38, 39, 40;
+ setarray @Ys, 100, 100, 100, 101, 101, 102, 102, 102;
+ @x = 0;
+ @y = 0;
+ callfunc "SoulMenhir";
+ @map$ = "";
+ cleararray @Xs[0], 0, getarraysize(@Xs);
+ cleararray @Ys[0], 0, getarraysize(@Ys);
+ @x = 0;
+ @y = 0;
+ close;
+}
diff --git a/npc/029-1/traveler.txt b/npc/029-1/traveler.txt
new file mode 100755
index 00000000..83b623fc
--- /dev/null
+++ b/npc/029-1/traveler.txt
@@ -0,0 +1,7 @@
+
+029-1,69,68,0 script Knitra the Traveler NPC103,{
+ @npcname$ = "Knitra";
+ @NpcTravelBit = $@candor_bit;
+ callfunc "Traveler";
+ end;
+}
diff --git a/npc/029-1/tutorial.txt b/npc/029-1/tutorial.txt
new file mode 100755
index 00000000..870104d7
--- /dev/null
+++ b/npc/029-1/tutorial.txt
@@ -0,0 +1,52 @@
+- script #TutorialConfig NPC32767,{
+ end;
+
+OnInit:
+ $@ScorpionFighter = 0;
+ $@ScorpionTimer = 0;
+ set $@ScorpDeath, 0;
+ $@SpokeToKaan = (1 << 31);
+ end;
+}
+029-2,21,26,0 script TutDebug NPC154,{
+ mes "[TutDebug]";
+ mes "Reset?";
+ menu
+ "Reset Kaan/Hasan",L_Kaan,
+ "Yes.",L_Reset,
+ "No.",L_close;
+
+L_Kaan:
+ QL_BEGIN = 8;
+ STARTAREA = STARTAREA &~ $@SpokeToKaan;
+ mes "Reset!";
+ goto L_close;
+
+L_Reset:
+ TUT_var = 0;
+ QL_BEGIN = 0;
+ STARTAREA = STARTAREA &~ $@SpokeToKaan;
+ mes "Reset!";
+ goto L_close;
+
+L_close:
+ close;
+
+OnInit:
+ if(!debug)
+ disablenpc "TutDebug";
+ end;
+}
+029-1,32,99,0 script #tutorialoutside NPC45,0,0,{
+ if (QL_BEGIN >= 8)
+ goto L_Warp;
+ goto L_ResetTutorial;
+
+L_ResetTutorial:
+ QL_BEGIN = 8;
+ goto L_Warp;
+
+L_Warp:
+ warp "029-2", 114, 92;
+ end;
+}
diff --git a/npc/029-1/valon.txt b/npc/029-1/valon.txt
new file mode 100755
index 00000000..d8b3a0c6
--- /dev/null
+++ b/npc/029-1/valon.txt
@@ -0,0 +1,137 @@
+- script #ValonConfig NPC32767,{
+ end;
+
+OnInit:
+ setarray $@ValonMob, 1002,1050,1046,1003;
+ setarray $@ValonMobName$, "Maggots","House Maggots","Tame Scorpions","Scorpion";
+ setarray $@ValonMobCnt, 10,5,3,1;
+ end;
+}
+function script ValonCount {
+ @valon_mob = 0;
+ if (QL_VALON >= 2)
+ @valon_mob = (QL_VALON - 2);
+ @valon_count = ((STARTAREA & NIBBLE_2_MASK) >> NIBBLE_2_SHIFT);
+ return;
+}
+function script ResetValonCntMask {
+ STARTAREA = (STARTAREA & ~(NIBBLE_2_MASK) | (0 << NIBBLE_2_SHIFT));
+ return;
+}
+function script AddValonCntMask {
+ @valon_tmp = (@valon_count + 1);
+ if (@valon_tmp > $@ValonMobCnt[@valon_mob])
+ @valon_tmp = $@ValonMobCnt[@valon_mob];
+ STARTAREA = (STARTAREA & ~(NIBBLE_2_MASK) | (@valon_tmp << NIBBLE_2_SHIFT));
+ @valon_tmp = 0;
+ callfunc "ValonProgress";
+ return;
+}
+function script ValonProgress {
+ callfunc "ValonCount";
+ if ((QL_VALON > 1) && (QL_VALON < 6))
+ message strcharinfo(0), $@ValonMobName$[@valon_mob] + ": " + @valon_count + "/" + $@ValonMobCnt[@valon_mob];
+ return;
+}
+029-1,74,86,0 script ValonDebug NPC156,{
+ mes "[Valon Debug]";
+ mes "Reset?";
+ menu
+ "Yes.", L_Reset,
+ "No.", L_close;
+
+L_Reset:
+ QL_VALON = 0;
+ STARTAREA = (STARTAREA & ~(NIBBLE_2_MASK) | (0 << NIBBLE_2_SHIFT));
+ mes "Reset!";
+ goto L_close;
+
+L_close:
+ close;
+
+OnInit:
+ if (!debug)
+ disablenpc "ValonDebug";
+ end;
+}
+029-1,72,86,0 script Valon NPC156,{
+ callfunc "PCtoNPCRange";
+ if(@npc_check) end;
+
+ callfunc "ValonCount";
+ if (QL_VALON >= 6)
+ goto L_QuestComplete;
+ if (QL_VALON == 1)
+ goto L_QuestAskAgain;
+ if (@valon_count >= $@ValonMobCnt[@valon_mob])
+ goto L_NextMob;
+ if ((QL_VALON >= 2) && (QL_VALON < 6))
+ goto L_QuestStarted;
+ goto L_QuestAsk;
+
+L_QuestAskAgain:
+ mes "[Valon]";
+ mes "\"Hello, Adventurer! Have you come back to help?\"";
+ menu
+ "Yes. I will help with the island beasts.", L_Accept,
+ "Maybe some other time.", L_close;
+
+L_QuestAsk:
+ mes "[Valon]";
+ mes "\"Hello!";
+ mes "You're looking for adventures, right?\"";
+ mes "\"But you shouldn't underestimate this island, it is dangerous.\"";
+ mes "\"It's crawling with scorpions, and the heat has overcome adventurers tougher than you are.\"";
+ mes "\"I should know I guard this gate from all manner of island beasts.\"";
+ mes "\"Maybe you would like help and earn your stripes?\"";
+ mes "\"The Council of Wizard's does offer a reward for helping...\"";
+ QL_VALON = 1;
+ callfunc "ResetValonCntMask";
+ menu
+ "YES!!! let me at them!", L_Accept,
+ "Maybe some other time.", L_close;
+
+L_Accept:
+ QL_VALON = 2;
+ callfunc "ValonCount";
+ goto L_NewMob;
+
+L_NextMob:
+ getexp 40, 0;
+ mes "\"I see you killed all the " + $@ValonMobName$[@valon_mob] + " needed.\"";
+ mes "\"The Wizard's thank thee as well.\"";
+ Zeny = Zeny + 25;
+ QL_VALON = (QL_VALON + 1);
+ callfunc "ResetValonCntMask";
+ callfunc "ValonCount";
+ if (@valon_mob == getarraysize($@ValonMob))
+ goto L_QuestOver;
+ goto L_NewMob;
+
+L_NewMob:
+ mes "\"Let's see whats on the list. Ah ok, I need you to kill me " + $@ValonMobCnt[@valon_mob] + " " + $@ValonMobName$[@valon_mob] + "\"";
+ mes "\"I'll be waiting here, come back and see after you've killed those mobs.\"";
+ goto L_close;
+
+L_QuestStarted:
+ mes "[Valon]";
+ mes "Hail adventurer! You are well on your way to mastering the beasts of the island.\"";
+ mes "\"You need to kill " + $@ValonMobName$[@valon_mob] + ": " + @valon_count + "/" + $@ValonMobCnt[@valon_mob] + "\"";
+ mes "\"Come back and see me when the job is done.\"";
+ goto L_close;
+
+L_QuestOver:
+ mes "[Valon]";
+ mes "\"Thanks once again for helping with the monsters in the island.\"";
+ getexp 50, 0;
+ QL_VALON = (QL_VALON + 1);
+ goto L_close;
+
+L_QuestComplete:
+ mes "[Valon]";
+ mes "\"Thanks once again for helping with the monsters in the island.\"";
+ goto L_close;
+
+L_close:
+ close;
+}
diff --git a/npc/029-1/vincent.txt b/npc/029-1/vincent.txt
new file mode 100755
index 00000000..c0f66644
--- /dev/null
+++ b/npc/029-1/vincent.txt
@@ -0,0 +1,134 @@
+029-1,108,108,0 script Vincent Debug NPC113,{
+ mes "[Vincent Debug]";
+ mes "Reset?";
+ menu
+ "Yes.", L_Reset,
+ "No.", L_close;
+
+L_Reset:
+ QL_VINCENT = 0;
+ mes "Reset!";
+ goto L_close;
+
+L_close:
+ close;
+
+OnInit:
+ if (!debug)
+ disablenpc "Vincent Debug";
+ end;
+}
+029-1,107,110,0 script Vincent NPC113,{
+ @halloween_npc_id = $@halloween_npc_vincent;
+ callfunc "TrickOrTreat";
+
+ if (QL_VINCENT >= 2) goto L_Done;
+ if (QL_VINCENT == 1) goto L_Progress;
+ goto L_Con_Vin_First;
+
+L_Con_Vin_First:
+ mes "[Vincent]";
+ mes "\"I'm making an action figure. I'm almost done with it.\"";
+ next;
+
+ @temp = rand(4);
+ if(@temp == 1) goto L_Opening2;
+ if(@temp == 2) goto L_Opening3;
+ if(@temp == 3) goto L_Opening4;
+ goto L_Opening1;
+
+L_Opening1:
+ mes "\"I just need 5 more Bug Legs to finish my action figure!\"";
+ next;
+ goto L_Ask;
+
+L_Opening2:
+ mes "\"This maggot action figure is awesome! I just need to attach 5 Bug Legs.\"";
+ next;
+ goto L_Ask;
+
+L_Opening3:
+ mes "\"This is a great action figure! A must have! All I need is a few parts...\"";
+ next;
+ goto L_Ask;
+
+L_Opening4:
+ mes "\"Can you get me 5 Bug Legs? I need them to replace the action figure parts.\"";
+ next;
+ goto L_Ask;
+
+L_Ask:
+ mes "\"Will you help me find 5 Bug Legs?\"";
+ next;
+ menu
+ "Yes.", L_Sure,
+ "No.", L_close;
+
+L_Sure:
+ QL_VINCENT = 1;
+ @temp = rand(4);
+ if(@temp == 1) goto L_Req2;
+ if(@temp == 2) goto L_Req3;
+ if(@temp == 3) goto L_Req4;
+ goto L_Req1;
+
+L_Req1:
+ mes "[Vincent]";
+ mes "\"Thank you!\"";
+ next;
+ goto L_Wait;
+
+L_Req2:
+ mes "[Vincent]";
+ mes "\"I don't know how to thank you enough!\"";
+ next;
+ goto L_Wait;
+
+L_Req3:
+ mes "[Vincent]";
+ mes "\"I will thank you when I get them!\"";
+ next;
+ goto L_Wait;
+
+L_Req4:
+ mes "[Vincent]";
+ mes "\"I'm sure I will give a small reward.\"";
+ next;
+ goto L_Wait;
+
+L_Wait:
+ mes "\"Now please go get me 5 Bug Legs.\"";
+ goto L_close;
+
+L_Progress:
+ if(countitem("BugLeg") >= 5)
+ goto L_Have;
+ mes "[Vincent]";
+ mes "\"Please help me collect 5 Bug Legs! I need them to complete my action figure.\"";
+ goto L_close;
+
+L_Have:
+ mes "[Vincent]";
+ mes "\"Excellent! Finally I can complete the model!!\"";
+ next;
+ if(countitem("BugLeg") < 5)
+ goto L_Progress;
+ delitem "BugLeg", 5;
+ getexp 50, 0;
+ Zeny = Zeny + 1000;
+ QL_VINCENT = 2;
+
+ mes "[Vincent]";
+ mes "\"Here you go, a little of my appreciation!\"";
+ mes "";
+ mes "[1000 gold]";
+ goto L_close;
+
+L_Done:
+ mes "[Vincent]";
+ mes "\"Thanks for your help!\"";
+ goto L_close;
+
+L_close:
+ close;
+}
diff --git a/npc/029-1/zegas.txt b/npc/029-1/zegas.txt
new file mode 100755
index 00000000..8e777e13
--- /dev/null
+++ b/npc/029-1/zegas.txt
@@ -0,0 +1,94 @@
+029-1,45,85,0 script Zegas NPC165,{
+ @npc_distance = 2;
+ callfunc "PCtoNPCRange";
+ if(@npc_check) end;
+
+ if (QL_ZEGAS == 1)
+ goto L_Find;
+ if (QL_ZEGAS == 2)
+ goto L_Looking;
+ if (QL_ZEGAS == 3)
+ goto L_QuestEnd;
+ if (QL_ZEGAS == 4)
+ goto L_Thanks;
+ goto L_Meet;
+
+L_Meet:
+ mes "[Zegas]";
+ mes "\"Hey do you have a second?\"";
+ next;
+ mes "\"The storehouse here is over run with house maggots.\"";
+ next;
+ mes "\"Wouldn't you know it, the bug bomb Eomie gave us is in one of the store room barrels.\"";
+ next;
+ mes "\"Can you search the barrels for the bug bomb and set it off when you find it?\"";
+ QL_ZEGAS = 1;
+ menu
+ "Sure.",L_Start,
+ "Maybe some other time.",L_close;
+
+L_Find:
+ mes "[Zegas]";
+ mes "\"The storehouse is still over run with house maggots.\"";
+ next;
+ mes "\"Please help me find the bug bomb Eomie gave us is in one of the store room barrels?\"";
+ menu
+ "Sure.",L_Start,
+ "Maybe some other time.",L_close;
+
+L_Start:
+ mes "[Zegas]";
+ QL_ZEGAS = 2;
+ mes "\"Thanks, come back and see me once you found the bug bomb and set it off.\"";
+ goto L_close;
+
+L_Looking:
+ mes "[Zegas]";
+ mes "\"Still haven't found it? Well keep looking I know it's in there some where.\"";
+ goto L_close;
+
+L_QuestEnd:
+ mes "[Zegas]";
+ mes "\"From the smell I can see you found the bug bomb!\"";
+ mes "\"Thanks once again, I know it's not much but here is 50 GP for your troubles.\"";
+ getexp 50, 0;
+ Zeny = (Zeny + 50);
+ QL_ZEGAS = 4;
+ goto L_close;
+
+L_Thanks:
+ mes "[Zegas]";
+ mes "\"Thanks for Helping with clear out the store room!\"";
+ goto L_close;
+
+L_close:
+ close;
+}
+029-1,47,86,0 script ZegasDebug NPC165,{
+ mes "[Zegas Debug]";
+ mes "Reset ?";
+ menu
+ "Yes.", L_Reset,
+ "No.", L_close;
+
+L_Reset:
+ QL_ZEGAS = 0;
+ STARTAREA = STARTAREA &~ (1 << 20);
+ STARTAREA = STARTAREA &~ (1 << 21);
+ STARTAREA = STARTAREA &~ (1 << 22);
+ STARTAREA = STARTAREA &~ (1 << 23);
+ STARTAREA = STARTAREA &~ (1 << 24);
+ STARTAREA = STARTAREA &~ (1 << 25);
+ STARTAREA = STARTAREA &~ (1 << 26);
+ STARTAREA = STARTAREA &~ (1 << 27);
+ mes "Reset!";
+ goto L_close;
+
+L_close:
+ close;
+
+OnInit:
+ if (!debug)
+ disablenpc "ZegasDebug";
+ end;
+}
generated by cgit v1.2.3-70-g09d2 (git 2.46.0) at 2024-11-19 06:05:56 +0000