path: root/npc/005-1/vincent.txt

// TMW2 scripts.
// Authors:
//    Saulc
// Variables:
//    CandorQuest_Vincent  - quest var


005-1,99,105,0	script	Vincent	NPC_PLAYER,{
    .@q = getq(CandorQuest_Vincent);
    if (.@q == 1) goto L_CheckItems;
    if (.@q == 2) goto L_QuestDone;

    speech S_LAST_BLANK_LINE,
        l("I am making a figurin with Bug legs for the upcoming festival."),
        lg("Be a friend and bring me @@ @@.", "Be a friend and bring me @@ @@.", .LegsCount, getitemlink(BugLeg));

    switch (select(l("Ok, I'll be back in no time."),
                   rif(countitem(BugLeg) >= .LegsCount, l("I have them here already.")),
                   l("Sorry, I'm doing other things at the moment.")))
    {
        case 1:
            setq CandorQuest_Vincent, 1;
            speech S_FIRST_BLANK_LINE,
                l("Thank you. I'll wait here.");
            close;
        case 2:
            setq CandorQuest_Vincent, 1;
            goto L_CheckItems;
        case 3:
            speech S_FIRST_BLANK_LINE,
                l("But I'm almost out of @@...", getitemlink(BugLeg));
            close;
    }

L_CheckItems:
    if (countitem(BugLeg) < .LegsCount)
    {
        speech
            l("Sorry, but you don't have what I need."),
            l("I need @@ @@.", .LegsCount, getitemlink(BugLeg));
        close;
    }

    speech
        l("I can't believe it! You've brought me @@ @@!", .LegsCount, getitemlink(BugLeg)),
        l("That's exactly what I needed!"),
        l("I will be forever grateful!");

    delitem BugLeg, .LegsCount;
    getexp 15, 5;
    Zeny = Zeny + 850;
    message strcharinfo(0), l("You receive @@ GP!", 850);
    setq CandorQuest_Vincent, 2;
    close;

L_QuestDone:
    speech
        l("Hey, @@!", strcharinfo(0)),
        l("My figurin is so nice!");
    tutmes l("Some quests and events, like the festival, are only available during specific times.");
    tutmes l("Some will only repeat yearly, while other events happen weekly or monthly, or in some other time aspect.");
    close;

OnInit:
    .@npcId = getnpcid(.name$);
    setunitdata(.@npcId, UDT_HEADTOP, CreasedShirt);
    setunitdata(.@npcId, UDT_HEADMIDDLE, CreasedShorts);
    setunitdata(.@npcId, UDT_HEADBOTTOM, NPCEyes);
    setunitdata(.@npcId, UDT_WEAPON, LousyMoccasins);
    setunitdata(.@npcId, UDT_HAIRSTYLE, 25);
    setunitdata(.@npcId, UDT_HAIRCOLOR, 4);

    .LegsCount = 7;

    .sex = G_MALE;
    .distance = 5;
    end;
}