path: root/npc/014-4/thorn.txt

// TMW2 scripts.
// Authors:
//    Jesusalva
// Description:
//    Spring Quest, disabled during Easter
//
//    SQuest_SPring

014-4,149,98,0	script	Thorn	NPC_THORN_NPC,{
    if (season() != SPRING)
        goto L_OutOfSeason;
    if ($EVENT$ == "Easter")
        goto L_QuestDisabled;

    .@q=getq(SQuest_Spring);
    mesn;
    mesq l("Brrrr... I'm freezing! The spring at Woodlands is so harsh!!");
    if (.@q < 1)
        goto L_springQuest;

L_Main:
    close;

L_OutOfSeason:
    mesn;
    mesq l("Hmm, Woodlands is a wonderful place to live in! Although it is a tad too cold on spring...");
    goto L_Main;

L_QuestDisabled:
    mesn;
    mesq l("Happy Easter!");
    mesc l("The @@ quest is disabled during Easter event.", getitemlink(Wreath));
    next;
    goto L_Main;

L_springQuest:
    next;
    mesn;
    mesq l("Hey, do you know what is good on this harsh spring? A @@!", getitemlink(Wreath));
    next;
    mesn;
    mes l("What about you bring me:");
    mes l("@@/120 @@", countitem(Snowflake), getitemlink(Snowflake));
    mes l("@@/80 @@", countitem(CaramelCandy), getitemlink(CaramelCandy));
    mes l("@@/40 @@", countitem(GingerBreadMan), getitemlink(GingerBreadMan));
    mes l("@@/10 @@", countitem(ChocolateBiscuit), getitemlink(ChocolateBiscuit)); // Found at Chocolate Slime: 4.00%
    next;
    select
        l("Not now, thanks"),
        l("To be honest, I have that with me!");

    mes "";
    if (@menu == 1)
        goto L_Main;
    if (@menu == 2) {
        if (
            countitem(Snowflake)        < 120 ||
            countitem(CaramelCandy)     < 80 ||
            countitem(GingerBreadMan)   < 40 ||
            countitem(ChocolateBiscuit) < 10
            ) goto L_Lying;

        inventoryplace Wreath, 1;
        delitem Snowflake, 120;
        delitem CaramelCandy,  80;
        delitem GingerBreadMan, 40;
        delitem ChocolateBiscuit, 10;
        getitem Wreath, 1;
        getexp 6500, 120;
        setq1 SQuest_Spring, 1;
        mesn;
        mesq l("Yay yay! Many thanks! Here, take the reward as promised!");
        next;
        mesn;
        mesq l("We can do this again on next spring!");
        goto L_Main;
    }

    close;

L_Lying:
    mesn;
    mesq l("Please don't lie to me...");
    goto L_Main;

OnInit:
    .sex=G_MALE;
    .distance=4;
	end;

}