path: root/npc/003-1-1/yetiking.txt

// TMW2 Scripts
// Author:
//   Jesusalva
// Description:
//   Celestia Yeti King's quest. Designed so if you're with 4 players, all 4 can
//   summon the Yeti King, helping you while doing the quest by themselves.

// TODO: OnPCDieEvent must reset quest
// setnpcdisplay getarg(0), NPC_YETI_KING

003-1-1,94,21,0	script	#YetiKingSummon	NPC_SUMMONING_CIRC,{
    .@q=getq(HurnscaldQuest_Celestia);
    if (.@q == 1) goto L_Summon;
    end;

L_Summon:
    dispbottom l("Emoc otem itey gnik!"); // come to me yeti king, spelled backwards. Sorry.
    initnpctimer;
    end;

L_Die:
    percentheal(-100, -100);
    npctalk3 l("You're playing with fire. Or ice. Or whatever.");
    closedialog;
    close;

OnTimer1000:
    setnpcdisplay getarg(0), NPC_YETI_KING;
    end;

OnTimer2000:
    npctalk("Whom dares to disturb my slumber?!");
    end;

OnTimer5000:
    if (getareausers("003-1-1", 5) < 2) {
        npctalk("A lone adventurer? Pft. I'm back to my slumber!");
        stopnpctimer;
    } else {
        npctalk("You're courageous to summon me, I'll give you that.");
        areatimer 0, "006-1", 20, 20, 70, 60, 10, "#YetiKingSummon::OnSummonTalk";
    }
    end;

OnSummonTalk:
    .@q=getq(HurnscaldQuest_Celestia);
    if (.@q != 1)
        end;
    mesn "Dah Yeti King!!";
    mesq l("Why do you summon me? Speak.");
    mes "";
    select
        l("I'm sorry, these words just came to my mind."),
        l("Celestia asks for your help.");

    mes "";

    if (@menu == 1)
        goto L_Die;

    mesn "Dah Yeti King!!";
    mesq l("Yeah yeah yeah, you're not the first one to come talking about that to me.");
    next;
    mesn "Dah Yeti King!!";
    mesq l("My answer is a no, and it'll say like that. Don't test my patience any further.");
    next;
    select
        l("You'll come with me!"),
        l("I can prove you my worth!"),
        l("Sorry! Sorry!");

    mes "";
    if (@menu == 1)
        goto L_Die;
    if (@menu == 2)
        close;

    mesn "Dah Yeti King!!";
    mesq l("Well, then I'll give you a task. We may meet again in Soren Village.");
    next;
    mesn "Dah Yeti King!!";
    mesq l("I'll warp you to the Cave Of Trials. Pass all trials, and meet me on Soren's House. Hahah!");
    setq HurnscaldQuest_Celestia, 2;
    initnpctimer;
    close;

OnInit:
    .sex = G_OTHER;
    .distance = 1;
    end;
}