path: root/npc/012-7/airlia.txt

// TMW2 Script
// Author:
//    Jesusalva
// Personality Traits:
//    Bitter-sweet, resentful, lovely, cute
// Description:
//    Former Town's Mayor Daughter.
//    Have a grudge against current mayor.
//    Her father was banished from the town after the famine and the Monster Attack (Siege)
//    TODO: Remember to use disablenpc() and enablenpc() to keep consistency with Hurns Liberation Day
//    A new mayor was elected, which was her family political enemy. She misses her father,
//    which she doesn't knows where he is because the banishment. Main storyline unlocks
//    this side quest, but the main storyline keeps going forward regardless of that.
//    NOTE: Here, 'main storyline' is character story, do not mistake with world main storyline.

012-7,52,58,0	script	Airlia	NPC_ELF_F,{
    .@q1=getq(HurnscaldQuest_Farmers);
    .@n = getq(General_Narrator);
    if (strcharinfo(0) == $MOST_HEROIC$) npctalk3 l("Ah, if it isn't @@? You're the talk of the town!", $MOST_HEROIC$);
    if (.@q1 == 4) goto L_Letter;
    if (.@n == 3) goto L_Mayor;
    mesn;
    mesq l("Oh, a visitor. Welcome to the city hall. Please, enjoy your stay.");
    close;

// Hurnscald Farmers Quest
L_Letter:
    mesn;
    mesq l("You're the savior of Hurnscald crops. Half from the world would die from famine, weren't for you.");
    next;
    mesn;
    mesq l("We're currently the biggest exporter of food. We may be a small town, but Tulimshar and Halinarzo can barely hold themselves.");
    next;
    mesn;
    mesq l("Here, take this @@. This is the proof that you've helped Hurnscald greatly. This shall open new opportunities to you.", getitemlink(Scythe));
    inventoryplace Scythe, 1;
    setq HurnscaldQuest_Farmers, 5;
    getitem Scythe, 1;
    getexp 0, 100;
    close;

// Main Storyline & Airlia Quest
L_Mayor:
    .@q=getq2(General_Narrator);
    if (.@q == 3) goto L_In4;
    if (.@q == 2) goto L_In3;
    if (.@q == 1) goto L_In2;
    if (.@q == 0) goto L_In1;
    mesc l("Script Error"), 1;
    close;

L_In1:
    mesn strcharinfo(0);
    mesq l("Hello! Could I see the Mayor?");
    next;
    mesn;
    mesq l("Ah... The mayor. The current mayor. Why do you even want to talk to him, anyway?");
    next;
    mesn;
    mesq l("Anyway, he is not available at the moment. Try your luck again later.");
    setq2 General_Narrator, 1;
    close;

L_In2:
    mesn strcharinfo(0);
    mesq l("Hello! Could I see the Mayor?");
    next;
    mesn;
    mesq l("I already told you he is out! Why do you even want to talk to him?! Haven't I told you to... to... leave me alone!?");
    setq2 General_Narrator, 2;
    close;

L_In3:
    mesn strcharinfo(0);
    mesq l("Hello! Could I see the Mayor?");
    next;
    mesn;
    mes "...";
    next;
    mes "... ...";
    next;
    mes "... ... ...";
    next;
    mesn;
    mesq l("Fine.");
    next;
    mesn;
    mesq l("The mayor, Rakinorf, is probably on the Inn upstairs, drinking himself to death.");
    next;
    mesn;
    mesq l("Usually only sponsors are allowed up there, but I'll make an exception today. Go meet the mayor.");
    setq2 General_Narrator, 3;
    close;

L_In4:
    mesn;
    mesq l("The mayor, Rakinorf, is probably on the Inn upstairs, drinking himself to death.");
    next;
    mesn;
    mesq l("Usually only sponsors are allowed up there, but I'll make an exception today. Go meet the mayor.");
    close;

OnInit:
    .@npcId = getnpcid(.name$);
    setunitdata(.@npcId, UDT_HEADTOP, Earmuffs);
    setunitdata(.@npcId, UDT_HEADMIDDLE, RedknightArmor);
    setunitdata(.@npcId, UDT_HEADBOTTOM, Boots);
    setunitdata(.@npcId, UDT_WEAPON, CottonSkirt);
    setunitdata(.@npcId, UDT_HAIRSTYLE, 20);
    setunitdata(.@npcId, UDT_HAIRCOLOR, 5);

    .sex = G_FEMALE;
    .distance = 5;
    end;
}