path: root/npc/009-3/dangrostra.txt

// TMW2 Script
// Author:
//    Jesusalva
// Description:
//  Dang Rostra is the seller of Halinarzo (and usually sells overpriced stuff)
//  Dang Rostra is an anagram of DragonStar, winner of Easter 2018

009-3,26,47,0	script	Dang Rostra	NPC_PLAYER,{

    mesn;
    mesq l("Halinarzo people are very poor, but we have our resources...");
    mes "";
    menu
        l("Trade"), -,
        l("Leave"), L_Close;

    closedialog;
    shop .name$;
    close;

L_Close:
    closedialog;
    goodbye;
    close;

OnInit:
    .@npcId = getnpcid(.name$);
    setunitdata(.@npcId, UDT_HEADTOP, NPCEyes);
    setunitdata(.@npcId, UDT_HEADMIDDLE, VneckJumper);
    setunitdata(.@npcId, UDT_HEADBOTTOM, RaidTrousers);
    setunitdata(.@npcId, UDT_WEAPON, LousyMoccasins); // Boots
    setunitdata(.@npcId, UDT_HAIRSTYLE, 6);
    setunitdata(.@npcId, UDT_HAIRCOLOR, 3);

    .sex = G_MALE;
    .distance = 5;
    tradertype(NST_MARKET);

    // Bows (rare)
    sellitem ShortBow, 15200, 1;
    sellitem WoodenBow, 6800, 1;
    // Misc (uncommon)
    sellitem SharpKnife, -1, 1;
    sellitem EmptyBottle, -1, 1; // You can buy some empty bottles here, but they're scarse
    sellitem LimeDye, -1, 1;
    // Arrows (common)
    sellitem Arrow, -1, 200;
    sellitem IronArrow, -1, 90;
	sellitem ArrowAmmoBox, -1, 2;
	sellitem IronAmmoBox, -1, 1;

    // Speciality Drinks (common)
	sellitem Coffee, -1, 3;
    end;

OnClock0000:
    restoreshopitem ShortBow, 15200, 1;
OnClock1200:
    restoreshopitem WoodenBow, 6800, 1;
OnClock0400:
OnClock1600:
    restoreshopitem SharpKnife, 1;
    restoreshopitem EmptyBottle, 1;
    restoreshopitem LimeDye, 1;
OnClock0800:
OnClock2000:
    restoreshopitem Arrow, 200;
    restoreshopitem IronArrow, 90;
	restoreshopitem ArrowAmmoBox, 2;
	restoreshopitem IronAmmoBox, 1;
	restoreshopitem Coffee, 3;
    end;

}