1 files changed, 83 insertions, 0 deletions
diff --git a/npc/029-0/event.txt b/npc/029-0/event.txt
index e99af2013..4af454c62 100644
--- a/npc/029-0/event.txt
+++ b/npc/029-0/event.txt
@@ -232,3 +232,86 @@ OnMinute02:
     end;
 }
 
+
+003-0-2,34,21,0	script	Alliance Officer	NPC_HALBERDBARBARIAN,{
+    mesn;
+    mesq l("Good %s, %s. The council is not in session right now.", (is_night() ? l("evening") : l("morning")), lg("peasant"));
+    if (($BETASERVER || debug) && BaseLevel < 60) goto L_PowerUp;
+    close;
+
+L_PowerUp:
+    next;
+    mesn strcharinfo(0);
+    mesq l("Could you awake my lost and forsaken potential?");
+    next;
+    mesn;
+    mesq l("Yes. I can. But this is irreversible. Are you sure you want this?");
+    next;
+    mesc l("Awake lost potential? This will mess with your char data irreversibly, beware."), 1;
+    if (askyesno() == ASK_NO) close;
+    .@equip=true;
+    // IP Blacklist
+    if (array_find($@IPBLIST$, getcharip()) >= 0)
+        .@equip=false;
+    else
+        array_push($@IPBLIST$, getcharip());
+
+    // Level up
+    freeloop(true);
+    while (BaseLevel < 60)
+        getexp NextBaseExp, 100;
+    freeloop(false);
+
+    // Skip a few quests
+    setq ShipQuests_Arpan, 5;
+    if (getq(General_Narrator) < 17) {
+        // Homunculus
+        sk_lvup(AM_REST);
+        sk_lvup(AM_RESSURECTHOMUN);
+        sk_lvup(AM_CALLHOMUN);
+        setq General_Narrator, 17;
+    }
+
+    // Monster points
+    MPQUEST=true;
+    if (!Mobpt)
+        Mobpt+=1000000;
+
+    // Magic Power
+    adddefaultskills();
+    if (!MAGIC_LVL) {
+        sk_lvup(AL_DP);
+        MAGIC_LVL=1;
+    }
+
+    // Crafting
+    if (!CRAFTQUEST) {
+        sk_lvup(TMW2_CRAFT);
+        getitembound RecipeBook, 1, 4;
+        CRAFTQUEST=true;
+    }
+
+    // Free skills
+    sk_lvup(TMW2_MANABOMB);
+    sk_lvup(any(TMW2_FROSTDIVER, TMW2_NAPALMBEAT, TMW2_MAGICSTRIKE, TMW2_METEORSTRIKE, TMW2_FIREARROW, TMW2_BRAWLING, TMW2_FALKONSTRIKE, TMW2_CHARGEDARROW));
+
+    // Pure awesomeness
+    getitembound any(StrengthFruit, AgilityFruit, VitalityFruit, IntelligenceFruit, DexterityFruit, LuckFruit), 1, 4;
+    getitembound any(StrengthFruit, AgilityFruit, VitalityFruit, IntelligenceFruit, DexterityFruit, LuckFruit), 1, 4;
+
+    // Full power
+    getitembound Wurtzite, 6, 4;
+    getitembound Bread, 10, 4;
+
+    // Regeneration and misc
+    percentheal 100,100;
+    mesc l("You awake a long forgotten potential, and feel ready to take over the world.");
+    close;
+
+OnInit:
+    .distance=4;
+    if (!$BETASERVER && !debug)
+        disablenpc .name$;
+    end;
+}
+