path: root/npc/009-2/scholar.txt

// TMW2/LoF scripts.
// Authors:
//    TMW-LoF Team
//    Jesusalva
// Description:
//    Permanently repeatable quest, without any special limit
// HalinarzoQuest_MageEquipment
//  0 - Haven't started
//  1 - Listened to intro about mage equipments.
//  2 - NYI: A quest to obtain more powerful magic equipment.

009-2,51,54,0	script	Bella, the Scholar	NPC_BELLA,{
    .@q=getq(HalinarzoQuest_MageEquipment);
    mesn;
    mesq l("I am Bella, the Scholar.");
    if (!mstone(MAGIC_LVL)) goto L_NotEnough;
    mesq l("Out of my experience, you are ready to learn magic.");
    next;
    mesn;
    mesq l("A pity that without being born with magic, you need a Mana Stone... And there are none left...");
    mesc l("*sigh*");
    if (.@q < 1)
        goto L_Intro;
    close;

L_NotEnough:
    if (BaseLevel < $MANA_BLVL+MAGIC_LVL*rand(15,17)) {
        mesq l("Out of my experience, your level may not be enough.");
    }
    if (JobLevel < $MANA_JLVL+MAGIC_LVL*rand(10,12)) {
        mesq l("Out of my experience, your job may not be enough.");
    }
    if (readparam(bInt) < $MANA_BINT+MAGIC_LVL*rand(10,13)) {
        mesq l("Out of my experience, your base intelligence may not be enough.");
    }
    if (.@q < 1)
        goto L_Intro;
    close;

L_Intro:
    next;
    mesn;
    mesq l("I'll only say you this once. Mages can, of course, go to battlefield in heavy armor and stuff.");
    next;
    mesn;
    mesq l("But if a mage wants to be a warrior, they won't be able to use their full magic skills.");
    next;
    mesn;
    mesq l("Mages should use equipment designed for them. Those may be lacking on defense, but will raise MP and Magic Attack.");
    mesq l("I must, however, remember that the most powerful magical equipment ##B may require intelligence ##b to use.");
    next;
    mesn;
    mesq l("Without magic attack, using a fireball at an enemy will be like throwing a stone.");
    mesq l("And without proper MP-raising equipment, you'll be exausthed after your first fireball.");
    next;
    mesn;
    mesq l("Mage equipment also raises MP recovery. So yes, a mage can use a sword and heavy armor, but...");
    mesq l("...If they decide to do so, they'll have to deal with weak magical attacks, and with quick mana depletion.");
    next;
    inventoryplace TrainingWand, 1;
    mesn;
    mesq l("Thanks for listening to my rambles. I'll gift you a @@. Of course, having a wand won't give you magic...", getitemlink(TrainingWand));
    mesq l("...You need to learn magic before this equipment being useful to you in any way.");
    setq HalinarzoQuest_MageEquipment, 1;
    getitem TrainingWand, 1;
    close;

OnInit:
    .sex=G_FEMALE;
    .distance=5;
    end;
}