path: root/npc/018-5-4/elder.txt

// TMW2 Script
// Author:
//  dangerDuck
// Description:
//      Duck Elder is a friendly npc.
//      May eventually implement a quest that needs Duck Feathers
// Variable:
//      none

018-5,28,73,0	script	Duck Elder	NPC_DUCK_ELDER,{
    function elderAbout;
    function elderAboutSarah;
    function elderClose;
    mesn;
    mesq l("Hello %s. What brings you here?", get_race());
    mes ""; // Not needed
    select
        l("Oh, I'm just exploring. What can you tell me about this island?"),
        l("I came to enjoy a beautiful day with some ducks!");
    mes "";
    switch (@menu) {
        case 1:
            elderAbout();
    }
    elderClose();
    close;

function elderAbout {
    mesn;
    mesq l("This is Duck Island, the last safe refuge for birds. Ducks tend to be very peaceful, but our young ruler, King DD, has been taken up with the art of war.");
    mesn;
    mesq l("Unfortunately, he has been corrupted by the terrorist organization calling itself S.A.R.A.H. Hopefully, he will return to the ways of peace and bring prosperity to Duck Island once again.");
    mes "";
    select
        l("What's S.A.R.A.H.?"),
        l("Thanks, I think I'll continue exploring.");
    mes "";
    if (@menu == 1)
        elderAboutSarah();
    return;
}

function elderAboutSarah {
    mesn;
    mesq l("As I said, S.A.R.A.H. is a terrorist organization. They are dedicated to wiping out every single duck, worldwide. No duck has ever survived an encounter with a S.A.R.A.H. agent. You would do best to avoid them.");
    mesn;
    mesq l("I suggest you leave now, %s. If you are even suspected of being a S.A.R.A.H. agent . . .", get_race());
    close;
    return;
}

function elderClose {
    mesn;
    mesq l("Enjoy your time here, %s. And keep your eye out for agents of S.A.R.A.H.", get_race());
    mesn;
    mesq l("Perhaps you may be of assistance later . . .");
    close;
    return;
}

OnInit:
    .sex = G_OTHER;
    .distance = 4;
    end;
}