path: root/npc/014-4/thorn.txt

// TMW2 scripts.
// Authors:
//    Jesusalva
// Description:
//    Spring Quest, disabled during Easter
//    Sighly inspired with Soren and Demure relationship, I guess
//
//    SQuest_Spring
//      0 - Not Assigned
//      1 -

014-4,149,98,0	script	Thorn	NPC_THORN_NPC,{
    if (season() != SPRING && !$@GM_OVERRIDE)
        goto L_OutOfSeason;
    if ($EVENT$ == "Easter")
        goto L_QuestDisabled;

    .@q=getq(SQuest_Spring);
    mesn;
    mesq l("Blossom, blossom, why you do this to me...");
    if (.@q < 1)
        goto L_SpringQuest;

L_Main:
    next;
    .@q=getq(HurnscaldQuest_Thorn);
    if (.@q == 0) {
        mesn;
        mesq l("I'm actually half-wose. This means part of me is tree.");
        next;
        mesn;
        mesq l("I can walk, I'm just... Trapped here. That's why I need someone to help me to cultivate my wose part!");
        next;
        mesn;
        mesq l("Could you please bring me @@ @@ and @@ @@? I'll give you a bunch of herbs if you help me!", 12, getitemlink(Root), 35, getitemlink(Acorn));
        next;
        mesc l("Give him the materials he asked for?");
        if (askyesno() == ASK_YES) {
            inventoryplace ShadowHerb, 8, ArtichokeHerb, 12;
            if (!transcheck(Root, 12, Acorn, 35))
                close;
            getitem ShadowHerb, 8;
            getitem ArtichokeHerb, 12;
            getexp 600, 120; // Reference: Level 20
            mesn;
            mesq l("Thanks for helping me out. I know this is nothing, but please accept these herbs I've collected.");
            setq HurnscaldQuest_Thorn, 1;
            next;
        }
    }
    closeclientdialog;
    goodbye;
    end;

L_OutOfSeason:
    mesn;
    mesq l("Maybe on spring Blossom will look at me... For now, my wose part is withering.");
    goto L_Main;

L_QuestDisabled:
    mesn;
    mesq l("Happy Easter!");
    mesc l("The @@ quest is disabled during Easter event.", getitemlink(Wreath));
    next;
    goto L_Main;

L_SpringQuest:
    next;
    mesn;
    mesq l("Hey, you! Help me!");
    next;
    mesn;
    mesq l("My waifu Blossom has me trapped here, and she won't even look at me, because I'm part-Wose!");
    next;
    mesn;
    mesq l("But it is spring! Perhaps, if you bring me some flowers and fruits which only grow at Spring, I could impress her!");
    next;
    mesn;
    mes l("What about you bring me:");
    mes l("@@/55 @@", countitem(Rose), getitemlink(Rose));
    mes l("@@/55 @@", countitem(Tulip), getitemlink(Tulip));
    mes l("@@/50 @@", countitem(Blueberries), getitemlink(Blueberries));
    mes l("@@/10 @@", countitem(GrassSeeds), getitemlink(GrassSeeds));

    mes l("@@/80 @@", countitem(MauveHerb), getitemlink(MauveHerb));
    mes l("@@/80 @@", countitem(GambogeHerb), getitemlink(GambogeHerb));
    mes l("@@/80 @@", countitem(CobaltHerb), getitemlink(CobaltHerb));
    mes l("@@/80 @@", countitem(AlizarinHerb), getitemlink(AlizarinHerb));
    next;
    select
        l("Not now, thanks"),
        l("To be honest, I have that with me!");

    mes "";
    if (@menu == 1)
        goto L_Main;
    if (@menu == 2) {
        if (
            countitem(Rose)             < 55 ||
            countitem(Tulip)            < 55 ||
            countitem(Blueberries)      < 50 ||
            countitem(GrassSeeds)       < 10 ||
            countitem(MauveHerb)        < 80 ||
            countitem(GambogeHerb)      < 80 ||
            countitem(CobaltHerb)       < 80 ||
            countitem(AlizarinHerb)     < 70
            ) goto L_Lying;

        inventoryplace Wreath, 1;
        delitem Rose, 55;
        delitem Tulip, 55;
        delitem Blueberries, 50;
        delitem GrassSeeds, 10;
        delitem MauveHerb, 80;
        delitem GambogeHerb, 80;
        delitem CobaltHerb, 80;
        delitem AlizarinHerb, 80;
        getitem Wreath, 1;
        getexp (210*BaseLevel), 120;
        setq1 SQuest_Spring, 1;
        mesn;
        mesq l("Many thanks! If I let my wose side blossom, I'm sure she'll look at me!");
        next;
        mesn;
        mesq l("Here, take the reward as promised!");
        goto L_Main;
    }

    close;

L_Lying:
    mesn;
    mesq l("Please don't lie to me...") + " </3";
    goto L_Main;

OnInit:
    .sex=G_MALE;
    .distance=4;
	end;

}