path: root/npc/001-1/rewards.txt

// TMW2 Script
// Author:
//  Jesusalva
// Description:
//  Trades Strange Coins for useful items

001-1,243,26,0	script	Aeros Trader	NPC_M_COINKEEPER,{
    mesn;
    mesq l("Oh, hello there! Welcome to the Mana Plain Of Existence!");
    next;
    mesn;
    mesq l("In this wonderful realm, you can find and earn many @@, our currency!", getitemlink(StrangeCoin));
    next;
    mesn;
    mesq l("You can then trade these coins for items with me!");
    next;
    openshop;
    closedialog;
    close;

OnInit:
    .@npcId = getnpcid(0, .name$);
    setunitdata(.@npcId, UDT_HEADTOP, TopHat);
    setunitdata(.@npcId, UDT_HEADMIDDLE, GoldenWarlordPlate);
    setunitdata(.@npcId, UDT_WEAPON, JeansChaps);
    setunitdata(.@npcId, UDT_HEADBOTTOM, AssassinBoots);
    setunitdata(.@npcId, UDT_HAIRSTYLE, 25);
    setunitdata(.@npcId, UDT_HAIRCOLOR, 4);

    .sex = G_MALE;
    .distance = 5;

	tradertype(NST_CUSTOM);

	// Equipment
	sellitem ThunderStaff,20000;
	sellitem PiouEgg,4500;
    sellitem BowlerHat, 800;
	sellitem AshUrn,700;
	sellitem Googles,600;
    sellitem BunnyEars, 500;

    // Temporary, Seasonal, for events, rare drops, next release
    sellitem ChampionshipBow, 1000;
    sellitem JeansShorts, 300;
    sellitem PiouSlayer, 150;
    sellitem WoodenSword, 100;

    // Temporary, but later may sell rare dyes (eg. golden?)
    sellitem RedDye, 50;
    sellitem GreenDye, 50;
    sellitem BlueDye, 50;

    // Consumables
	sellitem ElixirOfLife,35;
	sellitem Grenade,12;
	sellitem Curshroom,7;
	sellitem PetcaringGuide,5; // I needed to add this somewhere
	end;

/* set currency to be item 828 */
OnCountFunds:
	setcurrency(countitem(StrangeCoin));
	end;

/* @price is total cost. @points is if we accept two items as currency. */
OnPayFunds:
	//dispbottom "Hi: price="+@price+" and points="+@points;
	if( countitem(StrangeCoin) < @price )
		end;
	delitem StrangeCoin,@price;
	purchaseok();
	end;

}