path: root/npc/017-1/nowhere_man.txt

// TMW2/LoF scripts.
// Authors:
//    TMW-LoF Team
//    Jesusalva
// Description:
//    Pachua's Cousin. On LoF/TMWA he also crafted Iron Powder, Sulfur Powder, and Yellow Powder (for magic)
//    IMPORTANT @Saulc : DO NOT GIVE ANY EXPERIENCE ON THIS NPC.
//    This is sort of a bet, you know. “Go hunt Mountain Snakes”, or bet some precious
//    crafting material on this NPC. Two choices. The easy way is RISKY, not REWARDING.
//    The refund is the exact fair price, retrieved from database. The only "loss" here
//    is that you would rather do something else with Leather Patch but instead, you "sold" it.
//    If you sell items you don't get experience, so you shouldn't get any exp here either.
//
//    This NPC could as well do Jeans Shorts, but I'm too lazy to calculate formula now.
//    The price is Cave Snake Skin in proportion to Jean Shorts rarity, and cost in proportion
//    to sell price difference.

017-1,155,162,0	script	Nowhere Man	NPC_UKAR,{
    mesn;
    mesq l("Welcome! I come from nowhere, and I hunt Snakes. I also make fine leather items from their skin!");
    next;
    mesn;
    mesq l("Actually, I need to practice a little, so I'll make them almost with no cost for you!");
    next;
    mesn;
    // 320 * 6 = 1920 GP vs 450 GP (-)
    mesq l("If you bring me 6 @@ I can make a @@ for you.", getitemlink(MountainSnakeSkin), getitemlink(LeatherGloves));
    // 95 * 2 = 190 GP vs 400 GP (210 GP)
    mesq l("If you bring me 2 @@ and 210 GP, I can make a @@ for you.", getitemlink(CaveSnakeSkin), getitemlink(JeansShorts));
    // 160 * 1 = 160 GP vs 500 GP (340 GP)
    mesq l("If you bring me 1 @@ and 440 GP, I can make a @@ for you.", getitemlink(SnakeSkin), getitemlink(LeatherPatch));
    next;
    select
        l("Nice to know. I'll come to you when random numbers try to kill me."),
        rif(countitem(MountainSnakeSkin) >= 6, l("I want the Gloves")),
        rif(countitem(CaveSnakeSkin) >= 2 && Zeny >= 210, l("I want the Shorts")),
        rif(countitem(SnakeSkin) >= 1 && Zeny >= 440, l("I want Leather Patch")),
        l("Leather... Hmm... Do I know you from somewhere? Some... desert?");

    switch (@menu) {
        case 2:
            inventoryplace LeatherGloves, 1;
            delitem MountainSnakeSkin, 6;
            getitem LeatherGloves, 1;
            mesn;
            mesq l("Many thanks!");
            break;
        case 3:
            inventoryplace JeansShorts, 1;
            delitem CaveSnakeSkin, 2;
            Zeny=Zeny-210;
            getitem JeansShorts, 1;
            mesn;
            mesq l("Many thanks!");
            break;
        case 4:
            inventoryplace LeatherPatch, 1;
            delitem SnakeSkin, 1;
            Zeny=Zeny-440;
            getitem LeatherPatch, 1;
            mesn;
            mesq l("Many thanks!");
            break;
    }
    close;


OnInit:
    .@npcId = getnpcid(0, .name$);
    setunitdata(.@npcId, UDT_HEADTOP, IceGladius);
    setunitdata(.@npcId, UDT_HEADMIDDLE, CreasedShirt);
    setunitdata(.@npcId, UDT_HEADBOTTOM, NPCEyes);
    setunitdata(.@npcId, UDT_WEAPON, CreasedShorts);
    setunitdata(.@npcId, UDT_HAIRSTYLE, 2);
    setunitdata(.@npcId, UDT_HAIRCOLOR, 4);

    .sex=G_MALE;
    .distance=5;
    end;

}