path: root/npc/020-7-1/sage.txt

// TMW2 scripts.
// Authors:
//    Jesusalva
//    TMW Org.
// Description:
//    Blue Sage
//
//    Minimum level: 36 (implicit)
//    Minimum jblvl: 16 (implicit)
//
// NivalisQuest_BlueSage STRUCTURE
//  FIELD 1:
//      INVESTIGATION
//      1 - STBY OUTSIDE
//      2 - ACCESS GRANTED
//      3 - QUEST ASSIGNED BY PEETU - talk to Oskari (and others)
//      4 - Oskari is OK with peetu, but wanna hear from others. He also sends you
//          to ask what Peetu happened
//      5 - Adultered ingredients seems the cause, report to Elias
//      6 - Elias is now worried about a visitor. Ask people about and report.
//      7 - If everyone found the visitor, confirm Elias the worries
//      8 - Elias sent you to Oskari to inform the issue. Blue Sage probably knew all along.
//      8/9 WARNING: will not advance unless everyone thinks Peetu is good.
//      9 - Oskari accepts the cause. Tells to report Peetu that it probably was
//          a saboutage, to check if the Silk Cocoon really was there.
//      10 - Peetu confirmed the saboutage. Report to Blue Sage.
//      11 - Blue Sage accepted the evidence, and explains about other sages issues.
//          It's not known who or what is behind this. He excuses for making you waste
//          your time. He asks you to return to him later, as he needs to write letters.
//      12 - QUEST COMPLETE - You collected your reward
//          Also picked up a letter for Frostia Mayor, about the incident (Main Story).
//  FIELD 2:
//      Bitwise (BS_QVISITOR)
//  FIELD 3:
//      Bitwise (BS_QHELPER)

020-7-1,35,59,0	script	The Blue Sage	NPC_BLUESAGE,{
    .@cindy=($@CINDY_STATE < gettimetick(2));
    .@q=getq(NivalisQuest_BlueSage);
    mesn l("Nikolai, the Blue Sage");
    if (is_night())
        .@t$=l("Good evening");
    else
        .@t$=l("Good morning");
    mesq .@t$ + l(", my name is Nikolai. I am a sage, and the owner of this place.");
    next;
    mesn l("Nikolai, the Blue Sage");
    mesq l("Not only that, but I am also Angela's husband and Nivalis Mayor. If you have any issues, you can go straight to me.");
    if (.@cindy) {
        mesc l("Nikolai takes a sweat of his head. He seems worried with Cindy.");
    }
    next;
    select
        rif(.@q, l("I came here to talk about the World's Edge.")),
        rif(.@cindy, l("Aren't you Cindy's father? Why don't you go to her rescue?")),
        l("Please excuse me, Blue Sage Nikolai.");
    mes "";
    switch (@menu) {
        case 1:
            // Quest ends at stage 12
            if (.@q == 12) {
                mesc b(l(".:: Main Quest 4-1 ::.")), 3;
                mesc l("* Get information about the World Edge"), 1;
                mesc l("@@ You need to wait further releases to continue this quest!", b(l("WARNING:")));
                close;
            }
            // You must solve the issue here, first
            mesn l("Nikolai, the Blue Sage");
            mesq l("Well, I would love to, but the house is a mess.");
            next;
            mesn l("Nikolai, the Blue Sage");
            mesq l("All Peetu have been doing the past hours was crying, and crying, and crying some more. I can't barely sleep hearing his cries from my room.");
            next;
            mesn l("Nikolai, the Blue Sage");
            mesq l("Not only that, but he is the only one here besides me who can do magic. Without him, I have to work doubled.");
            next;
            mesn l("Nikolai, the Blue Sage");
            mesq l("He should be crying in the far northeast corner of this library. Can you go there to see him?");
            next;
            mesn l("Nikolai, the Blue Sage");
            mesq l("Once he resumes working confiantly, we can go over this important subject.");
            break;
        case 2:
            // Quest ends at stage 12
            if (.@q != 12) {
                mesn l("Nikolai, the Blue Sage");
                mesq l("The house is a mess. They need me here. Also.");
                next;
            }
            mesn l("Nikolai, the Blue Sage");
            mesq l("Just like every cave below the woodlands are under the Terranite King domains, every land covered in snow is under the Yeti King's domains.");
            next;
            mesn l("Nikolai, the Blue Sage");
            mesq l("It would be unwise to pick a fight with the Yeti King himself. The whole town would suffer.");
            next;
            mesn l("Nikolai, the Blue Sage");
            mesq l("Not only that, but the Yeti King and me had an... incident, in times best forgotten. Let's not talk about it.");
            next;
            mesn l("Nikolai, the Blue Sage");
            mesq l("The situation is different if someone from Hurnscald went to her rescue. That's why I ask you to help my Cindy.");
            next;
            mesn l("Nikolai, the Blue Sage");
            mesq l("Please talk to my wife first, she knows more about the situation than I do.");
            next;
            mesq l("Also, Yetis can be crafty at times. I think someone on Hurnscald Household knew a lot about them, you might want to ask them if you ever feel struck.");
            break;
    }
    close;

OnInit:
    .sex=G_MALE;
    .distance=5;
    npcsit;
    end;
}