path: root/npc/027-0/enrique.txt

// TMW2 Script
// Author:
//  Jesusalva
// Description:
//  Enrique is the headmaster of the Academy

027-0,46,25,0	script	Enrique	NPC_BLACKALCHEMIST,{
    mesn;
    mesq l("Hello. I am Enrique, headmaster of The Academy.");
    mesc l("Your current scholar rank: %s (%s Research Points)",
            academicrank(), fnum(MAGIC_RP));
    if (!MAGIC_LVL)
        close;
    do
    {
        next;
        select
            l("Thanks!"),
            l("What is the Academy?"),
            l("What are Magic Skill Points?"),
            l("What are Research Points"),
            l("What is the Scholar Rank?"),
            l("Who are the most famous scholars?"),
            rif(!ACADEMIC_RANK, l("I would like to enroll!")),
            l("What counts for titulation? Could you give me examples?"),
            rif(getskilllv(TMW2_STUDY) < ACADEMIC_RANK, l("I would like to learn a new skill!"));
        mes "";
        switch (@menu) {
        case 1:
            goodbye();
            break;
        case 2:
            mesn;
            mesq l("The Academy Island is situated east of Land of Fire Village.");
            next;
            mesn;
            mesq l("It was built by The Alliance, and can be accessed by a ship in Tulimshar.");
            next;
            mesn;
            mesq l("As you may be aware, the Magic Council is in Tulim, after all.");
            next;
            mesn;
            mesq l("Here you can find professors, academics and researchers. Feel free to enroll in any class as well.");
            break;
        case 3:
            mesn;
            mesq l("Simply put, they are raw power.");
            next;
            mesn;
            mesq l("There is only so much magical power your body can handle without breaking.");
            next;
            mesn;
            mesq l("By \"breaking\", I do not mean death. It is something worse.");
            next;
            mesn;
            mesq l("How to expand this limit? Well, you'll need to touch a Mana Stone. If you can handle more raw power, your limit will extend.");
            next;
            mesn;
            mesq l("It also increases naturally as you grow, albeit less.");
            next;
            mesn;
            mesq l("Keep in mind, we at the Academy do not have a Mana Stone.");
            break;
        case 4:
            mesn;
            mesq l("It is something not yet fully implemented.");
            break;
        case 5:
            mesn;
            mesq l("It is something not yet fully implemented.");
            break;
        case 6:
            HallOfAcademic();
            break;
        case 7:
            mesn;
            mesq l("That is not how things are done here.");
            next;
            mesn;
            mesq l("First, you need to contribute to the common knowledge of this world. Like, write a %s or something.", "[@@https://wiki.moubootaurlegends.org/|"+l("Wiki article")+"@@]");
            next;
            mesn;
            mesq l("Then someone of a scholarship rank above your must approve it, and say that your work is enough to the next scholar rank.");
            next;
            mesn;
            mesq l("For the higher titles, you'll need vouch of multiple people. You can vouch for anyone below your rank with %s but never for someone of same or higher rank.", b("@titulate"));
            next;
            mesn;
            mesq l("Do note that abuse will cause both you and the person you vouched for to be kicked from the Academy! So be mindful with to whom you give titles.");
            next;
            mesn;
            mesq l("Abuse can be determined by your peers or by the grandmasters, so be careful.");
            break;
        case 8:
            mesn;
            mesq l("Oh, several things. It depends a bit on what the scholars consider, and the scholars... well, they change.");
            next;
            mesn;
            mesq l("For example, translations do not count. Wiki articles count.");
            next;
            mesn;
            mesq l("Writing/Updating in client-data quests.xml and items.xml with the correct information usually counts as well.");
            next;
            mesn;
            mesq l("But pretty much, anything which contributes to the common knowledge of this world. It might even be writing a NPC telling about the world history, developing software for Wiki/GameInfo/etc., it all depends on the scholars.");
            break;
        case 9:
            // TODO: Give TMW2_STUDY for MSP. Need X skills learnt or 1M GP.
            mesn;
            mesq l("Soon enough, young %s. The study skill is almost finished... Muahaha!", strcharinfo(0));
            break;
        }
    } while (@menu != 1);
    close;

OnInit:
    .distance = 4;
    .sex = G_MALE;
    end;
}