Merge branch 'master' into legacy

Override all files with 'master' version.

This version is meant to preserve git history as requested by bjorn.

17 files changed, 1353 insertions, 0 deletions

diff --git a/npc/001-2/_import.txt b/npc/001-2/_import.txt
new file mode 100644
index 00000000..58464d30
--- /dev/null
+++ b/npc/001-2/_import.txt
@@ -0,0 +1,18 @@
+// Map 001-2: South Tulimshar Indoor
+// This file is generated automatically. All manually added changes will be removed when running the Converter.
+"npc/001-2/_warps.txt",
+"npc/001-2/bank.txt",
+"npc/001-2/david.txt",
+"npc/001-2/fieri.txt",
+"npc/001-2/forge_shops.txt",
+"npc/001-2/government_building.txt",
+"npc/001-2/heathin.txt",
+"npc/001-2/jhedia.txt",
+"npc/001-2/manakins.txt",
+"npc/001-2/mapflags.txt",
+"npc/001-2/pauline.txt",
+"npc/001-2/sandra.txt",
+"npc/001-2/tathin.txt",
+"npc/001-2/tondar.txt",
+"npc/001-2/wizards.txt",
+"npc/001-2/yanis.txt",
diff --git a/npc/001-2/_warps.txt b/npc/001-2/_warps.txt
new file mode 100644
index 00000000..84eb0d69
--- /dev/null
+++ b/npc/001-2/_warps.txt
@@ -0,0 +1,17 @@
+// This file is generated automatically. All manually added changes will be removed when running the Converter.
+// Map 001-2: South Tulimshar Indoor warps
+001-2,25,65,0	warp	#001-2_25_65	0,0,001-1,114,100
+001-2,28,102,0	warp	#001-2_28_102	0,0,001-1,27,33
+001-2,28,86,0	warp	#001-2_28_86	0,0,001-1,28,22
+001-2,105,102,0	warp	#001-2_105_102	1,0,001-1,54,35
+001-2,25,28,0	warp	#001-2_25_28	0,0,001-1,49,72
+001-2,28,28,0	warp	#001-2_28_28	0,0,001-1,52,72
+001-2,31,28,0	warp	#001-2_31_28	0,0,001-1,55,72
+001-2,71,102,0	warp	#001-2_71_102	0,0,001-1,37,33
+001-2,105,73,0	warp	#001-2_105_73	3,0,001-2,104,42
+001-2,105,43,0	warp	#001-2_105_43	3,0,001-2,104,74
+001-2,114,53,0	warp	#001-2_114_53	0,0,001-1,57,23
+001-2,95,53,0	warp	#001-2_95_53	0,0,001-1,52,23
+001-2,57,90,0	warp	#001-2_57_90	0,0,001-2,35,94
+001-2,36,95,0	warp	#001-2_36_95	0,1,001-2,58,90
+001-2,65,26,0	warp	#001-2_65_26	0,0,001-1,59,99
diff --git a/npc/001-2/bank.txt b/npc/001-2/bank.txt
new file mode 100644
index 00000000..7ab46396
--- /dev/null
+++ b/npc/001-2/bank.txt
@@ -0,0 +1,6 @@
+001-2,63,17,0	script	Hydusun	NPC149,{
+    @npcname$ = "Hydusun";
+    callfunc "Banker";
+    close;
+}
+
diff --git a/npc/001-2/david.txt b/npc/001-2/david.txt
new file mode 100644
index 00000000..f3ce6b55
--- /dev/null
+++ b/npc/001-2/david.txt
@@ -0,0 +1,52 @@
+001-2,92,88,0	script	David	NPC120,{
+    @Potion_EXP = 2000;
+
+    if (Rossy_Quest == 17) goto L_FinalEnd;
+    if (Rossy_Quest == 14) goto L_Julia;
+    if (Rossy_Quest >= 8) goto L_Done;
+
+    mes "[David]";
+    mes "\"Learning magic is hard...\"";
+    if (Rossy_Quest == 7) goto L_Help;
+    close;
+
+L_Help:
+    menu
+        "Do you know Rossy?", L_Set,
+        "I can tell, it is hard.", L_No;
+
+L_Set:
+    mes "[David]";
+    mes "\"Yes, I do. I am her teacher. Actually, that reminds me about her final exam... she didn't hand in her potion yet. Time is running out.\"";
+    menu
+        "A potion? Oh, uhm... Strange kind of exam. Bye.", L_No,
+        "Right, I have her potion in my pocket. She asked me to bring it to you. Here it is.", L_Next;
+
+L_Next:
+    mes "[David]";
+    mes "\"Let me see.\"";
+    Rossy_Quest = 8;
+    mes "\"This potion is... perfect! Tell Rossy that she successfully made her potion; it is flawless!\"";
+    getexp @Potion_EXP, 0;
+    close;
+
+L_Done:
+    mes "[David]";
+    mes "\"I am really happy that my best student successfully passed her exam!\"";
+    close;
+
+L_No:
+    close;
+
+L_Julia:
+    mes "[David]";
+    mes "\"I heard Rossy's sister got kidnapped. We're counting on you to find her!\"";
+    next;
+    mes "\"If you do find her, talk to her sister and her mother.\"";
+    close;
+
+L_FinalEnd:
+    mes "[David]";
+    mes "Well done! Thanks for finding Julia!";
+    close;
+}
diff --git a/npc/001-2/fieri.txt b/npc/001-2/fieri.txt
new file mode 100644
index 00000000..5d6a0890
--- /dev/null
+++ b/npc/001-2/fieri.txt
@@ -0,0 +1,117 @@
+001-2,114,89,0	script	Fieri	NPC117,{
+    if (QL_FIERI >= 4) goto L_Done2;
+    if (QL_FIERI == 3) goto L_Progress2;
+    if (QL_FIERI == 2) goto L_Done1;
+    if (QL_FIERI == 1) goto L_Progress;
+
+    @temp = rand(2);
+    if(@temp == 1) goto L_Opening1;
+    goto L_Opening0;
+
+L_Opening0:
+    mes "[Fieri]";
+    mes "\"The Wizards are always hungry. All the magic all the time, sapping their energy.";
+    mes "Could I ask a favor of you?\"";
+    next;
+    goto L_Ask;
+
+L_Opening1:
+    mes "[Fieri]";
+    mes "\"These Wizards eat like a store house full of maggots.";
+    mes "At this rate I'll have nothing left to cook. Can you help me with a task?\"";
+    next;
+    goto L_Ask;
+
+L_Ask:
+    menu
+        "Yes.", L_Yes,
+        "No.", L_close;
+
+L_Yes:
+    @temp = rand(2);
+    if(@temp == 1) goto L_Req1;
+    goto L_Req0;
+
+L_Req0:
+    mes "[Fieri]";
+    mes "\"Great!  I need a Beer for my Tonori Delight.\"";
+    next;
+    goto L_Set;
+
+L_Req1:
+    mes "[Fieri]";
+    mes "\"Bring me a Beer. I'll give you something if you do.\"";
+    next;
+    goto L_Set;
+
+L_Set:
+    QL_FIERI = 1;
+    mes "[Fieri]";
+    mes "\"Please bring it to me!\"";
+    goto L_close;
+
+L_Progress:
+    if (countitem("Beer") < 1) goto L_NotEnough;
+    mes "[Fieri]";
+    mes "\"Oooh, perfect! It's perfect!";
+    mes "You brought me my Beer!  Here, have some cake for your troubles.\"";
+    getinventorylist;
+    if (@inventorylist_count - (countitem("Beer") == 1) > 99 - (countitem("CherryCake") == 0) ) goto L_TooMany;
+    delitem "Beer", 1;
+    getexp 100, 0;
+    getitem "CherryCake", 5;
+    QL_FIERI = 2;
+    next;
+    mes "\"Now let's see...\"";
+    goto L_close;
+
+L_Progress2:
+    if (countitem("MaggotSlime") < 3) goto L_NotEnough1;
+    mes "[Fieri]";
+    mes "\"Nice!  They're perfect, just perfect!";
+    mes "You brought me the 3 Maggot Slimes! Here, have some Tonori Delight as reward.\"";
+    getinventorylist;
+    if ((@inventorylist_count - (countitem("MaggotSlime") == 3) > 99  - (countitem("TonoriDelight") == 0) )) goto L_TooMany;
+    delitem "MaggotSlime", 3;
+    getexp 100, 0;
+    getitem "TonoriDelight", 3;
+    QL_FIERI = 4;
+    goto L_close;
+
+L_NotEnough:
+    mes "[Fieri]";
+    mes "\"Oh, please hurry and bring me a Beer. The Wizards need their Tonori Delight!\"";
+    goto L_close;
+
+L_NotEnough1:
+    mes "[Fieri]";
+    mes "\"Please do hurry and bring me 3 Maggot Slimes, so I can finish the Tonori Delight!\"";
+    goto L_close;
+
+L_Done1:
+    mes "[Fieri]";
+    mes "\"Thank you so much!\"";
+    mes "\"But... I need some more ingredients.\"";
+    next;
+    mes "\"I need 3 Maggot Slimes for that.\"";
+    mes "\"Bring them to me, and I'll give you something nice.\"";
+    QL_FIERI = 3;
+    goto L_close;
+
+L_Done2:
+    mes "[Fieri]";
+    mes "\"I hope you like Tonori Delight as much as I do, because, you see...\"";
+    next;
+    mes "\"Tonori Delight is life!\"";
+    goto L_close;
+
+L_close:
+    @temp = 0;
+    close;
+
+L_TooMany:
+    next;
+    mes "[Fieri]";
+    mes "\"You don't have room for my reward. I'll wait until you do.\"";
+    goto L_close;
+}
diff --git a/npc/001-2/forge_shops.txt b/npc/001-2/forge_shops.txt
new file mode 100644
index 00000000..cdbece0a
--- /dev/null
+++ b/npc/001-2/forge_shops.txt
@@ -0,0 +1,36 @@
+// The Mana World Script
+// (C) Jesusalva, 2021
+// Licensed under GPLv2 or later
+
+001-2,30,60,0	script	Gungnir	NPC311,{
+    shop .name$;
+    goodbye;
+    close;
+
+OnInit:
+    tradertype(NST_ZENY);
+    sellitem SlingShot;
+    sellitem SlingBullet;
+    sellitem ShortBow;
+    sellitem Arrow;
+    sellitem IronArrow;
+    .distance = 5;
+    end;
+}
+
+
+001-2,25,59,0	script	Mjolnir	NPC377,{
+    shop .name$;
+    goodbye;
+    close;
+
+OnInit:
+    tradertype(NST_ZENY);
+    sellitem Knife;
+    sellitem SharpKnife;
+    sellitem Dagger;
+    sellitem LeatherShield;
+    .distance = 5;
+    end;
+}
+
diff --git a/npc/001-2/government_building.txt b/npc/001-2/government_building.txt
new file mode 100644
index 00000000..d4a73df0
--- /dev/null
+++ b/npc/001-2/government_building.txt
@@ -0,0 +1,154 @@
+
+001-2,25,21,0	script	Estard	NPC107,{
+    mes "[Estard]";
+    mes "\"Hello. What can I do for you?\"";
+    next;
+    if (getpartnerid())
+        goto L_Main_married;
+
+    menu
+        "I'd like to get married.", L_marry,
+        "Never mind.", L_close;
+
+L_Main_married:
+    menu
+        "I'd like to file for divorce.", L_divorce,
+        "Never mind.", L_close;
+
+L_marry:
+    if (BaseLevel < WEDDING_MIN_LEVEL)
+        goto L_marry_too_young;
+    if (Zeny < WEDDING_FEE)
+        goto L_marry_too_poor;
+
+    mes "";
+    mes "[Estard]";
+    mes "\"Are you sure that you want to get married? It'll cost you ##B" + WEDDING_FEE + " GP##b.\"";
+    menu
+        "Yes!", L_marry_do,
+        "I'm having second thoughts...", L_close;
+
+L_marry_do:
+    callsub S_give_rings;
+    mes "";
+    mes "[Estard]";
+    mes "\"Here are your rings. In order to marry each other, you both must stand within one of the designated areas (like that small rug over there in the corner), wear your rings, and say '#marry (your partner's name).'\"";
+    close;
+
+L_marry_too_young:
+    mes "";
+    mes "[Estard]";
+    mes "\"I'm sorry, but you are too young to get married. You must be at least " + WEDDING_MIN_LEVEL + " levels old.\"";
+    next;
+
+    menu
+        "Can I at least get the wedding rings now?", L_Get_rings,
+        "Thanks anyways.", L_close;
+
+L_marry_too_poor:
+    mes "";
+    mes "[Estard]";
+    mes "\"It costs ##B" + WEDDING_FEE + " GP##b to get married. That covers all the processing fees for the marriage and provides you with two wedding rings.\"";
+    close;
+
+L_Get_rings:
+    mes "";
+    mes "[Estard]";
+    mes "\"Yes! You certainly can. They're ##B" + WEDDING_FEE + " GP##b. That covers all the processing fees for the marriage and provides you with two wedding rings.\"";
+
+    if (Zeny < WEDDING_FEE)
+        menu
+            "Thanks, but I don't have enough with me right now.", L_close;
+    if (Zeny >= WEDDING_FEE)
+        menu
+            "Sounds great!", L_Get_rings_pay,
+            "No thanks.", L_close;
+    goto L_Get_rings_pay;
+
+L_Get_rings_pay:
+    callsub S_give_rings;
+
+    mes "";
+    mes "[Estard]";
+    mes "\"There you go! %%1\"";
+    close;
+
+L_divorce:
+    @divorce_cost = DIVORCE_FEE_PER_LEVEL * BaseLevel;
+
+    if (Zeny < @divorce_cost)
+        goto L_divorce_not_enough;
+
+    mes "[Estard]";
+    mes "\"I'm sorry to hear that. If you're sure you want a divorce, it'll cost you %%B" + @divorce_cost + " GP%%b.\"";
+    next;
+    menu
+        "I'm sure.", L_do_divorce,
+        "I'm having second thoughts...", L_close;
+
+L_do_divorce:
+    if (Zeny < @divorce_cost)
+        goto L_Not_enough_money;
+
+    divorce();
+    if (getpartnerid() < 1) goto L_divorce_done;
+
+    mes "";
+    mes "[Estard]";
+    mes "\"I'm having trouble finding your documents. Please come back later.\"";
+    mes "";
+    mes "[Server]";
+    mes "There was an unexpected error when processing your divorce. Please report this to the developers.";
+    close;
+
+L_divorce_done:
+    Zeny = Zeny - @divorce_cost;
+
+    mes "";
+    mes "[Estard]";
+    mes "\"You have now officially divorced your spouse.\"";
+    close;
+
+L_divorce_not_enough:
+    mes "";
+    mes "[Estard]";
+    mes "\"I'm sorry, but you don't have enough money to get a divorce. You need ##B" + @divorce_cost + " GP##b.\"";
+    close;
+
+L_Not_enough_money:
+    mes "";
+    mes "[Estard]";
+    mes "\"I'm sorry, but it seems as though you don't have enough money.\"";
+    close;
+
+L_No_Room_For_Rings:
+    mes "";
+    mes "[Estard]";
+    mes "\"Hm... it doesn't look like you have enough room to carry these rings.";
+    mes "Free up some space, and then I'd be happy to give them to you.\"";
+    close;
+
+L_close:
+    mes "";
+    mes "[Estard]";
+    mes "\"OK. Just come back whenever you're ready.\"";
+    close;
+
+S_give_rings:
+    if (Zeny < WEDDING_FEE)
+        goto L_Not_enough_money;
+    getinventorylist;
+    if (@inventorylist_count > 98)
+        goto L_No_Room_For_Rings;
+
+    Zeny = Zeny - WEDDING_FEE;
+    getitem "WeddingRing", 1;
+    getitem "WeddingRing", 1;
+    return;
+}
+
+001-2,22,21,0	script	Guard#govt_in	NPC123,{
+    mes "[Guard]";
+    mes "\"You're not allowed back here.\"";
+    close;
+}
diff --git a/npc/001-2/heathin.txt b/npc/001-2/heathin.txt
new file mode 100644
index 00000000..82f72802
--- /dev/null
+++ b/npc/001-2/heathin.txt
@@ -0,0 +1,338 @@
+001-2,23,55,0	script	Heathin	NPC147,{
+    @TARROW_REQ_TERRA_ORE = 1;
+    @TARROW_REQ_COAL = 5;
+    @TARROW_REQ_GP = 3000;
+    @heathin_xp_bonus = (100 * BaseLevel);
+
+    if (QL_TERRANITE_ARMOR == 14) && (BaseLevel >= 80) goto L_Arrows_Trade;
+    if (QL_TERRANITE_ARMOR == 13) && (BaseLevel >= 80) goto L_Arrows_Ready;
+    if (QL_TERRANITE_ARMOR == 12) && (BaseLevel >= 80) goto L_Arrows_Forge;
+    if (QL_TERRANITE_ARMOR == 11) && (BaseLevel >= 80) goto L_Arrows;
+    if (QL_TERRANITE_ARMOR == 11) goto L_Forge_Thanks;
+    if (QL_TERRANITE_ARMOR == 10) && (BaseLevel >= 80) goto L_Chest_Armor_Ready;
+    if (QL_TERRANITE_ARMOR == 9) && (BaseLevel >= 80) goto L_Chest_Armor_Forge;
+    if (QL_TERRANITE_ARMOR == 8) && (BaseLevel >= 80) goto L_Chest_Armor;
+    if (QL_TERRANITE_ARMOR == 8) goto L_Forge_Thanks;
+    if (QL_TERRANITE_ARMOR == 7) && (BaseLevel >= 75) goto L_Legs_Ready;
+    if (QL_TERRANITE_ARMOR == 6) && (BaseLevel >= 75) goto L_Legs_Forge;
+    if (QL_TERRANITE_ARMOR == 5) && (BaseLevel >= 75) goto L_Legs;
+    if (QL_TERRANITE_ARMOR == 5) goto L_Forge_Thanks;
+    if (QL_TERRANITE_ARMOR == 4) && (BaseLevel >= 70) goto L_Hood_Ready;
+    if (QL_TERRANITE_ARMOR == 3) && (BaseLevel >= 70) goto L_Hood_Forge;
+    if (QL_TERRANITE_ARMOR == 2) && (BaseLevel >= 70) goto L_Hood;
+    if (QL_TERRANITE_ARMOR == 2) goto L_Forge_Thanks;
+    if (QL_TERRANITE_ARMOR == 1) && (BaseLevel >= 60) goto L_Forge_Award;
+    if (QL_TERRANITE_ARMOR < 1 && BaseLevel >= 60) goto L_Start;
+
+    mes "[Heathin]";
+    mes "\"Hello, friend. I am Heathin, a smith of exotic metals. \"";
+    close;
+
+L_Start:
+    mes "[Heathin]";
+    mes "\"Hello, friend. I am Heathin, a smith of exotic metals. \"";
+    next;
+    mes "\"By the order of the Wizard's Council, I've been commissioned to forge armor for the upcoming expediation. However, I am but a simple smith and cannot complete all this effort by myself. I need individuals that can gather Coal to heat my forge.\"";
+    next;
+    mes "\"Perhaps you would be interested in helping me out?  Would you be willing to help me gather Coal and help me fulfill my commission?  I am asking any and all willing souls to get me 50 coal, as that would put a significant dint in my goal.\"";
+    menu
+        "Sure, I'll help!", L_Help,
+        "I'd rather keep my Coal for my own purposes, thank you very much.", L_No,
+        "Wait, what kind of award are we talking about?", L_Interested;
+
+L_Help:
+    QL_TERRANITE_ARMOR = 1;
+    mes "[Heathin]";
+    mes "\"Excellent!  I am always glad when someone can be of service not just to me, but to all of Tulimshar. Please get me 50 Coal and you will be compensated for your efforts.\"";
+    close;
+
+L_Interested:
+    mes "[Heathin]";
+    mes "\"Well, I can compensate you from the commision I getting from the council.\"";
+    next;
+    mes "\"How does 20,000 GP and I'll offer my smithing services for a discount?\"";
+    next;
+    mes "\"Does this sound like something you might be interested in?\"";
+    menu
+        "Sure, I'll help!", L_Help,
+        "I'd rather keep my Coal.", L_No,
+        "Can you repeat that again?", L_Interested;
+
+L_Forge_Award:
+    if (countitem (Coal) < 50) goto L_Forge_Wait;
+    getinventorylist;
+    QL_TERRANITE_ARMOR = 2;
+    delitem Coal, 50;
+    getexp @heathin_xp_bonus, 0;
+    Zeny = Zeny + 20000;
+    mes "[Heathin]";
+    mes "\"You have brought the Coal. This is most excellent!  As promised, I have a reward for you. Hopefully you will find it useful.\"";
+    next;
+    mes "\"Time to make some armor. The Council will be pleased. Thank you for your efforts!\"";
+    close;
+
+L_Forge_Wait:
+    mes "[Heathin]";
+    mes "\"Hello again. Making armor keeps me pretty busy. I certainly hope I can fulfill my commission soon so that I can move on to bigger and better things.\"";
+    next;
+    mes "\"The pay is good, certainly, but I am a far better smith than this. If you can bring me 50 Coal, it would surely get me to my goal faster.\"";
+    next;
+    mes "\"I will be sure to provide an apt award once you are done.\"";
+    close;
+
+L_Forge_Thanks:
+    mes "[Heathin]";
+    mes "\"Thank you again for helping me fulfil my commission. It has made a signficant dint in what the Council requires of me. Perhaps I may be of service to you again one day!\"";
+    close;
+
+L_Hood:
+    mes "[Heathin]";
+    mes "\"Hello again friend, I just found out about this great metal called terranite.\"";
+    next;
+    mes "\"This metal is almost as strong as steel, but is also very ductile.\"";
+    next;
+    mes "\"With some effort, I can make this metal form rings tighter than any chain mail. It isn't the prettiest in hue, but its uses can be many.\"";
+    next;
+    mes "\"Unfortunately, it seems to be difficult to gather. Most that have searched for Terranite Ore either cannot find it or have never returned...\"";
+    next;
+    mes "\"I may be an excellent smith, but I certainly am no combatant. However, I would enjoy turning this ore into something useful, perhaps some type of armor to help those that may be braver.\"";
+    next;
+    mes "\"So, what do you say?  Are you interested?\"";
+    menu
+        "No, thank you. Maybe later.", L_No,
+        "Armor, you say?  Definitely!", L_Yes;
+
+L_No:
+    mes "[Heathin]";
+    mes "\"Ah, that is too bad. Come back anytime.\"";
+    close;
+
+L_Yes:
+    QL_TERRANITE_ARMOR = 3;
+    mes "[Heathin]";
+    mes "\"Great, this is going to be fun!  As I have not had much practice with this armor, I'd like to get started soon.\"";
+    next;
+    mes "Heathin thinks for a moment.";
+    next;
+    mes "\"Ah, I know!  I will make a helm... Well, more like a hood, since it will be woven.\"";
+    next;
+    mes "\"It will require a great amount of heat, if the rumors are to be believed. For this, I will need 100 Coal to keep my forge burning hot. I will also need 10 Terranite Ore to make the armor. Of course, such work does not come cheap. While I may enjoy my work, my time and effort is very valuable. Since you have been a great help I will only need 20,000 gold pieces, well below my going rate. Please come back with the gold, Coal and ore and I'll make this hood for you.\"";
+    close;
+
+L_Hood_Forge:
+    if ( (Zeny < 20000)
+        || (countitem(Coal) < 100)
+        || (countitem(TerraniteOre) < 10) )
+            goto L_Hood_Wait;
+    QL_TERRANITE_ARMOR = 4;
+    delitem Coal, 100;
+    delitem TerraniteOre, 10;
+    getexp @heathin_xp_bonus, 0;
+    Zeny = Zeny - 20000;
+    mes "[Heathin]";
+    mes "\"Great, you brought everything!  Come back later and I'll have the helm ready for you.\"";
+    close;
+
+L_Hood_Wait:
+    mes "[Heathin]";
+    mes "\"I am very busy right now. If you could bring me 10 Terranite Ore, 100 Coal and 20,000 gold pieces, I will make that terranite hood for you.\"";
+    close;
+
+L_Hood_Ready:
+    getinventorylist;
+    if ((checkweight("TerraniteHelmet", 1) == 0) || (@inventorylist_count == 100))
+        goto L_InventoryNoSpace;
+    QL_TERRANITE_ARMOR = 5;
+    getitem TerraniteHelmet, 1;
+    mes "[Heathin]";
+    mes "\"I am all done with your terranite hood. I hope you enjoy it!  I have some work to wrap up for the Council, but come back later and I might be able to assist you again.\"";
+    close;
+
+L_Legs:
+    QL_TERRANITE_ARMOR = 6;
+    mes "[Heathin]";
+    mes "\"I am glad you are back!  I've just finished up some more of my commission. Now I can get back to making terranite armor for you. This time I will make some pants, but they need more ore, more Coal to heat my forge and of course, more gold for my efforts.\"";
+    next;
+    mes "\"To make terranite pants, I need 200 Coal, 30 Terranite Ore and 40,000 gold pieces. The faster you bring this to me, the faster I can have your terranite pants ready.\"";
+    close;
+
+L_Legs_Forge:
+    if ( (Zeny < 40000)
+        || (countitem(Coal) < 200)
+        || (countitem(TerraniteOre) < 30) )
+            goto L_Legs_Wait;
+    QL_TERRANITE_ARMOR = 7;
+    delitem Coal, 200;
+    delitem TerraniteOre, 30;
+    getexp @heathin_xp_bonus, 0;
+    Zeny = Zeny - 40000;
+    mes "[Heathin]";
+    mes "\"Great, you have brought everything!  Come back later and I will have those terranite pants ready for you.\"";
+    close;
+
+L_Legs_Wait:
+    mes "[Heathin]";
+    mes "\"I am very busy right now. If you could bring me 30 Terranite Ore, 200 Coal and 40,000 gold pieces, I will make those terranite pants for you.\"";
+    close;
+
+L_Legs_Ready:
+    getinventorylist;
+    if ((checkweight("TerraniteLegs", 1) == 0) || (@inventorylist_count == 100))
+        goto L_InventoryNoSpace;
+    QL_TERRANITE_ARMOR = 8;
+    getitem "TerraniteLegs", 1;
+    mes "[Heathin]";
+    mes "\"I am all done with your terranite pants. Hope you enjoy them!  I have some more work to complete for the Council. Come back later and I might be able to assist you again.\"";
+    close;
+
+L_Chest_Armor:
+    QL_TERRANITE_ARMOR = 9;
+    mes "[Heathin]";
+    mes "\"Good to see you again. I have just finished up some more of my commission. Now I can get back to making terranite armor for you. This time, I will make some terranite chest armor, but it needs more ore, more Coal for my forge and of course, more gold to compensate for my efforts.\"";
+    next;
+    mes "\"To make terranite chest armor, I need 250 Coal, 40 Terranite Ore and 50,000 gold pieces. The faster you bring this to me, the faster I can have your terranite armor ready.\"";
+    close;
+
+L_Chest_Armor_Forge:
+    if ( (Zeny < 50000)
+        || (countitem(Coal) < 250)
+        || (countitem(TerraniteOre) < 40) )
+            goto L_Chest_Armor_Wait;
+    QL_TERRANITE_ARMOR = 10;
+    delitem Coal, 250;
+    delitem TerraniteOre, 40;
+    getexp @heathin_xp_bonus, 0;
+    Zeny = Zeny - 50000;
+    mes "[Heathin]";
+    mes "\"Splendid, you have brought everything!  Come back later and I will have the terranite chest armor ready for you.\"";
+    close;
+
+L_Chest_Armor_Wait:
+    mes "[Heathin]";
+    mes "\"I am very busy right now. If you could bring me 40 Terranite Ore, 250 Coal and 50,000 gold pieces, I will make that chest armor for you.\"";
+    close;
+
+L_Chest_Armor_Ready:
+    getinventorylist;
+    if ((checkweight("TerraniteChestArmor", 1) == 0) || (@inventorylist_count == 100))
+        goto L_InventoryNoSpace;
+    QL_TERRANITE_ARMOR = 11;
+    getitem "TerraniteChestArmor", 1;
+    mes "[Heathin]";
+    mes "\"I have completed your terranite chest armor. I hope you enjoy it!  I have some work to wrap up for the Council again, but come back later and I might be able to assist you once more.\"";
+    close;
+
+L_Arrows:
+    mes "[Heathin]";
+    mes "\"How good to see you. I have experimented a little with Terranite Ore to see what else can be done with it. It seems to have some qualities suitable for weapons, but I have only tested it with arrows. If you would like, I can make Terranite Arrows, but as as with the armor, I need Coal, Terranite Ore and payment for my efforts.\"";
+    next;
+    mes "\"Also, it might be a while until I have time to see what else I can make with terranite other than arrows, as right now the Council is keeping me rather busy with my commission. So, would you like some Terranite Arrows?\"";
+    menu
+        "No, thank you.", L_Arrows_No,
+        "Sure, I could use some arrows.", L_Arrows_Yes;
+
+L_Arrows_No:
+    mes "[Heathin]";
+    mes "\"Well, if you change your mind, I'm not going anywhere.\"";
+    close;
+
+L_Arrows_Yes:
+    QL_TERRANITE_ARMOR = 12;
+    mes "[Heathin]";
+    mes "\"Good, good. I shall begin crafting these arrows as soon as you come back. However, I cannot just make small handfuls as it would not be worth my time and effort to have my concentration interrupted for small tasks. I will make 1,000 Terranite Arrows per request, for which I will need "+@TARROW_REQ_TERRA_ORE+" Terranite Ore, "+@TARROW_REQ_COAL+" Coal and "+@TARROW_REQ_GP+" gold pieces.\"";
+    next;
+    mes "\"See you soon!\"";
+    close;
+
+L_Arrows_Forge:
+    if ( (Zeny < @TARROW_REQ_GP)
+        || (countitem(Coal) < @TARROW_REQ_COAL)
+        || (countitem(TerraniteOre) < @TARROW_REQ_TERRA_ORE) )
+            goto L_Arrows_Wait;
+    QL_TERRANITE_ARMOR = 13;
+    delitem Coal, @TARROW_REQ_COAL;
+    delitem TerraniteOre, @TARROW_REQ_TERRA_ORE;
+    getexp @heathin_xp_bonus, 0;
+    Zeny = Zeny - @TARROW_REQ_GP;
+    mes "[Heathin]";
+    mes "\"Wonderful! You have everything I asked for. I will start working on the arrows right away.\"";
+    close;
+
+L_Arrows_Wait:
+    mes "[Heathin]";
+    mes "\"If you want Terranite Arrows, please get me "+@TARROW_REQ_TERRA_ORE+" Terranite Ore, "+@TARROW_REQ_COAL+" Coal and "+@TARROW_REQ_GP+" gold pieces.\"";
+    close;
+
+L_Arrows_Ready:
+    getinventorylist;
+    if ((checkweight(TerraniteArrow, 1000) == 0) || (@inventorylist_count == 100))
+        goto L_InventoryNoSpace;
+    QL_TERRANITE_ARMOR = 14;
+    getitem TerraniteArrow, 1000;
+    mes "[Heathin]";
+    mes "\"All done, here you go!  I hope you like them. I am still working on my commission, but if you ever need any more Terranite Arrows, just come on by with "+@TARROW_REQ_COAL+" Coal, "+@TARROW_REQ_TERRA_ORE+" Terranite Ore and "+@TARROW_REQ_GP+" gold pieces and I will make another 1,000 arrows for you. By now I have enough Terranite Ore in reserve that you can just trade me my requirements to keep my resources up. Thank you for all your efforts!\"";
+    close;
+
+L_Arrows_Trade:
+    mes "[Heathin]";
+    mes "\"Hello, there. If you have "+@TARROW_REQ_COAL+" Coal, "+@TARROW_REQ_TERRA_ORE+" Terranite Ore and "+@TARROW_REQ_GP+" gold pieces, I will trade you 1,000 Terranite Arrows. Would you like some Terranite Arrows?\"";
+    menu
+        "No.", L_Arrows_Trade_No,
+        "Yes.", L_Arrows_Trade_Yes;
+
+L_Arrows_Trade_No:
+    mes "[Heathin]";
+    mes "\"Come back again if you would like to get Terranite Arrows.\"";
+    close;
+
+L_Arrows_Trade_Yes:
+    if ( (Zeny < @TARROW_REQ_GP)
+        || (countitem(Coal) < @TARROW_REQ_COAL)
+        || (countitem(TerraniteOre) < @TARROW_REQ_TERRA_ORE) )
+            goto L_Arrows_Trade_Wait;
+    getinventorylist;
+    if ((checkweight(TerraniteArrow, 1500) == 0) || (@inventorylist_count == 100))
+        goto L_InventoryNoSpace;
+    delitem Coal, @TARROW_REQ_COAL;
+    delitem TerraniteOre, @TARROW_REQ_TERRA_ORE;
+    Zeny = Zeny - @TARROW_REQ_GP;
+    @lucky = 5 * rand(Luk);
+    @lucky$ = "";
+    getitem TerraniteArrow, 1000 + @lucky;
+    mes "[Heathin]";
+    if(@lucky>0)
+        @lucky$ = " You are lucky, I could forge "+@lucky+" more arrows than expected.";
+    mes "Here you go!" + @lucky$ + " Come back again if you want more Terranite Arrows.\"";
+    close;
+
+L_Arrows_Trade_Wait:
+    mes "[Heathin]";
+    mes "\"It seems that you do not have the necessary resources for me to trade you. Please come back with "+@TARROW_REQ_COAL+" Coal, "+@TARROW_REQ_TERRA_ORE+" Terranite Ore and "+@TARROW_REQ_GP+" gold pieces if you want another 1,000 Terranite Arrows.\"";
+    close;
+
+L_InventoryNoSpace:
+    mes "[Heathin]";
+    mes "\"Hm no. You can't carry this right now. Make some room and come back.\"";
+    close;
+
+}
+001-2,25,55,0	script	HeathinDebug	NPC147,{
+    mes "[Heathin Debug]";
+    mes "Debug Action";
+    menu
+        "Reset", L_Reset,
+        "Exit", L_End;
+
+L_Reset:
+    QL_TERRANITE_ARMOR = 0;
+    mes "Reset!";
+    goto L_End;
+
+L_End:
+    end;
+
+OnInit:
+    if (!debug)
+        disablenpc "HeathinDebug";
+    end;
+}
diff --git a/npc/001-2/jhedia.txt b/npc/001-2/jhedia.txt
new file mode 100644
index 00000000..8d5e2e28
--- /dev/null
+++ b/npc/001-2/jhedia.txt
@@ -0,0 +1,60 @@
+
+001-2,23,50,0	script	Jhedia	NPC160,{
+    @Cost_Per_Ingot = 1000;
+    @iron_Ore_Per = 5;
+    @Coal_Per = 10;
+
+    mes "[Jhedia]";
+    mes "\"I forge Iron Ore into ingots. Ingots are more useful for skilled smiths, like armorers, because the ore is refined and made into useful units which can be worked with. To make ingots, I need " + @iron_Ore_Per + " Iron Ore and " + @Cost_Per_Ingot + " gp per ingot. I also need " + @Coal_Per + " Coal for my forge.\"";
+    next;
+    mes "[Jhedia]";
+    mes "\"How many ingots would you like?\"";
+    input @ingot_count;
+
+    if (@ingot_count == 0)
+        goto L_Jhedia_Bye;
+    @Zeny_cost = @ingot_count * @Cost_Per_Ingot;
+    if (countitem("IronOre") < @iron_Ore_Per * @ingot_count)
+        goto L_Jhedia_NotEnough_Ore;
+    if (countitem("Coal") < @Coal_Per * @ingot_count)
+        goto L_Jhedia_NotEnough_Coal;
+    if (Zeny < @Zeny_cost)
+        goto L_Jhedia_NotEnough_Zeny;
+    getinventorylist;
+    if (@inventorylist_count == 100
+        && countitem("IronIngot") == 0
+        && countitem("IronOre") > @ingot_count * @iron_Ore_Per
+        | countitem("Coal") > @ingot_count * @Coal_Per)
+            goto L_Jhedia_NotEnoughSlots;
+    Zeny = Zeny - @Zeny_cost;
+    delitem "IronOre", @ingot_count * @iron_Ore_Per;
+    delitem "Coal", @ingot_count * @Coal_Per;
+    getitem "IronIngot", @ingot_count;
+    close;
+
+L_Jhedia_Bye:
+    mes "[Jhedia]";
+    mes "\"Goodbye then.\"";
+    close;
+
+L_Jhedia_NotEnough_Ore:
+    mes "[Jhedia]";
+    mes "\"You do not seem to have enough Iron Ore.\"";
+    close;
+
+L_Jhedia_NotEnough_Coal:
+    mes "[Jhedia]";
+    mes "\"You do not seem to have enough Coal.\"";
+    close;
+
+L_Jhedia_NotEnough_Zeny:
+    mes "[Jhedia]";
+    mes "\"You do not seem to have enough gold pieces.\"";
+    close;
+
+L_Jhedia_NotEnoughSlots:
+    mes "[Jhedia]";
+    mes "\"You do not seem to have enough room to carry this many ingots.\"";
+    close;
+
+}
diff --git a/npc/001-2/manakins.txt b/npc/001-2/manakins.txt
new file mode 100644
index 00000000..db8ea1dd
--- /dev/null
+++ b/npc/001-2/manakins.txt
@@ -0,0 +1,45 @@
+
+001-2,29,57,0	script	Terranite Armor#Female	NPC401,{
+    mes "A complete set of female Terranite armor stands on display. These appear to be made to order.";
+    next;
+    mes "An inscription on the helmet reads \"Made by Heathin.\"";
+    close;
+}
+
+001-2,34,57,0	script	Terranite Armor#Male	NPC402,{
+    mes "A complete set of male Terranite armor stands on display. These appear to be made to order.";
+    next;
+    mes "An inscription on the helmet reads \"Made by Heathin.\"";
+    close;
+}
+
+001-2,34,62,0	script	Terranite	NPC403,{
+    mes "Ahhh! A Terranite!";
+    next;
+    mes "Wait a minute...";
+    next;
+    mes "It appears to just be a display model.";
+    close;
+}
+
+
+001-2,91,39,0	script	Talponian#Female	NPC404,{
+    mes "A female Talponian manakin stands on display.";
+    close;
+}
+
+001-2,91,44,0	script	Talponian#Male	NPC405,{
+    mes "A male Talponian manakin stands on display.";
+    close;
+}
+
+001-2,118,39,0	script	Gispaan#Female	NPC406,{
+    mes "A female Gispaan manakin stands on display.";
+    close;
+}
+
+001-2,118,44,0	script	Gispaan#Male	NPC407,{
+    mes "A male Gispaan manakin stands on display.";
+    close;
+}
+
diff --git a/npc/001-2/mapflags.txt b/npc/001-2/mapflags.txt
new file mode 100644
index 00000000..e7ed8657
--- /dev/null
+++ b/npc/001-2/mapflags.txt
@@ -0,0 +1,2 @@
+//001-2	mapflag	town
+//001-2	mapflag	resave	001-1,60,105
diff --git a/npc/001-2/pauline.txt b/npc/001-2/pauline.txt
new file mode 100644
index 00000000..992a371a
--- /dev/null
+++ b/npc/001-2/pauline.txt
@@ -0,0 +1,257 @@
+
+001-2,77,78,0	script	Pauline	NPC208,{
+
+    @Pauline_MASK = NIBBLE_4_MASK;
+    @Pauline_SHIFT = NIBBLE_4_SHIFT;
+
+    @pauline_state = ((QUEST_MAGIC2 & @Pauline_MASK) >> @Pauline_SHIFT);
+
+
+    @pauline_REWARD = 10000;
+
+    if (@pauline_state == 4)    goto L_MoreMagic;
+    if (@pauline_state == 3)    goto L_KnowIngredientsPinkie;
+    if (@pauline_state == 2)    goto L_Ingredients;
+    if (@pauline_state == 1)    goto L_Back;
+
+    if (getskilllv(SKILL_MAGIC_ASTRAL) > 0)
+        goto L_Magic;
+    mesn;
+    mes "\"I've mastered several schools of magic and fought the Yeti in Kaizei.\"";
+    next;
+    mes "\"The path of magic is a long and difficult one.\"";
+    goto L_close;
+
+L_Magic:
+    mesn;
+    mes "\"Ah. I see you are skilled in the Art of Astral Magic.\"";
+    mes "\"Who taught you?\"";
+    menu
+        "I learnt it myself!", L_Next,
+        "Sagatha is my teacher.", L_Sagatha,
+        "You must be mistaken.", L_close;
+
+L_Next:
+    mes "\"You did? Not bad. I guess then there is nothing I can teach you. Or are you interested in sharing knowledge?\"";
+    menu
+        "Yes, please.", L_Spells,
+        "No, thanks.", L_close;
+
+L_Sagatha:
+    mesn;
+    mes "\"Ah, that Witch!\"";
+    mes "\"Very well.\"";
+    next;
+    mes "\"Do you want me to teach you things Sagatha doesn't know yet?\"";
+    next;
+    menu
+        "Yes.", L_Spells,
+        "No.", L_close;
+
+L_Back:
+    mesn;
+    mes "\"So, you're back. Are you ready to share knowledge now?\"";
+    menu
+        "Yes.", L_Spells,
+        "No.", L_close;
+
+L_Spells:
+    @pauline_state = 1;
+    callsub S_Update_Mask;
+    mesn;
+    mes "\"Okay.\"";
+    mes "\"Not long ago I discovered some new caves near Tulimshar. In an abandond chamber I found some paintings on the wall.\"";
+    next;
+    mes "\"They weren't typical for this region, so I examined them closely. I found some invocations I have never heard before.\"";
+    mes "\"I thought that they would fit better into the Woodland area. I could only decipher two invocations so far. Those are two spells used to summon creatures.\"";
+    next;
+    mes "\"One was for summoning Mouboos and the other one was for summoning Pinkies.\"";
+    mes "\"Have you ever heared about those?\"";
+    next;
+    menu
+        "Yes. I thought you had something new to tell. [Walk Away]", L_close,
+        "No, tell me more.", L_Next1;
+
+L_Next1:
+    mesn;
+    mes "\"Well I could only read the invocations. So I don't exactly know what kind of ingredients you are going to need.\"";
+    mesq l("\"The first one for the mouboo was %s and the one for the pinkie was %s.", b("Kalboo"), b("Kalgina"));
+    next;
+    mes "\"For the pinkie spell my suggestion is to try similar ingredients to the other Astral spells. Try a root and some item typical for pinkies.\"";
+    mes "\"The mouboo spell might be more complicated. From what I could translate, one of the spell components is crafted by magic.\"";
+    next;
+    mes "\"When you find the right ingredients, come back and bring them to me to try those spells out.\"";
+    next;
+    mesq l("Goodbye.");
+    @pauline_state = 2;
+    callsub S_Update_Mask;
+    goto L_close;
+
+L_Ingredients:
+    mesn;
+    mes "\"Hello, have you found out what ingredients to use yet?\"";
+    menu
+        "Yes.", L_KnowIngredientsMouboo,
+        "No.", L_Next2;
+
+L_Next2:
+    mes "\"Okay. Come back as soon as you know.\"";
+    goto L_close;
+
+L_KnowIngredientsMouboo:
+    mes "\"Did you bring them?\"";
+    menu
+        "Yes." , L_Next3,
+        "No.", L_ComeBackLater;
+
+L_Next3:
+    mesq l("Then tell me the ingredients for the mouboo summoning spell and give them to me. Start with the first ingredient and then tell me the second one separately.");
+    mes "##B" + l("Drag and drop an item from your inventory.") + "##b";
+    next;
+    .@it1 = requestitem();
+    mes l("Next ingredient.");
+    mes "##B" + l("Drag and drop an item from your inventory.") + "##b";
+    .@it2 = requestitem();
+
+    if (.@it1 < 1 || .@it2 < 1)
+        goto L_Wrong;
+    if (countitem(.@it1) < 1 || countitem(.@it2) < 1)
+        goto L_NotEnough;
+    mesq l("Do you want to give me these items?");
+    menu
+        l("No."), L_ComeBackLater,
+        l("Yes."), L_Next4;
+
+L_Next4:
+    delitem .@it1, 1;
+    delitem .@it2, 1;
+    mesq l("Okay let me try this.");
+    if ((.@it1 == Root && .@it2 == MoubooFigurine) ||
+        (.@it1 == MoubooFigurine && .@it2 == Root))
+        goto L_TrySpellMouboo;
+
+    mesc l("The Witch takes %s and %s and put them togheter calling %s.", getitemlink(.@it1), getitemlink(.@it2), b("kalboo"));
+    mesc l("Nothing happens.");
+    mesn;
+    mesq l("It seems you did not tell me the correct ingredients. Come back when you find the correct ones.");
+    goto L_close;
+
+L_TrySpellMouboo:
+    mesc l("The Witch takes %s and %s and put them togheter calling %s.", getitemlink(.@it1), getitemlink(.@it2), b("kalboo"));
+    monster "001-1", 55,68, "Good", Mouboo, 1;
+    mesn;
+    mesq l("It worked!");
+    @pauline_state = 3;
+    callsub S_Update_Mask;
+    getexp @pauline_REWARD, 0;
+    goto L_close;
+
+L_KnowIngredientsPinkie:
+    mes "##B" + l("Drag and drop an item from your inventory.") + "##b";
+    next;
+    .@it1 = requestitem();
+    mes l("Next ingredient.");
+    mes "##B" + l("Drag and drop an item from your inventory.") + "##b";
+    .@it2 = requestitem();
+
+    if (.@it1 < 1 || .@it2 < 1)
+        goto L_Wrong;
+    if (countitem(.@it1) < 1 || countitem(.@it2) < 1)
+        goto L_NotEnough;
+    mesq l("Do you want to give me these items?");
+    menu
+        "No.", L_ComeBackLater,
+        "Yes.", L_Next5;
+
+L_Next5:
+    delitem .@it1, 1;
+    delitem .@it2, 1;
+    mesq l("Okay let me try this.");
+    if ((.@it1 == Root && .@it2 == PinkAntenna) ||
+        (.@it1 == PinkAntenna && .@it2 == Root))
+        goto L_TrySpellPinkie;
+
+    mesc l("The Witch takes %s and %s and put them togheter calling %s.", getitemlink(.@it1), getitemlink(.@it2), b("kalgina"));
+    mesc l("Nothing happens.");
+    mesn;
+    mesq l("It seems you did not tell me the correct ingredients. Come back when you find the correct ones.");
+    goto L_close;
+
+
+L_TrySpellPinkie:
+    mesc l("The Witch takes %s and %s and put them togheter calling %s.", getitemlink(.@it1), getitemlink(.@it2), b("kalgina"));
+    monster "001-1", 54,68, "Good", Pinkie, 1;
+    mesn;
+    mesq l("It worked!");
+    @pauline_state = 4;
+    callsub S_Update_Mask;
+    getexp @pauline_REWARD, 0;
+    goto L_close;
+
+L_MoreMagic:
+    mesn;
+    mes "\"Thanks for telling me the ingredients. As soon as I find out more about those wall paintings I will let you know.\"";
+    goto L_close;
+
+L_Wrong:
+    mes "The Witch looks at you and snorts.";
+    mesn;
+    mes "\"You told me the wrong ingredients. Come back as soon as you know the correct ones.\"";
+    goto L_close;
+
+L_NotEnough:
+    mesn;
+    mes "\"Hey, you don't have this with you!\"";
+    mes "\"Come back when you have the right ingredients.\"";
+    goto L_close;
+
+L_ComeBackLater:
+    mesn;
+    mes "\"Then come back later.\"";
+    goto L_close;
+
+L_close:
+    @pauline_ingredient1$ = "";
+    @pauline_ingredient2$ = "";
+    cleararray @items$, "", getarraysize(@items$);
+    cleararray @item_names$, "", getarraysize(@item_names$);
+    @pauline_state = 0;
+    @pauline_REWARD = 0;
+    close;
+
+S_Update_Mask:
+    QUEST_MAGIC2 = (QUEST_MAGIC2 & ~(@Pauline_MASK)) | (@pauline_state << @Pauline_SHIFT);
+    return;
+}
+
+001-2,79,74,0	script	PaulineDebug	NPC208,{
+    @Pauline_MASK = NIBBLE_4_MASK;
+    @Pauline_SHIFT = NIBBLE_4_SHIFT;
+
+    @pauline_state = ((QUEST_MAGIC2 & @Pauline_MASK) >> @Pauline_SHIFT);
+
+    mes "Reset Quest State";
+    mes @pauline_state;
+    menu
+        "Yes.", L_Next,
+        "No.", L_close;
+
+L_Next:
+    @pauline_state = 0;
+    callsub S_Update_Mask;
+    mes "Done";
+    close;
+
+L_close:
+    @pauline_state = 0;
+    close;
+
+S_Update_Mask:
+    QUEST_MAGIC2 = (QUEST_MAGIC2 & ~(@Pauline_MASK)) | (@pauline_state << @Pauline_SHIFT);
+    return;
+
+OnInit:
+    if (!debug)
+        disablenpc "PaulineDebug";
+    end;
+}
diff --git a/npc/001-2/sandra.txt b/npc/001-2/sandra.txt
new file mode 100644
index 00000000..705a6144
--- /dev/null
+++ b/npc/001-2/sandra.txt
@@ -0,0 +1,103 @@
+001-2,98,88,0	script	Sandra	NPC114,{
+    if (QL_SANDRA >= 2) goto L_Done;
+    if (QL_SANDRA == 1) goto L_Progress;
+
+    mes "[Sandra]";
+    mes "\"Hunting monsters for potion ingredients can sometimes be a difficult task.\"";
+    next;
+
+    @temp = rand(4);
+    if(@temp == 1) goto L_Opening1;
+    if(@temp == 2) goto L_Opening2;
+    if(@temp == 3) goto L_Opening3;
+    goto L_Opening0;
+
+L_Opening0:
+    mes "\"In the outskirts of Tulimshar, there are some scorpions... I need  help!  Will you help?\"";
+    next;
+    goto L_Ask;
+
+L_Opening1:
+    mes "\"When you venture to the outskirts of Tulimshar, you can spot scorpions. Will you help me kill some?\"";
+    next;
+    goto L_Ask;
+
+L_Opening2:
+    mes "\"The Scorpion Stinger carries many properties used in potions. Would you get some for me?\"";
+    next;
+    goto L_Ask;
+
+L_Opening3:
+    mes "\"You look sturdy enough, will you help me get something?\"";
+    next;
+    goto L_Ask;
+
+L_Ask:
+    menu
+        "Yes.", L_Yes,
+        "No.", L_close;
+
+L_Yes:
+    @temp = rand(3);
+    if(@temp == 1) goto L_Req1;
+    if(@temp == 2) goto L_Req2;
+    goto L_Req0;
+
+L_Req0:
+    mes "[Sandra]";
+    mes "\"I need 5 Scorpion Stingers.\"";
+    next;
+    goto L_Set;
+
+L_Req1:
+    mes "[Sandra]";
+    mes "\"I heard a while ago that stingers from scorpions can be used for medical purposes. I need you to help me get 5 Scorpion Stingers.\"";
+    next;
+    goto L_Set;
+
+L_Req2:
+    mes "[Sandra]";
+    mes "\"Bring me 5 Scorpion Stingers. I'll give you something if you do!\"";
+    next;
+    goto L_Set;
+
+L_Set:
+    QL_SANDRA = 1;
+    mes "\"Please get them for me!\"";
+    goto L_close;
+
+L_Progress:
+    if (countitem("ScorpionStinger") < 5)
+        goto L_NotEnough;
+    mes "[Sandra]";
+    mes "\"Excellent! You brought me 5 Scorpion Stingers!";
+    mes "Here's something for you.\"";
+    getinventorylist;
+    if (@inventorylist_count + (countitem("ScorpionStinger") == 5) - (countitem("Arrow") == 0) > 99)
+        goto L_TooMany;
+    delitem "ScorpionStinger", 5;
+    getitem "Bow", 1;
+    getitem "Arrow", 100;
+    QL_SANDRA = 2;
+    goto L_close;
+
+L_NotEnough:
+    mes "[Sandra]";
+    mes "\"Please hurry and bring me 5 Scorpion Stingers.\"";
+    goto L_close;
+
+L_Done:
+    mes "[Sandra]";
+    mes "\"Thank you for all your help!\"";
+    goto L_close;
+
+L_close:
+    @temp = 0;
+    close;
+
+L_TooMany:
+    next;
+    mes "[Sandra]";
+    mes "\"You don't have room for my reward. I'll wait until you do.\"";
+    goto L_close;
+}
diff --git a/npc/001-2/tathin.txt b/npc/001-2/tathin.txt
new file mode 100644
index 00000000..e8dc9394
--- /dev/null
+++ b/npc/001-2/tathin.txt
@@ -0,0 +1,28 @@
+001-2,28,21,0	script	Tathin	NPC107,{
+    mes "[Tathin]";
+    mes "\"Hello what Can I do for you?\"";
+    next;
+
+    menu
+        "I'd like to join a party.", L_Give_Party,
+        "I'd like to create my own party.", L_Give_Make_Party,
+        "Nothing, I guess.", L_close;
+
+L_Give_Party:
+    mes "[Tathin]";
+    mes "\"You'll need to be invited by an existing member of a party to join it. You may also create your own party.\"";
+    next;
+    mes "[Tathin]";
+    mes "\"Remember, parties cannot share experience if any members are more than 10 levels apart.\"";
+    menu
+      "I'd like to create my own party.", L_Give_Make_Party,
+      "Goodbye.", L_close;
+
+L_Give_Make_Party:
+    mes "[Tathin]";
+    mes "\"You can create parties with the 'new' or 'create' commands on the Party tab in the client. Parties need to have unique names.\"";
+    close;
+
+L_close:
+    close;
+}
diff --git a/npc/001-2/tondar.txt b/npc/001-2/tondar.txt
new file mode 100644
index 00000000..8ffd2523
--- /dev/null
+++ b/npc/001-2/tondar.txt
@@ -0,0 +1,55 @@
+
+001-2,95,79,0	script	Tondar	NPC168,{
+    mes "[Tondar]";
+    mes "\"We're not accepting any new students right now.\"";
+    if (getskilllv(SKILL_MAGIC) > 0)
+        goto L_may_ask;
+    goto L_End;
+
+L_may_ask:
+    next;
+    menu
+        "Can you teach me a spell?", L_Askspell,
+        "Do you have a magic library?", L_library,
+        "Are you sure?  I can pay well...", L_Nopay,
+        "That's unfortunate.", L_End,
+        "Goodbye, then.", L_End;
+
+L_library:
+    mes "[Tondar]";
+    mes "\"Of course we do. It is only for graduate students, alumni, and faculty.\"";
+    next;
+    menu
+        "Thank you, and goodbye.", L_End,
+        "Nobody else is allowed inside?", L_Next;
+
+L_Next:
+    mes "[Tondar]";
+    mes "\"Well, it is possible to get a special permit from the headmaster. But he is currently on sabbatical.\"";
+    close;
+
+L_Askspell:
+    mes "[Tondar]";
+    mes "\"We only teach spells to students.\"";
+    next;
+    menu
+        "Oh, come on... just one little spell!", L_Nopay,
+        "Pretty please?", L_spell,
+        "I can pay you, too...", L_Nopay;
+
+L_spell:
+    mes "[Tondar]";
+    mes "\"Well, all right; this one can't do much harm. Press your hands together and say `" + b("abizit") + "'.\"";
+    mes "\"This will release a steady flow of magic within you. Focus and try to control it; it is a good meditative practice.\"";
+    learnskill SKILL_ABIZIT;
+    close;
+
+L_Nopay:
+    mes "[Tondar]";
+    mes "The wizard frowns angrily.";
+    mes "\"Do not tempt me to teach you a different kind of lesson, young one!  Begone!\"";
+    goto L_End;
+
+L_End:
+    close;
+}
diff --git a/npc/001-2/wizards.txt b/npc/001-2/wizards.txt
new file mode 100644
index 00000000..9fa5fa84
--- /dev/null
+++ b/npc/001-2/wizards.txt
@@ -0,0 +1,26 @@
+
+-	script	Magic Council	NPC32767,{
+    explode .@n, strnpcinfo(0), "#";
+    if   (.@n[1] == 9) mes "The arch wizard seems to be busy.";
+    else if (.@n[1])   mes "The wizard seems to ignore you.";
+    else               mes "Strangely, you feel nothing – as if its membrane is closed to you.";
+    next;
+    mes "Perhaps you should come back later.";
+    close;
+
+OnInit:
+    .distance = 4;
+    end;
+}
+
+001-2,104,19,0	duplicate(Magic Council)	Desert Mana Seed#_M	NPC166
+001-2,99,22,0	duplicate(Magic Council)	Wizard#1	NPC355
+001-2,92,24,0	duplicate(Magic Council)	Wizard#2	NPC356
+001-2,92,30,0	duplicate(Magic Council)	Wizard#3	NPC357
+001-2,99,32,0	duplicate(Magic Council)	Wizard#4	NPC358
+001-2,110,22,0	duplicate(Magic Council)	Wizard#5	NPC359
+001-2,117,24,0	duplicate(Magic Council)	Wizard#6	NPC360
+001-2,117,30,0	duplicate(Magic Council)	Wizard#7	NPC361
+001-2,110,32,0	duplicate(Magic Council)	Wizard#8	NPC362
+001-2,104,27,0	duplicate(Magic Council)	Arch-Wizard#9	NPC354
+
diff --git a/npc/001-2/yanis.txt b/npc/001-2/yanis.txt
new file mode 100644
index 00000000..df2d8678
--- /dev/null
+++ b/npc/001-2/yanis.txt
@@ -0,0 +1,39 @@
+
+001-2,31,21,0	script	Yanis	NPC107,{
+    QUEST_NorthTulimshar = QUEST_NorthTulimshar | $@knowYanisNT;
+    @halloween_npc_id = $@halloween_npc_yanis;
+    callfunc "TrickOrTreat";
+
+    goto L_Base_Menu;
+
+L_Base_Menu:
+
+    mes "[Yanis]";
+    mes "\"Welcome. I'm handling issues with trading licenses for the shop owners in Tulimshar. Can I help you?\"";
+    if (QL_IMEC != 1)
+        menu
+            "Nothing right now.",L_BeforeClose;
+    menu
+        "Imec asked me to bring this petition.",L_Next,
+        "Nothing right now.",L_BeforeClose;
+
+L_Next:
+    mes "[Yanis]";
+    mes "\"Imec? I see. Give it to me.\"";
+    mes "Yanis has a disapproving look on his face. He takes the letter and writes something on another paper.";
+    next;
+    mes "[Yanis]";
+    mes "\"Here you have a letter of acknowledgement. You can bring that back to Imec. We will have a look at his case.\"";
+    QL_IMEC = 2;
+    goto L_BeforeClose;
+
+L_BeforeClose:
+    if (QL_KYLIAN != 3)
+        goto L_close;
+    next;
+    mes "You think that this is the person Kylian needs to talk to. You should tell him.";
+    goto L_close;
+
+L_close:
+    close;
+}