path: root/npc/027-0/emma.txt

// TMW2 Script
// Author:
//  Jesusalva
// Description:
//  Emma is Enrique's wife

027-0,88,26,2	script	Emma	NPC_DARK_SORCERER_F,{
    mesn;
    mesq l("Hello. I am Emma, Enrique's wife.");
    mesc l("Your current scholar rank: %s (%s Research Points)",
            academicrank(), fnum(MAGIC_RP));
    if (!MAGIC_LVL)
        close;
    next;
    mesn;
    mesq l("I'm currently doing tutorship for students who are... falling behind %%p");
    next;
    mesn;
    mesq l("Do you need the extra credit?");
    mesc l("Tutorship will give you Research Points."), 1;
    mesc l("You should not leave this room."), 1;
    mesc l("Tutorship is NOT the most effective way."), 1;
    next;
    mesq l("Do you need the extra credit?");
    mesc l("Cost: %d GP/min", .cost);
    mesc l("Gain: %d RP/min", .gain);
    menuint
        l("I'm fine, thanks"), 0,
        l("5 minutes"), 5,
        l("10 minutes"), 10,
        l("15 minutes"), 15,
        l("30 minutes"), 30,
        l("1 hour"), 60,
        l("2 hours"), 120,
        l("I'm fine, thanks"), 0;
    mes "";
    if (!@menuret) {
        mesn;
        mesq l("Then I hope you can keep your grades high, hmm hmm!");
        close;
    }
    if (Zeny < .cost*@menuret) {
        mesn;
        mesq l("Ara ara? You do not have enough money with you!");
        close;
    }
    Zeny-=.cost;
    addtimer2(60000, .name$+"::OnTick");
    @emmatick=max(@emmatick, gettimetick(2)) + @menuret*60;
    mesn;
    mesq l("Hmm hmm! Then, let's begin.");
    mesc l("Note: You can increase the time by talking to Emma again.");
    close;

OnTick:
    // Time out
    if (@emmatick < gettimetick(2)) {
        npctalk3 l("Enough for now. Let's rest, shall we?");
        end;
    }
    // Changed maps
    if (getmap() != "027-0")
        end;

    MAGIC_RP+=.gain;
    dispbottom l("Research Points +%d", .gain);
    addtimer2(60000, .name$+"::OnTick");
    end;

OnInit:
    .distance = 4;
    .sex = G_FEMALE;
    .cost = 5000;
    .gain = 15;
    end;
}