Initial commit

7 files changed, 273 insertions, 0 deletions

diff --git a/npc/001-2-28/_import.txt b/npc/001-2-28/_import.txt
new file mode 100644
index 000000000..a58d3feec
--- /dev/null
+++ b/npc/001-2-28/_import.txt
@@ -0,0 +1,8 @@
+// Map 001-2-28: Red Plush Inn
+// This file is generated automatically. All manually added changes will be removed when running the Converter.
+"npc/001-2-28/_warps.txt",
+"npc/001-2-28/jenna.txt",
+"npc/001-2-28/mapflags.txt",
+"npc/001-2-28/note.txt",
+"npc/001-2-28/plush.txt",
+"npc/001-2-28/shop.txt",
diff --git a/npc/001-2-28/_warps.txt b/npc/001-2-28/_warps.txt
new file mode 100644
index 000000000..4447ee632
--- /dev/null
+++ b/npc/001-2-28/_warps.txt
@@ -0,0 +1,5 @@
+// This file is generated automatically. All manually added changes will be removed when running the Converter.
+// Map 001-2-28: Red Plush Inn warps
+001-2-28,29,42,0	warp	#001-2-28_29_42	0,0,001-1,118,89
+001-2-28,61,30,0	warp	#001-2-28_61_30	0,0,001-1,135,83
+001-2-28,34,25,0	warp	#001-2-28_34_25	3,0,001-2-29,38,34
diff --git a/npc/001-2-28/jenna.txt b/npc/001-2-28/jenna.txt
new file mode 100644
index 000000000..4beb0604b
--- /dev/null
+++ b/npc/001-2-28/jenna.txt
@@ -0,0 +1,79 @@
+// Evol scripts.
+// Author:
+//    Travolta
+// Description:
+//    Jenna, waitress in Artis inn.
+
+001-2-28,52,32,0	script	Jenna#001-2-28	NPC_RAIJIN_FEMALE_WAITRESS,1,1,{
+
+    function SayRandomGreeting {
+
+        .@tick = gettimetick(1);
+        if (.@tick > @Artis_RedPlush_WaitressTick + 10)
+        {
+            setarray .messages$[0], l("Welcome to our inn!"),
+                                    l("Welcome to Red Plush."),
+                                    l("Please, have a seat."),
+                                    l("Lovely day, isn't it?");
+
+            .@r = rand(getarraysize(.messages$));
+            .@msg$ = .messages$[.@r];
+            npctalk3 .@msg$;
+            @Artis_RedPlush_WaitressTick = .@tick;
+        }
+    }
+
+    speech S_LAST_NEXT, l("Do you want a drink?");
+
+    closedialog;
+    shop "#Invisible001-2-28";
+    close;
+
+OnTimer1000:
+    dographmovestep;
+
+OnTouch:
+    SayRandomGreeting;
+    end;
+
+OnHour00:
+    if (playerattached())
+       @Artis_RedPlush_WaitressTick = 0;
+    end;
+
+OnInit:
+    .sex = G_FEMALE;
+    .distance = 5;
+    initmovegraph "m_table_1",    52, 32,
+                  "m_table_2",    56, 32,
+                  "big_table_l",  53, 27,
+                  "big_table_r",  56, 30,
+                  "s_table_1",    53, 36,
+                  "s_table_2",    58, 38,
+                  "lf_table_2",   45, 31;
+
+    setmovegraphcmd "m_table_1",   "s_table_2",  2,  "dir 4; wait 8",
+                    "m_table_1",   "lf_table_2", 1,  "dir 4; wait 8",
+                    "m_table_1",   "big_table_l",1,  "dir 0; wait 10",
+                    "m_table_2",   "m_table_1",  1,  "dir 0; wait 8",
+                    "m_table_2",   "lf_table_2", 1,  "dir 4; emote 2; wait 8",
+                    "m_table_2",   "big_table_l",2,  "dir 0; wait 8",
+                    "s_table_1",   "m_table_1",  5,  "dir 0; wait 10",
+                    "s_table_1",   "big_table_l",3,  "dir 0; wait 1; emote 103;"
+                                                     "say Thank you for the tip!;"
+                                                     "wait 15; moveon",
+                    "s_table_1",   "m_table_2",  1,  "dir 0; wait 8",
+                    "s_table_2",   "s_table_1",  1,  "wait 6",
+                    "s_table_2",   "m_table_2",  1,  "dir 0; wait 8",
+                    "big_table_l", "m_table_2",  1,  "dir 0; wait 6",
+                    "big_table_l", "s_table_1",  1,  "dir 2; wait 6",
+                    "big_table_r", "s_table_1",  1,  "dir 2; wait 6",
+                    "big_table_r", "m_table_2",  2,  "wait 8",
+                    "big_table_r", "s_table_2",  1,  "dir 4; wait 8",
+                    "lf_table_2",  "m_table_2",  1,  "dir 0; wait 8",
+                    "lf_table_2",  "big_table_r",1,  "dir 4; wait 1; emote 3; wait 6";
+
+    firstmove "wait 8";
+    initnpctimer;
+}
+
diff --git a/npc/001-2-28/mapflags.txt b/npc/001-2-28/mapflags.txt
new file mode 100644
index 000000000..8cf7ec216
--- /dev/null
+++ b/npc/001-2-28/mapflags.txt
@@ -0,0 +1 @@
+001-2-28	mapflag	town
diff --git a/npc/001-2-28/note.txt b/npc/001-2-28/note.txt
new file mode 100644
index 000000000..c57a3f21e
--- /dev/null
+++ b/npc/001-2-28/note.txt
@@ -0,0 +1,25 @@
+// Evol scripts.
+// Authors:
+//    gumi
+//    Qwerty Dragon
+//    Reid
+//    WildX
+// Description:
+//    A small note presenting the 7 main rules of Evol Online.
+
+001-2-28,36,28,0	script	Note#001-2-28	NPC_PAPER_NOTE,{
+    narrator S_LAST_NEXT,
+            l("There is a paper with some rules written on it.");
+
+    GameRules 8 | 4;
+
+    narrator S_NO_NPC_NAME,
+        l("Following these lines are some other writings on this paper."),
+        l("Do not give the password of your room to anybody! Keep it secret and try not to use the same one in any other room in the future. - Jenna");
+
+    close;
+
+OnInit:
+    .distance = 2;
+    end;
+}
diff --git a/npc/001-2-28/plush.txt b/npc/001-2-28/plush.txt
new file mode 100644
index 000000000..5600f2f24
--- /dev/null
+++ b/npc/001-2-28/plush.txt
@@ -0,0 +1,130 @@
+// Evol scripts.
+// Author:
+//    Reid
+// Description:
+//    Red, the Innkeeper.
+// Variable:
+//    INN_REGISTER
+
+001-2-28,28,28,0	script	Plush#001-2-28	NPC_RED,{
+
+    function narrator_explication {
+        narrator S_LAST_NEXT,
+            l("You will respawn at this place if defeated in combat."),
+            l("All you have to do is to select a bed in the upper level anytime after your reservation."),
+            l("Unlike other respawn points, an inn can fully restore your HP."),
+            l("Of course, you can select a bed somewhere else after your reservation, but you won't get your HP recovery until you choose to get some rest in the inn."),
+            l("You can also use your room to get some rest after a long battle. That will consume your reservation but your HP will be fully restored.");
+        return;
+    }
+
+    function accepted_room {
+        .@price = getarg(0);
+        if (Zeny < .@price)
+        {
+            speech S_FIRST_BLANK_LINE | S_LAST_NEXT, l("You don't have enough money, bring @@ E.", .@price);
+        }
+        else
+        {
+            emotion E_HAPPY;
+            Zeny = Zeny - .@price;
+            INN_REGISTER = REDPLUSH_INN;
+            PC_IS_DEAD = false;
+
+            speech S_FIRST_BLANK_LINE | S_LAST_NEXT,
+                lg("I registered you on the 4th room of the upper level.",
+                   "I registered you on the 2nd room of the upper level."),
+                l("You can go upstairs and choose a different room if you want.");
+            savepoint "001-2-29", 29, g(49, 35);
+        }
+    }
+
+    function register_room {
+        .@price = lognbaselvl(100, 10);
+
+        speech S_FIRST_BLANK_LINE | S_LAST_NEXT,
+            l("That will be @@ E to set your respawn point", .@price),
+            l("This will remain your respawn point until set elsewhere."),
+            l("Is that okay?");
+
+        if (askyesno() == ASK_YES)
+        {
+            accepted_room(.@price);
+        }
+        else
+        {
+            speech S_FIRST_BLANK_LINE | S_LAST_NEXT,
+                l("Come back later if you changed your mind!");
+        }
+
+        return;
+    }
+
+    function lodge_check {
+        if (INN_REGISTER == NO_INN)
+        {
+            register_room;
+        }
+        else if (INN_REGISTER == REDPLUSH_INN)
+        {
+            speech S_FIRST_BLANK_LINE | S_LAST_NEXT,
+                lg("You are already registered here."),
+                l("Go on the upper level if you want to change your room or to use it.");
+        }
+        else
+        {
+            speech S_FIRST_BLANK_LINE | S_LAST_NEXT,
+                lg("If you are registered somewhere else you will loose that reservation."),
+                l("Do you still want to lodge here?");
+
+            if (askyesno() == ASK_YES)
+            {
+                register_room;
+            }
+        }
+        return;
+    }
+
+    speech S_LAST_NEXT,
+        l("Welcome to the Red Plush inn!"),
+        l("What do you need?");
+
+    do
+    {
+        .@q = select(
+            l("Could I lodge here for a while?"),
+            l("What service do you offer?"),
+            l("What is your tipiou trying to do?"),
+            l("Nothing."));
+
+        switch (.@q)
+        {
+            case 1:
+                lodge_check;
+                break;
+            case 2:
+                emotion E_WINK;
+                speech S_FIRST_BLANK_LINE | S_LAST_NEXT,
+                    l("We offer a room for travelers passing by Artis, our beds are comfy and you can be guaranteed to be right as rain after a night here!"),
+                    l("If you wake up at the inn after a harsh battle, you will find yourself revitalized in an instant unlike other places where you can rest.");
+
+                narrator_explication;
+                break;
+            case 3:
+                speech S_FIRST_BLANK_LINE | S_LAST_NEXT,
+                    l("That poor one is doing his best to fly... But his last meal and the gravity is not helping him so far!");
+                break;
+            case 4:
+                break;
+        }
+    } while (.@q != 1 && .@q != 4);
+
+    closedialog;
+    goodbye;
+    close;
+
+OnInit:
+    .sex = G_FEMALE;
+    .distance = 5;
+}
+
diff --git a/npc/001-2-28/shop.txt b/npc/001-2-28/shop.txt
new file mode 100644
index 000000000..1d435c314
--- /dev/null
+++ b/npc/001-2-28/shop.txt
@@ -0,0 +1,25 @@
+// Evol scripts.
+// Authors:
+//    4144
+//    Reid
+// Description:
+//    Inn hidden shop.
+
+001-2-28,53,33,0	trader	#Invisible001-2-28	NPC_HIDDEN,{
+
+OnInit:
+    tradertype(NST_MARKET);
+
+    sellitem RedPlushWine, -1, 50;
+
+    .sex = G_OTHER;
+    .distance = 10;
+    end;
+
+OnClock0000:
+    restoreshopitem RedPlushWine, 20;
+OnClock0800:
+    restoreshopitem RedPlushWine, 20;
+OnClock1600:
+    restoreshopitem RedPlushWine, 20;
+}