path: root/npc/002-4/elmo.txt

// TMW2 Script.
// Authors:
//    Jesusalva
// Description:
//    Elmo's second dialog. He is Nard's deputy and second-in-command.
//    Elmo was created in Evol by Qwerty Dragon and Reid

002-4,27,27,0	script	Elmo	NPC_ELMO,{
    showavatar NPC_ELMO;  // this is handled by avatars.xml

    if (getq(CandorQuest_Sailors) == 2) goto L_Party;
    if (LOCATION$ == "Candor") goto L_Candor;


    sailortalk;
    end; // double-sure

L_Candor:
    mesn;
    if (getq(General_Narrator) < 1) mes l("\"Hey, have you already got the money necessary for the travel?");
    if (getq(General_Narrator) < 1) mes l("If you haven't, maybe there are a few things you can do besides selling items.\"");
    if (getq(General_Narrator) >= 1) mesq l("Maybe there are things in Candor which still require your attention? I overheard some of them.");
    next;

    mes "";

    // Valon Quest
    .@q=getq(CandorQuest_Trainer);
    if (.@q < 1) {
        mes col("##BFirst and foremost, you should talk to Trainer, inside the big house.##b", 1);
        mes l("Besides being able to train you, he is a walking encyclopedia - Ask him anything you are unsure about!");
        next;
        mes l("To find him, just leave the ship and turn left. You should also touch the Soul Menhir when you leave this ship.");
        mes l("The Soul Menhir will attach your soul, so when you die, you'll appear where you last touched it.");
        close;
    } else if (.@q < 12) {
        mes l("- Inside the big house is someone who can train you. All experience is handy!");
    }

    // Barrel Quest
    .@q=getq(CandorQuest_Barrel);
    if (.@q < 4)
        mes l("- I think you can help the storehouse for some quick cash.");
    if (getgmlevel() == 99 && .@q > 0 && .q < 4)
        mes l("Please, Game Master, help Zegas @@!", getquestlink(CandorQuest_Barrel));

    // Kids Quest
    .@q=getq(CandorQuest_HAS);
    if (.@q < 4)
        mes l("- You can always play with kids. Not very profitable, though.");

    // Sailors Quest
    .@q=getq(CandorQuest_Sailors);
    if (.@q < 3)
        mes l("- Some of our crew are missing. They're probably wasting their time at beach.");

    // Vincent Quest
    .@q=getq(CandorQuest_Vincent);
    if (.@q < 2)
        mes l("- I overheard rumors about a festival. Maybe someone needs help with their figurine?");

    // Tolchi Quest
    .@q=getq(CandorQuest_Tolchi);
    if (.@q < 2)
        mes l("- The weapon master, Tolchi, could use your help. But she will most likely force you to visit Tulimshar in the end.");

    // Maya Quest
    .@q=getq(CandorQuest_Maya);
    if (.@q < 4)
        mes l("- There is a woman walking on the island, called Maya. Once she realises you're willing to help, she'll start paying well.");

    // Ship Quests
    .@q1=getq(ShipQuests_Dan);
    .@q2=getq(ShipQuests_ChefGado);
    .@q3=getq(ShipQuests_Peter);
    if (.@q1 < 3 || .@q2 < 2 || .@q3 != 5)
        mes l("- Some sailors within this ship may need your help: Chef Gado, Dan, Peter... help them all and collect rewards!");

    // Report in an abstract way to the player how good they are at getting travel
    // discounts, and how much work is left to do. Some points are easy/required to get (eg. Dan, Peter, HAS, etc.)
    close2;
    .@n=nard_reputation();
    if (.@n >= 11)
            npctalk3 l("Nard is very impressed, you're really a hard worker. Congrats!");
    else if (.@n >= 9)
            npctalk3 l("Nard is impressed, you're a hard worker.");
    else if (.@n >= 7)
            npctalk3 l("Nard noticed your hard work.");
    else if (.@n >= 5)
            npctalk3 l("Nard likes people who work hard. Work harder!");
    else if (.@n >= 3)
            npctalk3 l("You really should do some tasks to impress our captain.");
    else
            npctalk3 l("Nard doesn't like people who gets money without working for it.");

    end;

L_Party:
    mesn;
    mesq l("What? A party?");
    next;
    setq CandorQuest_Sailors, 3;
    getexp 10, 0;
    Zeny = (Zeny + 1000);
    mesq l("Alright, I'll show up later. Thanks for calling me. Here's 1000 GP for your efforts."); // With this, the final cost is 50 GP
    close;

OnInit:
    .sex = G_MALE;
    .distance = 5;
    end;
}