path: root/npc/items/books.txt

// TMW-2 script.
// Author:
//    Jesusalva
//    gumi
//    Tirifto
// Description:
//    Books used by TMW-2. Some are from evol.

000-0,0,0,0	script	#Book-Fishing1	NPC_HIDDEN,{

    function read_book {

        setnpcdialogtitle l(.book_name$);

        narrator S_FIRST_BLANK_LINE | S_LAST_NEXT,
            l("To get started with fishing, you'll need two things: a fishing rod and a bait."),
            l("You just need one fishing rod, although you should take more than one single bait.");

        @menu = 0; // reset for the rif

        do
        {
            narrator S_NO_NPC_NAME,
                l("Please select a chapter:");

            mes "";

            select
                rif(@menu == 1, "► ") + l("Ch 1 — Fishing apparatus"),
                rif(@menu == 2, "► ") + l("Ch 2 — Baits"),
                rif(@menu == 3, "► ") + l("Ch 3 — Location"),
                rif(@menu == 4, "► ") + l("Ch 4 — Casting"),
                rif(@menu == 5, "► ") + l("Ch 5 — Reeling");

            switch(@menu)
            {
                case 1:
                    narrator S_FIRST_BLANK_LINE | S_LAST_NEXT,
                        l("You'll want your fishing rod to be flexible but solid."),
                        l("Comfortable grip is important especially for newcomers, since they'll be holding it for quite a while.");
                    break;
                case 2:
                    narrator S_FIRST_BLANK_LINE | S_LAST_NEXT,
                        l("You can use many diverse items to lure fishes."),
                        l("Most common and widely popular in the fish realm are @@ and pieces of @@.",
                            getitemlink(SmallTentacles), getitemlink(Bread)),
                        l("Some types of fish also enjoy @@ quite a bit.",
                            getitemlink(Aquada)),
                        l("Some people, however, prefer to fish with more unorthodox baits, such as @@ or @@.",
                            getitemlink(RoastedMaggot), getitemlink(CaveSnakeTongue));
                    break;
                case 3:
                    narrator S_FIRST_BLANK_LINE | S_LAST_NEXT,
                        l("Find yourself a nice dry spot on a coast where you can easily reach into deep water."),
                        l("Fishing next to shallow water is not going to work well, because fishes seldom go there."),
                        l("You can easily identify fishing spots, small bubbles and fishes are visible from the surface."),
                        l("Don't forget to come as close as possible to these spots!");
                    break;
                case 4:
                    narrator S_FIRST_BLANK_LINE | S_LAST_NEXT,
                        l("Toss the hook into deep water by clicking on where you want to cast it."),
                        l("Make sure to put on a bait after you click, though!"),
                        l("After that, stay still and be patient, but also alert!");
                    break;
                case 5:
                    narrator S_FIRST_BLANK_LINE | S_LAST_NEXT,
                        l("To successfully catch a fish, you need to pull up your hook by clicking it, right after it submerges."),
                        l("Should you be too quick or wait too long, you will most likely fail.");
                    break;
            }
        } while (true);

        end;
    }

OnShelfUse:
    if (openbookshelf())
        read_book;
    bye;

OnUse:
    if (openbook())
        read_book;
    bye;

OnInit:
    .book_name$ = getitemname(FishingGuideVolI);
    .sex = G_OTHER;
    .distance = 1;
    end;
}



000-0,0,0,0	script	#Book-Petcaring	NPC_HIDDEN,{
    function read_book {
        narrator 1,
        l("So you have now a pet, who is loyal to you. It'll follow you everywhere, but there are two things you must know."),
        l("Do not let intimacy and hunger get to zero. If any of those get to zero, it'll leave you forever."),
        l("Pets must keep a strict diet. Pious eats Piberries, Bhoppers eat Aquadas, and Maggots eats Bug Legs."),
        l("However, you should only give food when it's hungry, otherwise it'll believe you're a bad owner and intimacy will decrease."),
        l("Dying will also decrease the pet intimacy, and there are bonuses when your intimacy is high!"),
        l("To perform most actions, like feeding and renaming, just right-click it. You can even put it back on the egg if its following gets too annoying."),
        l("Give your pet a nice name, and keep it healthy, and you'll be a successful pet owner!"),
        l("Some pets will also collect loot for you, right click on it so it drop whatever it is holding for you."),
        l("...And if you're still trying to check your pet stats, just hover it with your mouse. Thanks."),
        l("-- Animals Protection Agency of Hurnscald");
    }
OnShelfUse:
    @book_name$ = .bookname$;
    if (openbookshelf ())
        read_book;
    close;
OnUse:
    @book_name$ = .bookname$;
    if (openbook ())
        read_book;
    close;
OnInit:
    .bookname$ = "Fluffy Animals who Love Their Owners";
    .sex = G_OTHER;
    .distance = 1;
    end;
}























000-0,0,0,0	script	#Book-JGrimorium	NPC_HIDDEN,{

    function read_book {

        setnpcdialogtitle l(.book_name$);

        narrator S_FIRST_BLANK_LINE | S_LAST_NEXT,
            l("I, second sage of Fate, write this book. The knowledge on it shall guide you to the Secret Of Mana.");

        @menu = 0; // reset for the rif

        do
        {
            narrator S_NO_NPC_NAME,
                l("Please select a chapter:");

            mes "";

            select
                rif( MAGIC_LVL >= 2  ,rif(@menu == 1, "► ") + l("Ch 1 — Prologue")),
                rif( MAGIC_EXP   ,rif(@menu == 2, "► ") + l("Ch 2 — Mana Magic vs Common Magic")),
                rif( MAGIC_LVL >= 2   ,rif(@menu == 3, "► ") + l("Ch 3 — Subclass")),
                rif( false   ,rif(@menu == 4, "► ") + l("Ch 4 — Casting")),
                rif( false   ,rif(@menu == 5, "► ") + l("Ch 5 — Reeling")),
                l("Close");

            switch(@menu)
            {
                case 1:
                    narrator S_FIRST_BLANK_LINE | S_LAST_NEXT,
                        l("Mana is something which existed since the being, but nobody knows much about."),
                        l("This book will write itself, and reveal you the Secret Of Mana."),
                        l("Give it time, increase your magic power, and you'll find out the truth."),
                        l("Your current maximum magic efficiency is @@. This book allows you many new possibilities.", MAGIC_LVL);
                    break;
                case 2:
                    narrator S_FIRST_BLANK_LINE | S_LAST_NEXT,
                        l("There are two kind of magic: Mana Skills and Magic Skills."),
                        l("They look like the same, but they're not. Mana Skills have a Magic Experience meter and have different rules."),
                        l("Re-casting the same mana skill won't give you magic experience. Magic Skills doesn't have this system, and level up on quest or, depending on the skill, on the skill window, using Job Level."),
                        l("The easiest way to identify is: Mana Skills never target a single foe. This grimorium reports your Mana Skills.");
                    if (getskilllv(TMW2_ZARKOR))
                        mesc l("Summon Cave Maggot - @sk-zarkor");
                    if (getskilllv(TMW2_KALMURK))
                        mesc l("Summon Maggot - @sk-kalmurk");
                    if (getskilllv(TMW2_PARUM))
                        mesc l("Parum - @sk-parum");
                    next;
                    mesn l("Current Magic Control");
                    .@val=MAGIC_EXP+rand(-MAGIC_LVL*5, MAGIC_LVL*5);
                    .@base=(MAGIC_LVL**3);
                    if (.@val > .@base*5)
                        mesc l("You are perfectly in control of your magic."), 3;
                    else if (.@val > .@base*4)
                        mesc l("You are mostly in control of your magic."), 2;
                    else if (.@val > .@base*3)
                        mesc l("You are somewhat in control of your magic."), 4;
                    else if (.@val > .@base*2)
                        mesc l("Your magic is more powerful than you, but you can control."), 7;
                    else if (.@val > .@base)
                        mesc l("You still are overwhelmed by your magic."), 6;
                    else
                        mesc l("You are completly overwhelmed by your magic."), 1;
                    next;
                    break;
                case 3:
                    mesc l("You currently have @@/@@ subclass(es).", total_subclass(),max_subclass());
                    if (MAGIC_SUBCLASS & CL_PALADIN)
                        mesc lg("Paladin");
                    if (MAGIC_SUBCLASS & CL_TANKER)
                        mesc lg("Tanker");
                    if (MAGIC_SUBCLASS & CL_BERSERKER)
                        mesc lg("Berserker");
                    if (MAGIC_SUBCLASS & CL_RANGER)
                        mesc lg("Ranger");
                    if (MAGIC_SUBCLASS & CL_SNIPER)
                        mesc lg("Sniper");
                    if (MAGIC_SUBCLASS & CL_WIZARD)
                        mesc lg("Wizard");
                    if (MAGIC_SUBCLASS & CL_SAGE)
                        mesc lg("Sage");
                    if (MAGIC_SUBCLASS & CL_PRIEST)
                        mesc lg("Priest");
                    next;
                    break;
                case 4:
                    narrator S_FIRST_BLANK_LINE | S_LAST_NEXT,
                        l("-"),
                        l("-"),
                        l("-");
                    break;
                case 5:
                    narrator S_FIRST_BLANK_LINE | S_LAST_NEXT,
                        l("-"),
                        l("-");
                    break;
                default:
                    close;
            }
        } while (true);

        end;
    }

OnShelfUse:
    if (openbookshelf())
        read_book;
    bye;

OnUse:
    read_book;
    bye;

OnInit:
    .book_name$ = getitemname(JesusalvaGrimorium);
    .sex = G_OTHER;
    .distance = 1;
    end;
}