path: root/npc/002-4/nard.txt

// TMW2 scripts.
// Authors:
//    Qwerty Dragon
//    Reid
//    Jesusalva
// Description:
//    Captain Nard dialogs.
//    Nard is a fair merchant ship's captain.
//    Original Nard's from Evol by Qwerty Dragon and Reid

002-4,25,26,0	script	Nard	NPC_NARD,{
    showavatar NPC_NARD;  // this is handled by avatars.xml

    .@nard = getq(ShipQuests_Nard); // TODO
    .@narrator = getq(General_Narrator);
    .@price=1500;

L_Checker:
    if (.@narrator == 1) goto L_Travel;
    if (LOCATION$ != "") goto L_NotYet;

    mesn;
    mesq l("Hello.");
    next;
    mesq l("Let me introduce myself, I am Nard, captain of this ship.");
    next;
    mesq lg("I am pleased to see that you have woken up and are active. Elmo came here to tell me this good news!");
    next;

    //setcamnpc "Elmo";
    //mesn "Elmo";
    //mesq l("Oh... Err, yes I did, or, well, good day to you!");
    //next;
    //restorecam;

    mesn;
    mesq l("Hehehe, he is a bit nervous, please forgive him, it is not everyday we have a new member in the crew!");
    next;
    mesq l("So, how do you feel? I see that Juliet did a marvellous job! You look like you're in good health now.");
    next;

L_Menu:
    menu
        lg("I feel ok."), L_Ok,
        l("Who's this Juliet?"), L_Juliet,
        lg("I'm a bit sick..."), -;

    mes "";
    mesn;
    mesq l("Oh, I was going to ask you if you wanted to help the crew search for some food and explore the island out there.");
    next;

L_MenuQuest:
    menu
        l("What do you need?"), -,
        l("Is there a reward?"), L_NeedHead,
        l("Wait, you never came here before?"), L_CandorIsland;

    mes "";
    mesn;
    mesq l("Ship travels are not free. See if you can gather some money, and I'll bring you to Tulimshar!");
    next;
    mesn;
    mesq l("Why Tulimshar, you say? Because well, believe me, if you want to find out anything, the best place to ask around is Tulim!");
    LOCATION$ = "Candor";

    //inventoryplace JohanneKey, 1;
    //setq ShipQuests_Nard, 1;
    //getitem JohanneKey, 1;

    close;


L_NeedHead:
    mes "";
    mesn;
    mesq l("You're pretty much stranded on this forsaken island if you don't help me!");
    next;
    mesq l("Also, I believe hard work always pay off.");
    next;
    goto L_MenuQuest;

L_Ok:
    mes "";
    mesn;
    mesq l("Good to know.");
    next;
    mesq l("We have made a stop at a little island, before making it on to the port of Tulimshar.");
    next;
    mesq l("It would be good for you to do some exercise, the ship isn't big enough for that.");
    next;

    goto L_SpecialTask;

L_Juliet:
    mes "";
    mesn;
    mesq l("You have an awful case of amnesia.");
    next;
    mesq l("She is the nurse and shipkeeper of this ship.");
    next;
    mesq lg("But most important, she is the one who took care of you when you were unconscious.");
    next;

L_SpecialTask:
    mesq l("I know that you are just starting to feel better, but I'd like you to explore the island we're currently at.");
    next;

    goto L_MenuQuest;

L_CandorIsland:
    mes "";
    mesn;
    mesq l("I never said that. I come here frequently to trade. It is you who should explore the island.");
    next;
    mesq l("This is ##BCandor Island##b. A very small community lives here.");
    next;
    mesq l("If they were any bigger, monsters would come and kill everyone.");
    next;

    goto L_MenuQuest;

L_NotYet:
    mesn;
    menu
        l("I've brought the money you've asked for."),-,
        l("Please excuse me, captain."), L_Close;

    mes "";
    if (Zeny >= .@price) {
        mesq l("Ten, fifty, thousand... Yep, this is the amount I've asked for.");
        next;
        setq General_Narrator, 1;
        set Zeny, Zeny-.@price;
        LOCATION$="Tulim";
        mesq l("Set sail! We're going to Tulimshar!");
        next;
        showavatar;
        setcam 0, 0;
        mes col(l("Some time later..."), 9);
        next;
        restorecam;
        showavatar NPC_NARD;  // this is handled by avatars.xml
        mesn;
        mesq l("Welcome to Tulimshar, @@!", strcharinfo(0));
        next;
        mesq l("You can explore the city as you want, but if I were you, I would visit the townhall first.");
        next;
        mesq l("When you get out of the ship, it is the first building you'll see. Talk to ##BLua##b, she is an alliance representative.");
        next;
        mesq l("The Alliance have records of everyone. And if you need another trip, talk to me!");

    } else {
        mesq l("You still haven't completed your tasks.");
        next;
        mesq l("You still need @@ GP for the trip to Tulimshar.", (.@price-Zeny));
    }
    close;

L_Travel:
    if (getq(CandorQuest_Barrel) == 4 &&
        getq(CandorQuest_HAS) == 3 &&
        getq(CandorQuest_Sailors) == 3 &&
        getq(CandorQuest_Vincent) == 2 &&
        getq(CandorQuest_Trainer) == 12)
            .@price-=500;
    mesn;
    mesq l("Hi @@.", strcharinfo(0));
    next;
    mesq l("You are currently at @@.", LOCATION$);
    mes "";
    mes l("A ship travel will cost you @@ GP.", .@price);

    if (Zeny >= .@price) {
        menu
            rif(LOCATION$ != "Candor", l("To Candor Island.")), L_TCandor,
            rif(LOCATION$ != "Tulim", l("To Tulimshar.")), L_TTulim,
            l("No, I'll save my money."), -;
    } else {
        mes l("You still need @@ GP to afford it.", (.@price-Zeny));
    }

    close;

L_TCandor:
    set Zeny, Zeny-.@price;
    LOCATION$="Candor";

    mes "";
    mesn;
    mesq l("Candor Island, then? Yes, that is a pretty island, right?");
    next;
    mesq l("I was planning to go there soon, anyway. All aboard!");
    close;

L_TTulim:
    set Zeny, Zeny-.@price;
    LOCATION$="Tulim";

    mes "";
    mesn;
    mesq l("Tulimshar, right? The oldest human city-state!");
    next;
    mesq l("I was planning to go there soon, anyway. All aboard!");
    close;

L_Close:
    close;

OnInit:
    .sex = G_MALE;
    .distance = 5;
    end;
}