path: root/npc/magic/limerizer.txt

// TMW2 script
// Author: Jesusalva <admin@tmw2.org>
//
// Magic Script: TMW2_LIMERIZER
//
// Summons slimes, be careful with acid

-	script	sk#limerizer	32767,{
    end;

OnCall:
    // Other requeriments: 20x Maggot Slime
    if (countitem(MaggotSlime) < 20) {
        dispbottom l("You need 20x @@ to cast this skill.", getitemlink(MaggotSlime));
        end;
    }

    // Check cooldown
    if (@limerizer_at > gettimetick(2)) {
        dispbottom l("Skill is in cooldown for @@.", FuzzyTime(@limerizer_at));
        end;
    }

    // Setup
    @sk=TMW2_LIMERIZER;
    @mp=30;
    @amp=3;

    // Check if you have mana to cast
    // MagicCheck(SkillID, Mana{, MP per level})
    if (!MagicCheck(@sk, @mp, @amp))
        end;

    // Destroy reagents
    delitem MaggotSlime, 20;

    // set cooldown
    @limerizer_at=gettimetick(2);
    @limerizer_at=@limerizer_at+54;

    // As usual, magic profeciency affects
    if (rand(1,6) < abizit()+1) {
        // Summon Magic
        // SummonMagic(SkillID, MobID{, SkillLevelPerMob=2{, Level Override}})
        SummonMagic(@sk, any(GreenSlime,AzulSlime,RedSlime,AngryYellowSlime), 2, MAGIC_LVL+getskilllv(@sk)-1);
    } else {
        dispbottom l("The spell fails!");
    }

    // Get 3~4 mana experience point (this is NOT used by Mana Stone)
    GetManaExp(@sk, rand(3,4));

    end;

OnInit:
    bindatcmd "sk-limerizer", "sk#limerizer::OnCall", 0, 100, 0;
    end;
}