Merged/Updated/Added scripts from rAthena.

- Fixed Bug #7400

Signed-off-by: j-tkay <joseph.tk.ea@gmail.com>

1 files changed, 350 insertions, 2 deletions

diff --git a/npc/re/merchants/coin_exchange.txt b/npc/re/merchants/coin_exchange.txt
index 7ee6a53af..a78491ffc 100644
--- a/npc/re/merchants/coin_exchange.txt
+++ b/npc/re/merchants/coin_exchange.txt
@@ -3,7 +3,7 @@
 //===== By: ==================================================
 //= Hercules Dev Team
 //===== Current Version: =====================================
-//= 1.1
+//= 1.2
 //===== Compatible With: =====================================
 //= Hercules
 //===== Description: =========================================
@@ -12,6 +12,7 @@
 //===== Additional Comments: =================================
 //= 1.0 First version. [Euphy/Lemongrass]
 //= 1.1 Added remaining Malangdo traders. [Euphy/Lemongrass]
+//= 1.2 Added Eclage traders (not fully complete). [Euphy]
 //============================================================
 
 // Malangdo
@@ -434,7 +435,7 @@ function	script	F_mal_coin	{
 			mes "Ahaaa~";
 			mes "If you want to buy this stuff,";
 			mes "you can talk to me";
-			mes "when you grow up little more.";
+			mes "when you grow up a little more.";
 			mes "This stuff is too expensive";
 			mes "for a child~";
 			close;
@@ -825,3 +826,350 @@ malangdo,150,135,5	script	Roving Merchant	495,{
 		next;
 	}
 }
+
+// Eclage
+//============================================================
+ecl_in01,66,95,2	script	Armor Merchant Naphara	436,{
+	mes "[Armor Merchant]";
+	mes "Hello, this is Naphara's store, a place of high class goods.";
+	mes "What would you need?";
+	next;
+	set .@i, select("Str Glove:Int Glove:Agi Glove:Vit Glove:Dex Glove:Luk Glove");
+	mes "[Armor Merchant]";
+	switch(.@i) {
+	case 1: // Str Glove
+		mes "^3131FFStr Glove^000000";
+		mes "^3131FFMHP + 100, MSP + 20^000000";
+		mes "^3131FFATK+1 increases for every STR+10^000000";
+		mes "^3131FFATK +1% added above STR 110^000000";
+		set .@item,2917; //Str_Glove
+		break;
+	case 2:
+		mes "^3131FFInt Glove^000000";
+		mes "^3131FFMHP + 100, MSP + 20^000000";
+		mes "^3131FFMATK+1 increases for every INT+10^000000";
+		mes "^3131FFMATK +1% added above INT 110^000000";
+		set .@item,2918; //Int_Glove
+		break;
+	case 3:
+		mes "^3131FFAgi Glove^000000";
+		mes "^3131FFMHP + 100, MSP + 20^000000";
+		mes "^3131FFFLEE+1 increases for every AGI+10^000000";
+		mes "^3131FFComplete Flee +1 added above AGI 110^000000";
+		set .@item,2919; //Agi_Glove
+		break;
+	case 4:
+		mes "^3131FFVit Glove^000000";
+		mes "^3131FFMHP + 100, MSP + 20^000000";
+		mes "^3131FFMHP+50 for every VIT+10^000000";
+		mes "^3131FFMHP+1% added above VIT 110^000000";
+		set .@item,2920; //Vit_Glove
+		break;
+	case 5:
+		mes "^3131FFDex Glove^000000";
+		mes "^3131FFMHP + 100, MSP + 20^000000";
+		mes "^3131FFHIT+1 increases for every DEX+10^000000";
+		mes "^3131FFRanged attack power +1% added above DEX 110^000000";
+		set .@item,2921; //Dex_Glove
+		break;
+	case 6:
+		mes "^3131FFLuk Glove^000000";
+		mes "^3131FFMHP + 100, MSP + 20^000000";
+		mes "^3131FFCRI+1 increases for every LUK+10^000000";
+		mes "^3131FFCritical damage +1% added above LUK 110^000000";
+		set .@item,2922; //Luk_Glove
+		break;
+	}
+	mes "^3131FFRequired Level: 100^000000";
+	mes "^3131FFSlot: 0^000000";
+	mes "^3131FFWeight: 10^000000";
+	mes "are the characteristic options.";
+	next;
+	mes "[Armor Merchant]";
+	mes "It costs 10 Splendide Coins.";
+	mes "Would you like to buy it?";
+	next;
+	if(select("Buy it.:Don't buy it.") == 2)
+		close;
+	if (countitem(6081) < 10) {
+		mes "[Armor Merchant]";
+		mes "It seems like you don't have enough coins.";
+		close;
+	}
+	mes "[Armor Merchant]";
+	mes "Here you go!"; //custom
+	delitem 6081,10; //Splendide_Coin
+	getitem .@item,1;
+	close;
+}
+
+ecl_in01,64,97,4	script	Slot Expert Nattuer#ecl	436,{
+	mes "[Slot Expert]";
+	mes "I am Slot Expert Nattuer.";
+	mes "If you bring me an item from my little brother Naphara along with 5 Splendide Coins, I will open up one Slot for you.";
+	next;
+	if(select("Activate a Slot.:Forget it.") == 2)
+		close;
+	mes "[Slot Expert]";
+	mes "Slot activation is an extremely difficult procedure that can fail even with heightened care and the use of a magnifying lens.";
+	next;
+	mes "[Slot Expert]";
+	mes "Of course, if your heart were as big as that flower-filled land, you wouldn't mind. Right? Should I go for it?";
+	next;
+	if(select("Continue.:Forget it.") == 2)
+		close;
+	mes "[Slot Expert]";
+	mes "Which item would you like to activate with a Slot?";
+	next;
+	setarray .@noslots[0],2917,2918,2919,2920,2921,2922;
+	setarray .@slotted[0],2923,2924,2925,2926,2927,2928;
+	set .@i, select("Str Glove:Int Glove:Ag Glove:Vit Glove:Dex Glove:Luk Glove")-1;
+	set .@item, .@noslots[.@i];
+	set .@new_item, .@slotted[.@i];
+	mes "[Slot Expert]";
+	mes "Let's confirm for the last time. Is the one you want "+getitemname(.@item)+"?";
+	next;
+	if(select("Yes:No") == 2) {
+		mes "[Slot Expert]";
+		mes "Why don't you talk to me when you know for sure.";
+		close;
+	}
+	if (countitem(.@item) == 0) {
+		mes "[Slot Expert]";
+		mes "You don't have that item. Why don't you talk to me when you know for sure.";
+		close;
+	}
+	if (countitem(6081) < 5) {
+		mes "[Slot Expert]";
+		mes "You don't have enough coins. Why don't you talk to me when you know for sure."; //custom
+		close;
+	}
+	delitem 6081,5; //Splendide_Coin
+	delitem .@item,1;
+	//custom to the end
+	if (rand(100) < 5) {
+		mes "[Slot Expert]";
+		mes "Oh no, it failed! I'm sorry, but I warned you this could happen. Better luck next time.";
+		close;
+	}
+	mes "[Slot Expert]";
+	mes "Success! I've activated the slot.";
+	getitem .@new_item,1;
+	close;
+}
+
+ecl_in01,67,39,4	script	Replication Expert Palt	445,{
+	emotion e_lv;
+	mes "[Paltu]";
+	mes "Woohoo- Greetings. What are you looking for? Lots of goods here.";
+	next;
+	switch(select("No thanks.:Replication?:I know you got lots up your sleeve!")) {
+	case 1:
+		emotion e_an;
+		mes "[Paltu]";
+		mes "Really? Hmm?";
+		close;
+	case 2:
+		mes "[Paltu]";
+		mes "One can say that there's no one better in Eclage than I at utilizing magic resistance.";
+		next;
+		mes "[Paltu]";
+		mes "I'll give you a good price whatever it is. Just trust me.";
+		next;
+		select("Could you do something for me?");
+		emotion e_no1;
+		mes "[Paltu]";
+		mes "Hey, I like your attitude.";
+		next;
+		mes "[Paltu]";
+		mes "Ah- you know the hat you're wearing?";
+		next;
+		emotion e_what;
+		mes "[Paltu]";
+		mes "Don't you have any of those hats lying around in storage that are solid but too ugly to wear? You do, right?";
+		next;
+		select(".........");
+		emotion e_dots,1;
+		emotion e_heh;
+		mes "[Paltu]";
+		mes "See! I knew it. I knew it from the first minute.";
+		next;
+		mes "[Paltu]";
+		mes "If you bring me ^ff0000 50 Splendide Coins and the ingredients^000000, I'll make you a new hat in the same shape but worn as a ^ff0000Costume^000000.";
+		next;
+		mes "[Paltu]";
+		mes "Hmm, what was it...?";
+		mes "I think you adventurers call them ^0571B0Costumes^000000? right?";
+		next;
+		select("Yes~ What do you need?");
+		mes "[Paltu]";
+		mes "I need 1 ^0571B0hat to replicate^000000 and";
+		mes "I need ^E1281E 4 Crystal Mirrors^000000 for magic resistance, ^E1281E 1 Fairy Magic Powder^000000 as the catalyst, and ^E1281E Emerald, Ruby, Sapphire, Topaz, and Zircon, 10 of each^000000, to be used for amplifying the magic power.";
+		next;
+		emotion e_no;
+		mes "[Paltu]";
+		mes "There's quite a lot of ingredients, right? Well, I can't do anything about that. Dealing with magic power is not a joke.";
+		next;
+		select("Which hats can be replicated?");
+		mes "[Paltu]";
+		mes "Oh! You're pretty sharp!";
+		mes "Almost forgot the most important thing.";
+		next;
+		mes "[Paltu]";
+		mes "Hats that I can replicate are:";
+		mes "^0571B0Frog Hat, Romantic Flower, Magestic Goat, Blush, Valkyrie Helm, Deviruchi Hat, Assassin Mask, Elven Ears, Hahoe Mask, and Boys Cap^000000 a total of 10 types.";
+		next;
+		mes "[Paltu]";
+		mes "What do you think? I'll make it happen as long as I have the ingredients and the compensation.";
+		next;
+		if(select("I'll do it later.:Show me what you got!") == 1) {
+			emotion e_dots;
+			mes "[Paltu]";
+			mes "What? Are you kidding me? Please tell me you are!";
+			close;
+		}
+		break;
+	case 3:
+		break;
+	}
+	mes "[Paltu]";
+	mes "Oh wow.";
+	mes "You made the right call. I thought I was going to starve to death because the Laphines have no interest in pretty hats.";
+	next;
+	mes "[Paltu]";
+	mes "I'll make it a great deal for you. You really should know I'm giving you a good deal here.";
+	next;
+	mes "[Paltu]";
+	mes "Is there something you had in mind? Why don't you take a look?";
+	next;
+	setarray .@items[0],
+		5447, //Frog_Cap
+		2269, //Centimental_Flower
+		2256, //Magestic_Goat
+		5040, //Blush
+		5171, //Valkyrie_Helm
+		5038, //Deviruchi_Cap
+		5096, //Assassin_Mask_
+		2286, //Elven_Ears
+		5176, //Hahoe_Mask
+		5016; //Boy's_Cap
+	setarray .@costumes[0],
+		19548, //C_Frog_Cap
+		19552, //C_Centimental_Flower
+		19549, //C_Magestic_Goat
+		19550, //C_Blush
+		19546, //C_Valkyrie_Helm
+		19547, //C_Deviruchi_Cap
+		19553, //C_Assassin_Mask_
+		19551, //C_Elven_Ears
+		0,     //-- not implemented? --
+		19545; //C_Boys_Cap
+	if (countitem(6081) >= 50 && countitem(747) >= 4 && countitem(6395) >= 1 && countitem(721) >= 10 && countitem(723) >= 10 && countitem(726) >= 10 && countitem(728) >= 10 && countitem(729) >= 10)
+		set .@item_check,1;
+	for(set .@i,0; .@i<getarraysize(.@items); set .@i,.@i+1) {
+		if (.@item_check && countitem(.@items[.@i]))
+			set .@menu$, .@menu$+getitemname(.@items[.@i])+":"; //custom
+		else
+			set .@menu$, .@menu$+getitemname(.@items[.@i])+" (^777777Insufficient ingredients^000000):";
+	}
+	set .@i, select(.@menu$)-1;
+	set .@item, .@items[.@i];
+	set .@new_item, .@costumes[.@i];
+	mes "[Paltu]";
+	mes "Is ^0571B0"+getitemname(.@item)+"^000000 what you wanted?";
+	next;
+	if (.@item_check == 0 || countitem(.@item) == 0) {
+		emotion e_sob;
+		mes "[Paltu]";
+		mes "Ay... Credit purchases are difficult for me.";
+		next;
+		mes "[Paltu]";
+		mes "^0571B0"+getitemname(.@item)+"^000000 and";
+		mes "^E1281E50 Splendide Coins, 4 Crystal Mirrors, 1 Fairy Magic Powder, 10 of each Emerald, Ruby, Sapphire, Topaz, and Zircon^000000 are necessary.";
+		next;
+		mes "[Paltu]";
+		mes "I'm in a tight spot myself. Please consider my situation also.";
+		close;
+	}
+	//custom to the end
+	if(select("Continue.:Forget it.") == 2)
+		close;
+	delitem .@item,1;
+	delitem 6081,50; //Splendide_Coin
+	delitem 747,4; //Crystal_Mirror
+	delitem 6395,1; //Angel_Magic_Power
+	delitem 721,10; //Azure_Jewel
+	delitem 723,10; //Cardinal_Jewel
+	delitem 726,10; //Blue_Jewel
+	delitem 728,10; //Golden_Jewel
+	delitem 729,10; //Bluish_Green_Jewel
+	getitem .@new_item,1;
+	mes "[Paltu]";
+	mes "Thank you so much! As promised, here is your costume.";
+	close;
+}
+
+ecl_in01,33,98,4	script	Herb Merchant Plafina#e	443,{
+	mes "[Herb Merchant]";
+	mes "Welcome, this is Plafina's Herb Store where only the freshest herbs are provided~!";
+	next;
+	switch(select("Snow Flip:Peony Mommy:Slapping Herb:Yggdrasil Dust:End conversation")) {
+	case 1:
+		mes "[Herb Merchant]";
+		mes "Snow Flip has special effects on ^3131FFBurning, Bleeding, Deep Sleep, Sleep^000000.";
+		set .@item,12812; //Snow_Flip
+		set .@cost,5;
+		break;
+	case 2:
+		mes "[Herb Merchant]";
+		mes "Peony Mamy has special effects on ^3131FFFrost, Frozen, Freezing^000000.";
+		set .@item,12813; //Peony_Mommy
+		set .@cost,5;
+		break;
+	case 3:
+		mes "[Herb Merchant]";
+		mes "Slapping Herb has special effects on ^3131FFStun, Fear, Chaos, Hallucination^000000.";
+		set .@item,12814; //Slapping_Herb
+		set .@cost,1;
+		break;
+	case 4:
+		mes "[Herb Merchant]";
+		mes "Yggdrasil Dust has special effects on ^3131FFBlind, Curse, Decrease Agility, Reverse Orcish^000000.";
+		set .@item,12815; //Yggdrasil_Dust
+		set .@cost,1;
+		break;
+	case 5:
+		mes "[Herb Merchant]";
+		mes "Come back anytime.";
+		close;
+	}
+	mes "Requires 5 seconds between uses.";
+	mes "It costs "+.@cost+" Splendide Coin"+((.@cost == 1)?"":"s")+" for each.";
+	next;
+	switch(select("Buy 1.:Buy 10.:Don't buy.")) {
+	case 1:
+		set .@amount,1;
+		break;
+	case 2:
+		set .@amount,10;
+		break;
+	case 3:
+		close;
+	}
+	set .@price,.@amount*.@cost;
+	mes "[Herb Merchant]";
+	mes "Would you like to buy "+.@amount+" "+getitemname(.@item)+"?";
+	next;
+	if(select("Buy.:Don't buy.") == 2)
+		close;
+	if (countitem(6081) < .@price) {
+		mes "[Herb Merchant]";
+		mes "You don't have enough coins.";
+		close;
+	}
+	mes "[Herb Merchant]";
+	mes "Here are your herbs."; //custom
+	delitem 6081,.@price; //Splendide_Coin
+	getitem .@item,.@amount;
+	end;
+}