path: root/npc/magic/kalmurk.txt

// TMW2 script
// Author: Jesusalva <admin@tmw2.org>
//
// Magic Script: TMW2_KALMURK
// 
// Spawns Maggots.


-	script	sk#kalmurk	32767,{
    end;

/*
OnFriendlyDeath:
    emote 4;
    end;
*/

OnCall:
    // Other requeriments
    if (countitem(MaggotSlime) < 2) {
        dispbottom l("You need 2x @@ to cast this skill.", getitemlink(MaggotSlime));
        end;
    }

    // Check cooldown
    if (@kalmurk_at > gettimetick(2)) {
        dispbottom l("Skill is in cooldown for @@.", FuzzyTime(@kalmurk_at));
        end;
    }

    // Setup
    @sk=TMW2_KALMURK;
    @mp=200;
    @amp=50;

    // Check if you have mana to cast
    // MagicCheck(SkillID, Mana{, MP per level})
    if (!MagicCheck(@sk, @mp, @amp))
        end;

    // Destroy reagents
    delitem MaggotSlime, 2;

    // set cooldown
    @kalmurk_at=gettimetick(2);
    @kalmurk_at=@kalmurk_at+16;

    if (rand(0,5) < abizit()+1) {
        // Summon Magic
        // SummonMagic(SkillID, MobID{, MobPerSkillLevel=2{, Level Override}})
        SummonMagic(@sk, Maggot, 2, MAGIC_LVL+getskilllv(@sk));
    }

    // Get a single mana experience point (this is NOT used by Soul Menhir)
    GetManaExp(@sk, abizit()+1);

    end;

OnInit:
    bindatcmd "sk-kalmurk", "sk#kalmurk::OnCall", 0, 100, 0;
    end;
}