path: root/npc/042-2/door.txt

// TMW 2 Script
// Author:
//  Jesusalva
//  Micksha
// Description:
//  Controls Weapons Room basement door

042-1,51,23,0	script	#KWRDoor	NPC_HIDDEN,0,0,{
    end;

OnTouch:
    .@g=getcharid(2);
    if ($KAMELOT_KEYMASK[.@g] & 16) {
        warp "042-3@"+.@g, 44, 59;
    } else {
        dispbottom l("This door is locked.");
    }
    end;

OnKillBoss:
    .@g=getcharid(2);
    dispbottom l("You found a key.");
    getitem TreasureKey, 1;
    $KAMELOT_KEYMASK[.@g]=$KAMELOT_KEYMASK[.@g]|16;
    // Reward for completing this stage
    getitem GuildCoin, min(1, $KAMELOT_MX[.@g]/20);
    $GUILD_BANK[.@g]+=500;
    .@gxp=$KAMELOT_MX[.@g]*5;
    guildgetexp(.@gxp); // 5xp per player average level (max 500/750)
    // Announce
    mapannounce getmap(), strcharinfo(0)+" has found the key for the door!", 0;
    // Guild Master Notification
    .@gm$=getguildmaster(.@g);
    if (!getcharid(3, .@gm$)) end;
    .@gma=getcharid(3, .@gm$);
    .@gmb=getcharid(0, .@gm$);
    if (!isloggedin(.@gma, .@gmb)) end;
    message .@gm$, strcharinfo(0)+" found the key: Guild GP +500 Guild XP +"+.@gxp;
    end;
}