path: root/npc/magic/zarkor.txt

// TMW2 script
// Author: Jesusalva <admin@tmw2.org>
//
// Magic Script: TMW2_ZARKOR
// 
// Spawns a Cave Maggot.


-	script	sk#zarkor	32767,{
    end;

OnNone:
    end;

OnCall:
    // PRE EXECUTION
    // Check Skill
    if (getskilllv(TMW2_ZARKOR) < 1)
        end;

    // Check cooldown
    if (@skzarkor_cooldown > gettimetick(0)) {
        dispbottom l("Cannot cast that now.");
        end;
    }

    // Check mana
    if (readparam(Sp) < 400) {
        dispbottom l("Insufficient mana.");
        end;
    }

    // Other requeriments
    if (countitem(ZarkorScroll) < 1) {
        dispbottom l("You need @@ to cast this skill.", getitemlink(ZarkorScroll));
        end;
    }

    // EXECUTION
    // Apply costs
    heal 0, -400;

    // Cause effect
    getmapxy(.@map$,.@x,.@y,0);
    monster(.@map$, .@x, .@y, "Summoned Monster", CaveMaggot, 1, "sk#zarkor::OnNone", Size_Medium, 1);
    dispbottom l("All monsters summoned!");
    /*
<size> can be:
	Size_Medium = medium (default)
	Size_Small = small
	Size_Large = big

<ai> can be:
	0 = none (default)
	1 = attack/friendly
	2 = sphere (Alchemist skill)
	3 = flora (Alchemist skill)
	4 = zanzou (Kagerou/Oboro skill)

    */

    // POST EXECUTION
    // set cooldown
    @skzarkor_cooldown=gettimetick(0)+20;
    end;

OnInit:
    bindatcmd "sk-zarkor", "sk#zarkor::OnCall", 0, 100, 0;
    end;
}