path: root/npc/re/quests/eden/121-130.txt

//================= Hercules Script =======================================
//=       _   _                     _
//=      | | | |                   | |
//=      | |_| | ___ _ __ ___ _   _| | ___  ___
//=      |  _  |/ _ \ '__/ __| | | | |/ _ \/ __|
//=      | | | |  __/ | | (__| |_| | |  __/\__ \
//=      \_| |_/\___|_|  \___|\__,_|_|\___||___/
//================= License ===============================================
//= This file is part of Hercules.
//= http://herc.ws - http://github.com/HerculesWS/Hercules
//=
//= Copyright (C) 2015  Hercules Dev Team
//= Copyright (C)  Dastgir
//= Copyright (C)  Capuche
//=
//= Hercules is free software: you can redistribute it and/or modify
//= it under the terms of the GNU General Public License as published by
//= the Free Software Foundation, either version 3 of the License, or
//= (at your option) any later version.
//=
//= This program is distributed in the hope that it will be useful,
//= but WITHOUT ANY WARRANTY; without even the implied warranty of
//= MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
//= GNU General Public License for more details.
//=
//= You should have received a copy of the GNU General Public License
//= along with this program.  If not, see <http://www.gnu.org/licenses/>.
//=========================================================================
//= Eden Group Quests - Mission [121-130]
//================= File Encoding =========================================
//= CP-949 (EUC-KR compatible). Do NOT read/save it as UTF-8.
//= -If the encoding is correct, the next three lines have the same length-
//= ============ �ġġġġġġġġġġġġġġġġġġġġġġġġġġġġġġġġġġġġġġġġġġġġ� ============
//= ============ ============================================= ============
//= ============ ������������������������������������������������������������������������������������������ ============
//================= Description ===========================================
//= Repeatable quests for players between BaseLevel 121 - 130.
//================= Current Version =======================================
//= 1.1
//=========================================================================

moc_para01,44,81,3	script	Melody-Jack#1	4_M_MELODY,8,8,{
	mes "[Melody-Jack]";
	if (!countitem(Para_Team_Mark)) {// Para_Team_Mark
		mes "Who the hell are you? Get out of here!";
		mes "I'm only talking to base level ^FF0000121-130^000000 adventurers.";
	}
	else if (!para_120lv01)
		mes "What? do not bother me. I am busy now.";
	else if (para_120lv01 == 1) {
		mes "You got a request from that little girl? The small, talktive and half-naked one over there?";
		next;
		select("Say yes.", "Avoid answering.");
		mes "[Melody-Jack]";
		mes "No. I do not care It will be fine if you stepped into this room not because you are lost. I need anyone except that kind of fool.";
		next;
		mes "[Melody-Jack]";
		mes "Please listen to me, I will offer you an attractive suggestion.";
		next;
		mes "[Melody-Jack]";
		mes "I am ^ff0000Melody - Jack!^000000 The best man with best dagger skills.";
		next;
		mes "Melody-Jack swipes a dagger in your direction.";
		next;
		mes "[Melody-Jack]";
		mes "I am qualified to take secret missions. And right now you're in luck.";
		next;
		mes "[Melody-Jack]";
		mes "It seems that I have to lose one mission, deal and promise, I can not take it right now.";
		next;
		mes "[Melody-Jack]";
		mes "Take my mission and solve the request of Aigu. I will compensate you.";
		next;
		mes "[Melody-Jack]";
		mes "Our deal will be kept as a secret to Aigu. If you do not have 9 lives. Lets start.";
		para_120lv01 = 2;
	}
	else if (para_120lv01 > 1) {
		mes "......";
		next;
		if (select( "Show me the requests!", "Make small-talk." ) == 2) {
			mes "[Melody-Jack]";
			mes "What? Are you interested in me?";
			next;
			switch( select( "I am interested.", "About requests", "About a deal", "What is a promise?" ) ) {
			case 1:
				mes "[Melody-Jack]";
				mes "Well go away. I have no interest in you.";
				close;
			case 2:
				mes "[Melody-Jack]";
				mes "I cannot stop it because of my bad credit. It drives me crazy.";
				next;
				mes "[Melody-Jack]";
				mes "I am lucky to make a double contract with an adventurer like you. They are not included in our contract.";
				close;
			case 3:
				mes "[Melody-Jack]";
				mes "To be honest I don't think there is anyone worthy of trust. Trust or promises are both silly.";
				next;
				mes "[Melody-Jack]";
				mes "I trust only me and my deal. Trust or promises are empty if they ar broken but if a deal is broken there is compensation or revenge.";
				close;
			case 4:
				mes "[Melody-Jack]";
				mes "Who're all of these kids?";
				next;
				mes "[Melody-Jack]";
				mes "I came out for nothing but I am supposed to fulfill my duty. I don't owe anyone a thing.";
				close;
			}
		}
		mes "[Melody-Jack]";
		if (BaseLevel < 121)
			mes "Oh, I made a mistake. You are not the level of adventurer I am looking for. I'm looking for base level 121 to 130 adventurers.";
		else if (BaseLevel < 131) {
			mes "I do not like it but a deal is a deal. Please come back after clearing monsters in the places where Aigu asked to search.";
			next;
			switch( select( "Thanatos Tower related ", "Rachel Shrine related ", "Nameless Island related ", "Abyss Lake related " ) ) {
			case 1:
				mes "[Melody-Jack]";
				mes "Thanatos tower is the most annoying place. Do not worry about your compensation. I keep my word.";
				next;
				switch( select( "Baroness of Retribution", "Lady Solace", "Mistress of Shelter", "Dame of Sentinel" ) ) {
				case 1:
					mes "[Melody-Jack]";
					if (questprogress(13120,PLAYTIME) == 1)
						mes "I think I finished today's performance. I cannot relax what if monsters show up suddenly.";
					else if (questprogress(13119,HUNTING) == 1) {
						cutin "�Ź��Ǵ�����ī��",3;  //retribution_card
						mes "I do not like that creature not because Aigu doesn't like them... How dare you? Who is punishing whom?";
						next;
						mes "[Melody-Jack]";
						mes "These are some of the most dangerous creatures in the world. These creatures deserve no justice.";
						next;
						mes "[Melody-Jack]";
						mes "Of course you can trust me. Because I believe in real deals. Lets sweep the creatures away.";
					}
					else if (questprogress(13119,HUNTING) == 2) {
						mes "Did you clear them? So that does not bother that little boy for a day. Good job.";
						callsub S_Quest,13119,13120,1;
					}
					else {
						cutin "�Ź��Ǵ�����ī��",3;  //retribution_card
						mes "As you know, Thanatos Tower is where Aigu cares the most. It is the most dangerous place in some ways.";
						next;
						mes "[Melody-Jack]";
						mes "Please clear monsters to help Aigu. Amateurs will make things messy.";
						next;
						if (select( "Take the request.", "Stop." ) == 1) {
							mes "[Melody-Jack]";
							mes "There must be a lot of them. Do not forget to keep this a secret. ";
							callsub S_Quest,13120,13119;
						}
					}
					break;
				case 2:
					mes "[Melody-Jack]";
					if (questprogress(13122,PLAYTIME) == 1)
						mes "I think I finished today's performance. I can not relax... What if monsters show up suddenly?";
					else if (questprogress(13121,HUNTING) == 1) {
						cutin "�����ϴ���",3;  //solace_card
						mes "The building does not seem to be designed by human beings and a strange melody is always playing there.";
						next;
						mes "[Melody-Jack]";
						mes "Do not fall into the mood of the melody because that can be your last song you hear.";
						next;
						mes "[Melody-Jack]";
						mes "Remember, there is strange music as sharp as knife to kill people in the world.";
					}
					else if (questprogress(13121,HUNTING) == 2) {
						mes "Have you ever heard the melody they are playing? You will have a chance if that little boy begins to play the performance again.";
						callsub S_Quest,13121,13122,1;
					}
					else {
						cutin "�����ϴ���",3;  //solace_card
						mes "Beautiful melody. Maybe it sounds beautiful because creatures are playing.";
						next;
						mes "[Melody-Jack]";
						mes "However that is another obstacle. A deal is prior to personal interest anytime. So clear Lady Solace.";
						next;
						if (select( "Take the request.", "Stop." ) == 1) {
							mes "[Melody-Jack]";
							mes "We are just keeping our end of the deal. Clear those creatures now.";
							callsub S_Quest,13122,13121;
						}
					}
					break;
				case 3:
					mes "[Melody-Jack]";
					if (questprogress(13124,PLAYTIME) == 1)
						mes "I think I finished today's performance. I can not relax... What if monsters show up suddenly?";
					else if (questprogress(13123,HUNTING) == 1) {
						cutin "�Ƚ����ִ���ī��",3;  //shelter_card
						mes "Do you know an angel that turned into a monster? I do not know if it was an angel or not. But its appearance was an angel.";
						next;
						mes "[Melody-Jack]";
						mes "Do not panic due to beautiful appearances regardless if it is an angel or a creature. You should do your job.";
						next;
						mes "[Melody-Jack]";
						mes "Everything has its time. Maybe you requested this because that time has come.";
					}
					else if (questprogress(13123,HUNTING) == 2) {
						mes "Good. Let me know if someone is looking for me. If so, I might need to change the details of the deal.";
						callsub S_Quest,13123,13124,1;
					}
					else {
						cutin "�Ƚ����ִ���ī��",3;  //shelter_card
						mes "Do you know an angel that turned into a monster? I do not know if it was an angel or not. But its appearance was an angel.";
						next;
						mes "[Melody-Jack]";
						mes "I don't care if it is a real angel or just a creature. Clear Mistress of Shelter.";
						next;
						if (select( "Take the request.", "Stop." ) == 1) {
							mes "[Melody-Jack]";
							mes "Dying flowers fall down by rain and wind. That is what you have to do.";
							emotion e_no1;
							callsub S_Quest,13124,13123;
						}
					}
					break;
				case 4:
					mes "[Melody-Jack]";
					if (questprogress(13126,PLAYTIME) == 1)
						mes "I finished my performance for today. I can not relax what if monsters show up suddenly.";
					else if (questprogress(13125,HUNTING) == 1) {
						cutin "�����ϴ���ī��",3;  //observation_card
						mes "You may have felt they are watching once you stepped into the upper area of Thanatos Tower.";
						next;
						mes "[Melody-Jack]";
						mes "Dame of Sentinel is not easy to handle so be sure to be ready to fight.";
						next;
						mes "[Melody-Jack]";
						mes "It is a fine day to die. It will be you or them so do your best.";
					}
					else if (questprogress(13125,HUNTING) == 2) {
						mes "You look fine. Maybe you are better than I thought? I did not check with my eyes though.";
						callsub S_Quest,13125,13126,1;
					}
					else {
						cutin "�����ϴ���ī��",3;  //observation_card
						mes "You will meet them if Aigu requests. The Dame of Sentinels.";
						next;
						mes "[Melody-Jack]";
						mes "I wish they are cleared as well for her to request this adventure easily.";
						next;
						if (select( "Take the request.", "Stop." ) == 1) {
							mes "[Melody-Jack]";
							mes "A request for a request... Whatever.";
							callsub S_Quest,13126,13125;
						}
					}
					break;
				}
				break;
			case 2:
				mes "[Melody-Jack]";
				mes "Aigu's adventure leads to Rachel Shrine. Okay... It is not strange if ^FF0000that human^000000 Aigu looking for is found anywhere.";
				next;
				switch( select( "Vanberk and Isilla", "Hodremlin", "Agav and Echio" ) ) {
				case 1:
					mes "[Melody-Jack]";
					if (questprogress(13128,PLAYTIME) == 1)
						mes "You may take a rest for a day. You cleared enough but fanatic is increased.";
					else if (questprogress(13127,HUNTING) == 1) {
						cutin "�̽Ƕ�ī��",3;  //isilla_card
						mes "Someone who believes they are right are the most dangerous. This world is full of fools.";
						next;
						mes "[Melody-Jack]";
						mes "Finally force others to believe what they believe. Lets clear Vanberk and Isilla.";
						next;
						mes "[Melody-Jack]";
						mes "It is not my business. But this time is different. A little boy might be in a danger so lets hurry to clear these monsters.";
					}
					else if (questprogress(13127,HUNTING) == 2) {
						mes "Just a day. Will be fine.";
						callsub S_Quest,13127,13128,1;
					}
					else {
						cutin "�Ǻ���ũī��",3;  //vanberk_card
						mes "Sanctuary in Rachel is prohibited to normal people from entering. You gotta know that.";
						next;
						mes "[Melody-Jack]";
						mes "They think they can find a clue there but it is not a safe place. You should clear Vanberk and Isilla in advance.";
						next;
						if (select( "Take the request.", "Stop." ) == 1) {
							mes "[Melody-Jack]";
							mes "Clear all as quickly as you can.";
							emotion e_flash;
							callsub S_Quest,13128,13127;
						}
					}
					break;
				case 2:
					mes "[Melody-Jack]";
					if (questprogress(13130,PLAYTIME) == 1)
						mes "Unknown mosters are dangerous so clear them first. I will inform you if something happens.";
					else if (questprogress(13129,HUNTING) == 1) {
						cutin "ȣ�巽��ī��",3;  //hodremlin_card
						mes "Cold teeth might be approaching. Its teeth are faster than your hands.";
						next;
						mes "[Melody-Jack]";
						mes "Rachel sanctuary will be approaching from everywhere. You should be careful of this one.";
						next;
						mes "[Melody-Jack]";
						mes "Just think of the job at hand. That will be enough.";
					}
					else if (questprogress(13129,HUNTING) == 2) {
						mes "I am not that worried but are you safe? Not bitten?";
						callsub S_Quest,13129,13130,1;
					}
					else {
						cutin "ȣ�巽��ī��",3;  //hodremlin_card
						mes "Fanatics are a problem. A more serious problem is that they show up suddenly.";
						next;
						mes "[Melody-Jack]";
						mes "Get rid of ^FF0000Hodremlin^000000 without any hesitation. Because they are very dangerous.";
						next;
						if (select( "Take the request.", "Stop." ) == 1) {
							mes "[Melody-Jack]";
							mes "They need faster hands than a head. I do not worry but you should be careful.";
							callsub S_Quest,13130,13129;
						}
					}
					break;
				case 3:
					mes "[Melody-Jack]";
					if (questprogress(13132,PLAYTIME) == 1)
						mes "If you can talk. There are no requests right now. Take a rest for the day.";
					else if (questprogress(13131,HUNTING) == 1) {
						cutin "��Ű��ī��",3;  //echio_card
						mes "Full of madness here. I just feel disgusting.";
						next;
						mes "[Melody-Jack]";
						mes "It is my feeling but you might like it. I am sure ^FF0000Agav^000000 and ^FF0000Echio^000000 will not like you.";
						next;
						mes "[Melody-Jack]";
						mes "They will run into you. Do not hesitate and keep focused on the job.";
					}
					else if (questprogress(13131,HUNTING) == 2) {
						mes "Found anyone? I wouldn't worry. A promise ia a promise and a deal is a deal.";
						callsub S_Quest,13131,13132,1;
					}
					else {
						cutin "�ư���ī��",3;  //agav_card
						mes "It is true that it is getting more dangerous inside of Rachel sanctuary, but Aigu will not care for things we are not sure.";
						next;
						mes "[Melody-Jack]";
						mes "That was not that bad. But someone needs to help? Lets clear ^FF0000Agav^000000 and ^FF0000Echio^000000 inside of Rachel Shrine.";
						next;
						if (select( "Take the request.", "Stop." ) == 1) {
							mes "[Melody-Jack]";
							mes "I cannot leave so farewell.";
							callsub S_Quest,13132,13131;
						}
					}
					break;
				}
				break;
			case 3:
				mes "[Melody-Jack]";
				mes "Nameless Island is not known to usual adventurers. Aigu is also interested in there.";
				next;
				switch( select( "Ragged Zombie Hunting", "Zombie Slaughter Hunting", "Banshee Hunting" ) ) {
				case 1:
					mes "[Melody-Jack]";
					if (questprogress(13134,PLAYTIME) == 1)
						mes "Ragged Zombie is reduced. It is a good time to proceed Aigu's request for a minute.";
					else if (questprogress(13133,HUNTING) == 1) {
						cutin "����������ī��",3;  //ragged_zombie_card
						mes "It is easy to meet everything on Nameless Island. So boring.";
						next;
						mes "[Melody-Jack]";
						mes "Get rid of it and help Aigu and the other adventurers.";
					}
					else if (questprogress(13133,HUNTING) == 2) {
						mes "Did you take a bath? It smells in here. But I am sure that you had a hard time with the smell.";
						callsub S_Quest,13133,13134,1;
					}
					else {
						cutin "����������ī��",3;  //ragged_zombie_card
						mes "The dead come back at night. Comes back sounds strange. Lets cut the crap.";
						next;
						mes "[Melody-Jack]";
						mes "Wish to clear ^FF0000Ragged Zombie^000000. It is easy because they show up everywhere.";
						next;
						if (select( "Take the request.", "Stop." ) == 1) {
							mes "[Melody-Jack]";
							mes "Take a ^FF0000bath^000000 and you won't smell anymore.";
							callsub S_Quest,13134,13133;
						}
					}
					break;
				case 2:
					mes "[Melody-Jack]";
					if (questprogress(13136,PLAYTIME) == 1)
						mes "I know the request to Nameless Island is not easy but I will be happy if you join again.";
					else if (questprogress(13135,HUNTING) == 1) {
						cutin "���񽽷���ī��",3;  //zombie_slaughter_card
						mes "It was not easy for me either to step into Nameless Island. I am not that patient.";
						next;
						mes "[Melody-Jack]";
						mes "But adventurers should challenge once. ^FF0000Zombie Slaughter^000000 is worth clearing.";
					}
					else if (questprogress(13135,HUNTING) == 2) {
						mes "You are quite good! You cleared them. It will take time to return.";
						callsub S_Quest,13135,13136,1;
					}
					else {
						cutin "���񽽷���ī��",3;  //zombie_slaughter_card
						mes "They are dangerous unlike Ragged Zombie because they swing something sharp.";
						next;
						mes "[Melody-Jack]";
						mes "Please clear ^FF0000Zombie Slaughter^000000. Be careful to avoid their blades.";
						next;
						if (select( "Take the request.", "Stop." ) == 1) {
							mes "[Melody-Jack]";
							mes "You've got many things to take care of so I will hold my words. Clear them.";
							callsub S_Quest,13136,13135;
						}
					}
					break;
				case 3:
					mes "[Melody-Jack]";
					if (questprogress(13138,PLAYTIME) == 1)
						mes "Banshee is cleared. Request is solved anyway but it is not the end. It will be required again sooner or later.";
					else if (questprogress(13137,HUNTING) == 1) {
						cutin "���ī��",3;  //banshee_card
						mes "You will see there are unwelcoming things while adventuring sometimes regardless of monsters and companions.";
						next;
						mes "[Melody-Jack]";
						mes "This request is like that for me. I just do not like creatures or the reason of giving this request.";
					}
					else if (questprogress(13137,HUNTING) == 2) {
						mes "You must be tired. You went to that tough place beyond your capability. Do not be angry. I will reward you for that.";
						callsub S_Quest,13137,13138,1;
					}
					else {
						cutin "���ī��",3;  //banshee_card
						mes "Please clear ^FF0000Banshee^000000 inside of Nameless Island. Do not say no. You know it is for Aigu as well.";
						next;
						mes "[Melody-Jack]";
						mes "Both Banshee and Aigu are annoying. I would not do this request but you will be different. Right?";
						next;
						if (select( "Take the request.", "Stop." ) == 1) {
							mes "[Melody-Jack]";
							mes "See? Someone needs this request. Clear ^FF0000Banshees^000000 at Nameless Island.";
							callsub S_Quest,13138,13137;
						}
					}
					break;
				}
				break;
			case 4:
				mes "[Melody-Jack]";
				mes "Abyss Lake has requests from a little girl. Very dilligent.";
				next;
				if (select( "Ferus and Bewler are cleared.", "Gold and Blue Acidus are cleared." ) == 1) {
					mes "[Melody-Jack]";
					if (questprogress(13140,PLAYTIME) == 1)
						mes "Green dragons and Red dragons remind me of watermelons.";
					else if (questprogress(13139,HUNTING) == 1) {
						cutin "�����䷯��ī��",3;  //ferus_card
						mes "Abyss Lake... Do you possibly know how to get in there? You are not an adventurer with that information?";
						next;
						mes "[Melody-Jack]";
						mes "Just in case I will give you a clue that a key and an entrance are going to be found around there.";
					}
					else if (questprogress(13139,HUNTING) == 2) {
						mes "Did you clear all of the dragons? Take a rest for a day.";
						callsub S_Quest,13139,13140,1;
					}
					else {
						cutin "�׸��䷯��ī��",3;  //ferus__card
						mes "Abyss Lake is full of dragons in and out. Dragons are not that special but there are so many.";
						next;
						mes "[Melody-Jack]";
						mes "Which one is more dangerous between Ferus and Bewler? I do not know. Clear both of them.";
						next;
						if (select( "Take the request.", "Stop." ) == 1) {
							mes "[Melody-Jack]";
							mes "Neither green nor red are disturbing. But regardless, come back after clearing all.";
							callsub S_Quest,13140,13139;
						}
					}
				}
				else {
					mes "[Melody-Jack]";
					if (questprogress(13142,PLAYTIME) == 1)
						mes "Take a rest. We should go and subdue Acidus dragons again.";
					else if (questprogress(13141,HUNTING) == 1) {
						cutin "�����ô���ī��",3;  //acidus__card
						mes "Abyss Lake is not close. But it is worth visiting.";
						next;
						mes "[Melody-Jack]";
						mes "This is technically a training exercise but just pretend you are helping someone. There will be a reward.";
					}
					else if (questprogress(13141,HUNTING) == 2) {
						mes "You are more of a talented adventurer than I thought. If you found a tactic, take care of it next time. This study is up to you.";
						callsub S_Quest,13141,13142,1;
					}
					else {
						cutin "�����",3;  //acidus_card
						mes "There is a cave where dragons are living inside of Abyss Lake. There are so many but flying things are annoying.";
						next;
						mes "[Melody-Jack]";
						mes "Subdue them as best as you can. Do not mind their colors because they are all to be cleared.";
						next;
						if (select( "Take the request.", "Stop." ) == 1) {
							mes "[Melody-Jack]";
							mes "Subdue the Gold and Blue Acidus monsters at the last level of Abyss Lake.";
							callsub S_Quest,13142,13141;
						}
					}
				}
				break;
			}
			close2;
			cutin "",255;
			end;
		}
		else {
			mes "You finished helping Aigu or did you quit? Anyways I have no more business for you. ";
			next;
			callsub S_Erasequest,
				13119,"Baroness of Retribution",
				13121,"Lady Solace",
				13123,"Mistress of Shelter",
				13125,"Dame of Sentinel",
				13127,"Vanberk and Isilla",
				13129,"Hodremlin",
				13131,"Agav and Echio",
				13133,"Ragged Zombie",
				13135,"Zombie Slaughter",
				13137,"Banshee",
				13139,"Ferus ",
				13141,"Acidus";
			mes "[Melody-Jack]";
			mes "I am not sure if you found what you are looking for... I cannot be involved anymore. Thanks.";
		}
	}
	close;
S_Quest:
	if (questprogress(getarg(0)))
		erasequest getarg(0);
	setquest getarg(1);
	if (getarg(2,0))
		getexp 900000,200000;
	return;
S_Erasequest:
	.@total = getargcount();
	for ( .@i = 0; .@i < .@total; .@i += 2 ) {
		.@quest_id = getarg(.@i);
		switch( questprogress(.@quest_id,HUNTING) ) {
		case 0:
			if (questprogress(.@quest_id+1))
				erasequest (.@quest_id+1);
			continue;
		case 1:
			mes "[Melody-Jack]";
			mes getarg(.@i+1) +" is cleared. No need to have more requests.";
			break;
		case 2:
			mes "[Melody-Jack]";
			mes getarg(.@i+1) +" is cleared. A deal is a deal. I need to get paid.";
			getexp 900000,200000;
			break;
		}
		erasequest .@quest_id;
		next;
	}
	return;
OnTouch:
	if (para_120lv01 == 1) {
		emotion e_gasp;
		mes "[Melody-Jack]";
		mes "Hey there! ... Wait.?";
		close;
	}
	end;
}

moc_para01,17,77,5	script	Aigu#1	4_F_IU,{
	mes "[Aigu]";
	if (!countitem(Para_Team_Mark)) {// Para_Team_Mark
		mes "Oh, why aren't you a part of Eden Group?";
		mes "I'm only talking to base level ^FF0000121-130^000000 adventurers.";
	}
	else if (!para_120lv01) {
		cutin "igu01",2;
		mes "Hi? A fine day like today. Can I ask for a favor? I heard that adventurers in Eden Group are nice.";
		next;
		if (select( "I'm not the nice kind.", "Sure, I'll help." ) == 1) {
			cutin "igu05",2;
			mes "[Aigu]";
			mes "yek.. I hate.";
		}
		else {
			cutin "igu03",2;
			mes "[Aigu]";
			mes "Really? I will introduce myself! I am the head of the ^ff0000Dandelion band Aigu.^000000";
			next;
			mes "[Aigu]";
			mes "I just came back from a local performance. There is someone I wanted to meet but is missing now so I came to Eden Group for a request.";
			next;
			mes "[Aigu]";
			mes "I just decided to make a request by myself because no one is in charge and everyone is busy. Thanks for the help.";
			para_120lv01 = 1;
		}
	}
	else {
		cutin "igu01",2;
		mes "It is nice to come back to Midgard! Very exciting as the first day.";
		next;
		if (select( "What is your request?", "Talk about something else." ) == 2) {
			cutin "igu01",2;
			mes "[Aigu]";
			mes "Dandelion band travels all around the world and conveys healing music to people";
			next;
			cutin "igu02",2;
			mes "[Aigu]";
			mes "Actually our songs have no magic but I am sure it helps people because I am singing.";
		}
		else if (BaseLevel < 121) {
			cutin "igu04",2;
			mes "[Aigu]";
			mes "I think it is difficult for you to get my request? For now, I think it will make more people lost. How about widening your sight by travelling?";
		}
		else if (BaseLevel < 131) {
			mes "[Aigu]";
			mes "I made a shelter for someone I am looking for and lost adventurers. I want to know which adventurer has been there.";
			next;
			switch( select( "Thanatos Tower search", "Rachel Sanctuary search", "Nameless Island search", "Abyss Lake search" ) ) {
				mes "[Aigu]";
			case 1:
				if (questprogress(13115,PLAYTIME) == 1)
					mes "I will ask to search again after for a while because there is hope since a trace of someone was found.";
				else if (questprogress(13111) == 1) {
					cutin "igu04",2;
					mes "You know someone went there but you do not know who that is? Thank you. But let me ask you to search again tomorrow since we do not know who it is.";
					callsub S_Quest,13111,13115,1250000,300000;
				}
				else if (questprogress(13107) == 1)
					mes "You may find shelter on top of the tower. Even that shelter only has water and a bonfire.";
				else {
					mes "Adventurers are easily lost because of dangerous monsters and the height of thanatos tower. But it isn't impossible for some adventurers so please check for me.";
					next;
					if (select( "Begin to search.", "Cancel." ) == 1) {
						mes "[Aigu]";
						mes "Thanatos tower is north of the Schwartzvalt Republic! It is not far from Juno or Hugel.";
						callsub S_Quest,13115,13107;// Thanatos Tower Search
					}
				}
				break;
			case 2:
				if (questprogress(13116,PLAYTIME) == 1)
					mes "Searching Rachel was enough. I will ask you again after a while.";
				else if (questprogress(13112) == 1) {
					mes "How was your trip? No special news. But it is not done yet so I will ask you to search again.";
					callsub S_Quest,13112,13116,1000000,300000;
				}
				else if (questprogress(13108) == 1)
					mes "Not able to enter the sanctuary in a usual way. It is not easy but we can find a clue at Rachel.";
				else {
					cutin "igu03",2;
					mes "There is a sanctuary inside of Rachel Shrine. It is possible to get stuck there once you're inside.";
					next;
					mes "[Aigu]";
					mes "Please take a look if there are any traces of lost adventurers at the southeast part of the 2nd floor in the middle zone.";
					next;
					if (select( "Begin the search.", "Stop." ) == 1) {
						cutin "igu05",2;
						mes "[Aigu]";
						mes "I wish you safety in your search.";
						callsub S_Quest,13116,13108;// Rachel holy ground Search
					}
				}
				break;
			case 3:
				if (questprogress(13117,PLAYTIME) == 1)
					mes "Searching Nameless Island will continue at another time. How about taking a rest for a while?";
				else if (questprogress(13113) == 1) {
					mes "Thank you! There are wandering adventurers also helping! We should continue to search anyway. Please help me next time again.";
					callsub S_Quest,13113,13117,900000,300000;
				}
				else if (questprogress(13109) == 1) {
					cutin "igu04",2;
					mes "Maybe... hanging out and drinking with the dead. But please talk with me.";
				}
				else {
					cutin "igu03",2;
					mes "Yes, Maybe they're not able to come because they've been captured by the dead! Nameless Island will be fine! Please search Nameless Island.";
					next;
					if (select( "Begin the search.", "Stop." ) == 1) {
						cutin "igu01",2;
						mes "[Aigu]";
						mes "I wil ask you to search the 1st underground of the monastery on Nameless Island. I cannot make you take that risk unless you volunteer.";
						callsub S_Quest,13117,13109;// Unknown island Search
					}
				}
				break;
			case 4:
				if (questprogress(13118,PLAYTIME) == 1)
					mes "I will try to search Abyss Lake again after a while.";
				else if (questprogress(13114) == 1) {
					cutin "igu05",2;
					mes "You came back safely but I guess there was no good result for your face. I will search more so do not disappoint! Thank you.";
					callsub S_Quest,13114,13118,900000,200000;
				}
				else if (questprogress(13110) == 1) {
					cutin "igu05",2;
					mes "Maybe, disappointed and fallen down because a monster was not found on the ground of the lake.";
				}
				else {
					mes "I suggest to search Abyss Lake precisely the cave at the middle of the lake.";
					next;
					mes "[Aigu]";
					mes "Yes! The end of a good adventure needs a dragon! I've heard there is a monster on the ground of a lake.";
					next;
					if (select( "Begin the search.", "Stop." ) == 1) {
						mes "[Aigu]";
						mes "Abyss Lake is the fastest way to get to Hugel. Please visit 3rd floor of underground cave.!";
						callsub S_Quest,13118,13110;// Abyss Lake Search
					}
				}
			}
		}
		else {
			cutin "igu04",2;
			mes "[Aigu]";
			mes "I can't give you any more search tasks right now! You need harder challenges suitable for your level.";
			callsub S_Erasequest,
				13107,"Thanatos Tower",
				13108,"Rachel Shrine",
				13109,"Nameless Island",
				13110,"Abyss Lake";
			callsub S_Erasequest2,
				13111,"Thanatos Tower",1250000,300000,
				13112,"Rachel Shrine",1000000,300000,
				13113,"Nameless Island",900000,300000,
				13114,"Abyss Lake",900000,200000;
			for ( .@i = 13115; .@i <= 13118; .@i++ )
				if (questprogress(.@i)) erasequest .@i;
		}
	}
	close2;
	cutin "",255;
	end;
S_Quest:
	if (questprogress(getarg(0)))
		erasequest getarg(0);
	setquest getarg(1);
	if (getarg(2,0))
		getexp getarg(2),getarg(3);
	return;
S_Erasequest:
	.@total = getargcount();
	for ( .@i = 0; .@i < .@total; .@i += 2 ) {
		if (questprogress(getarg(.@i))) {
			next;
			mes "[Aigu]";
			mes "Oh, you've been working on "+ getarg(.@i+1) +" Adventure task. Let me clear your record, so you can work on better tasks.";
			erasequest getarg(.@i);
		}
	}
	return;
S_Erasequest2:
	.@total = getargcount();
	for ( .@i = 0; .@i < .@total; .@i += 4 ) {
		if (questprogress(getarg(.@i))) {
			next;
			mes "[Aigu]";
			mes "Oh, you've already finished "+ getarg(.@i+1) +" Adventure. Thank you for helping me out with this task!.";
			erasequest getarg(.@i);
			getexp getarg(.@i+2),getarg(.@i+3);
		}
	}
	return;
}

-	script	Trace of an adventurer	-1,{
	.@quest = 13106 + atoi(strnpcinfo(2));
	.@delay = 13110 + atoi(strnpcinfo(2));
	if (questprogress(.@quest) == 1) {
		mes "I found traces of someone who was here but I cannot find a clue. Lets go back and report to Aigu.";
		erasequest .@quest;
		setquest .@delay;
	}
	else
		mes "There are traces of someone being here.";
	close;
}
thana_step,167,292,5	duplicate(Trace of an adventurer)	Trace of an adventurer#1	4_TRACE
ra_san05,265,69,5	duplicate(Trace of an adventurer)	Trace of an adventurer#2	4_TRACE
abbey02,155,290,5	duplicate(Trace of an adventurer)	Trace of an adventurer#3	4_TRACE
abyss_03,102,140,5	duplicate(Trace of an adventurer)	Trace of an adventurer#4	4_TRACE

tha_t06,126,128,3	script	Suspicious Monster#1	4_DEVIRUCHI,{
	mes "[Disguised Adventurer]";
	mes "I am just working at this dangerous place for 5000 zeny... Are you the adventurer who got a request from Eden Group?";
	next;
	switch( select( "Yes","No" ) ) {
	case 1:
		mes "[Disguised Adventurer]";
		if (BaseLevel < 121 || BaseLevel > 130) {
			mes "I could see that is not you at first glance!";
			close;
		}
		mes "The adventurers proceeding the request for Aigu are warped to the upper level on behalf of Aigu.";
		next;
		if (select( "Go up.", "Do not go up." ) == 1) {
			mes "[Disguised Adventurer]";
			if (questprogress(13107) != 1)
				mes "It seems that you're currently not doing the Thanatos Tower adventure request. I'm sorry but I'm doing this for Aigu and not you.";
			else {
				mes "Be careful! You can not come down once you go up. For Aigu!";
				close2;
				warp "thana_step",69,369;
				end;
			}
		}
		close;
	case 2:
		mes "[Disguised Adventurer]";
		mes "Or please pretend not to know me! I will be in a danger if you blow my cover!";
		close;
	}
}