path: root/npc/027-1/elza.txt

// TMW2 Script
// Author:
//  Jesusalva
// Description:
//  Forgetful

027-1,86,110,0	script	Elza	312,{
    mesn l("Elza, the Forgetful");
    mesq l("What was I doing before...? I totally forgot!");
    if (any(true, false))
        mesc l("Have you seen my brother %s?", any("Enzo", "Ezra"));
    next;
    mesc l("Teaching Elza your skills will make you both forget them."), 1;
    mesc l("Once your skill is forgotten, the Magic Skill Points used will be freed."), 1;
    mesc l("But be careful: Only 3MSP-costed skills can be forgotten, and learning fees WON'T be given back!"), 1;
    do
    {
        next;
        mesc l("Which skill will you FORGET permanently today?"), 1;
        menuint
            l("Uhm... Bye?"), 0,          
            rif(getskilllv(WZ_FROSTNOVA),       l("Frost Nova")), WZ_FROSTNOVA,
            rif(getskilllv(AC_SHOWER),          l("Arrow Shower")), AC_SHOWER,
            rif(getskilllv(SN_SHARPSHOOTING),   l("Sharpshooter")), SN_SHARPSHOOTING,
            rif(getskilllv(SN_WINDWALK),   	    l("Wind Walk")), SN_WINDWALK,
            rif(getskilllv(CR_TRUST),           l("Last Man Standing")), CR_TRUST,  
            l("None at the moment!"), 0;
        if (!@menuret)
            close;
        mes "";
        mesc l("Skill @@ will be permanently lost!", @menuret), 1;
        mesc l("Continue anyway?"), 1;
        if (askyesno() == ASK_YES) {
            .@lv=getskilllv(@menuret)+2;
            skill @menuret, 0, 0;
            MAGIC_PTS-=.@lv;
            mesc l("Skill @@ has been lost", @menuret), 3;
            mesc l("You recovered @@ magic skill points", .@lv), 3;
        } else {
            mesn l("Elza, the Forgetful");
            mesq l("Uh, what?");
        }
    } while (@menuret);
    close;

OnInit:
    .sex = G_FEMALE;
    .distance = 5;
    end;

}