restored custom events directory (deleted in r12177), moved it to where it was supposed to be moved

git-svn-id: https://rathena.svn.sourceforge.net/svnroot/rathena/trunk@12185 54d463be-8e91-2dee-dedb-b68131a5f0ec

10 files changed, 1337 insertions, 0 deletions

diff --git a/npc/custom/events/2006_dogs_year.txt b/npc/custom/events/2006_dogs_year.txt
new file mode 100644
index 000000000..1be5be4ff
--- /dev/null
+++ b/npc/custom/events/2006_dogs_year.txt
@@ -0,0 +1,98 @@
+//===== eAthena Script =======================================
+//= Eastern New Year 2006 The Year Of The Fire Dog
+//===== By: ==================================================
+//= Lupus (1.0)
+//===== Current Version: =====================================
+//= 1.1
+//===== Compatible With: =====================================
+//= eAthena Version; 5xxx+ (with 'disguise' command)
+//===== Description: =========================================
+//= Custom event: For 28-29 January
+//===== Additional Comments: =================================
+//= 1.0 Tested, fully working.[Lupus]
+//=		Add some national info in English if you can.
+//=	(Mine was in Russian, and it's damn hard to translate 8)
+//= 1.1 Commented out monster spawn as it is a custom mob and [L0ne_W0lf]
+//	not in the mob database.
+//============================================================
+
+
+prontera,149,167,6	script	Maria	81,{
+	mes "[Maria]";
+	//month
+	if((gettime(6)==1 && (gettime(5)==28 || gettime(5)==29))==0) {
+		mes "Happy New Year Of The Fire Dog! Woof!";
+		close;
+	}
+
+	mes "Happy New Year of The Fire Dog!";
+	if(rand(2))mes "By the way, 'Dogs' fit the most to the ones, born in years of Horse, Tiger and Rabbit.";
+	next;
+	menu "Tell me about Japanese traditions",-,
+		"Tell me about Chinese New Year",M_NGCH,
+		"Tell me about Korean New Year",M_NGCO,
+		"I need a doggy costume!",M_PRIZE,
+		"Happy New Year to you.",LEnd;
+
+	mes "[Maria]";
+	mes "Japan...";
+	mes "Put here some notes in English about their HNY.";
+	next;
+	mes "[Maria]";
+	mes "Put here some notes in English about their HNY.";
+	close;
+
+M_NGCH:
+	mes "[Maria]";
+	mes "China...";
+	mes "Put here some notes in English about their HNY.";
+	next;
+	mes "[Maria]";
+	mes "Put here some notes in English about their HNY.";
+	close;
+
+M_NGCO:
+	mes "[Maria]";
+	mes "Korea...";
+	mes "Put here some notes in English about their HNY.";
+	next;
+	mes "[Maria]";
+	mes "Put here some notes in English about their HNY.";
+	close;
+
+M_PRIZE:
+	mes "[Maria]";
+	if(countitem(12132)>9) {
+		mes "You should use all of your old costumes first!";
+		close;
+	}
+	mes "Some buddhistic books tell us legends about humans to dogs reincarnation... Buy ^FF0000this magic doggie costume^000000 for just ^0000FF999 Zeny^000000!";
+	mes "And prove old legends yourself!";
+	next;
+	menu "I'll buy one.",-,"No, thank you.",LEnd;
+	
+		mes "[Maria]";
+		if(Zeny<999) goto NoZ;
+		set Zeny,Zeny-999;
+		getitem 12132,1;
+		mes "Here you go. Its form will show true power of your spirit.";
+		emotion 15;
+		close;
+		NoZ:
+			mes "Oh dear, you lack of zeny. I have 7 puppies to feed, you know...";
+			emotion 17;
+			close;
+	LEnd:
+		mes "[Maria]";
+		mes "Happy New Year of the Fire Me!!! Woof-woof!";
+		emotion rand(19,20);
+		close;
+
+OnInit:
+	//Magic Doggie Costum
+	setitemscript 12132,"{ misceffect 215; if(BaseLevel>97){disguise 1022;end;}if(BaseLevel>90){disguise 1296;end;}if(BaseLevel>80){disguise 1106;end;}if(BaseLevel>50){disguise 1013;end;}if(BaseLevel>40){disguise 1135;end;}disguise 1107;}";
+	end;
+}
+
+// Requires custom monster.
+//prontera,0,0,0,0	monster	Fire Dog	1987,50,3600000,1800000,0
diff --git a/npc/custom/events/draculax.txt b/npc/custom/events/draculax.txt
new file mode 100644
index 000000000..5e03ddb1e
--- /dev/null
+++ b/npc/custom/events/draculax.txt
@@ -0,0 +1,130 @@
+//===== eAthena Script =======================================
+//= Dracula X Script
+//===== By: ==================================================
+//= valaris (1.0)
+//===== Current Version: =====================================
+//= 1.0a
+//===== Compatible With: =====================================
+//= eAthena RC4+
+//===== Description: =========================================
+//= Custom Dracula X Event
+//============================================================
+
+
+mag_dun02,72,182,1	script	Dracula's Coffin::Dracula_Init	-1,{
+
+OnInit:
+	set $dracula_event,0;
+	end;
+
+OnKilled:
+	MapAnnounce "mag_dun02","Dracula's curse has been lifted!",17;
+	set $dracula_event,0;
+	initnpctimer;
+	end;
+
+OnTimer7200000:
+	if($dracula_event==0) 
+	stopnpctimer;
+	enablenpc "Dracula_Event";
+	end;
+}
+
+mag_dun02,72,182,1	script	Dracula's Coffin::Dracula_Event	801,{
+
+	if($dracula_event==1)
+	close;
+
+	set $dracula_event,1;
+	MapAnnounce "mag_dun02","Count Dracula : Who has awakened me from my slumber?",17;
+	npcskilleffect 21,10,66,175;
+	initnpctimer;
+	end;
+
+OnTimer500:
+	npcskilleffect 21,10,74,187;
+	end;
+
+OnTimer1000:
+	npcskilleffect 21,10,80,180;
+	end;
+	
+OnTimer1500:
+	npcskilleffect 21,10,79,183;
+	end;
+
+OnTimer2000:
+	npcskilleffect 21,10,66,175;
+	end;
+
+OnTimer2500:
+	npcskilleffect 21,10,63,186;
+	end;
+
+OnTimer3000:
+	npcskilleffect 21,10,75,186;
+	end;
+
+OnTimer3500:
+	npcskilleffect 21,10,75,173;
+	end;
+
+OnTimer4000:
+	npcskilleffect 21,10,80,170;
+	end;
+
+OnTimer4500:
+	npcskilleffect 21,10,60,179;
+	end;
+
+OnTimer5000:
+	npcskilleffect 21,10,74,187;
+	end;
+
+OnTimer6000:
+	npcskilleffect 21,10,69,182;
+	end;
+
+OnTimer6500:
+	npcskilleffect 21,10,80,180;
+	end;
+
+OnTimer7000:
+	npcskilleffect 21,10,60,179;
+	end;
+
+OnTimer7500:
+	npcskilleffect 21,10,66,175;
+	end;
+
+OnTimer8000:
+	npcskilleffect 21,10,80,187;
+	end;
+
+OnTimer8500:
+	npcskilleffect 21,10,75,186;
+	end;
+
+OnTimer9000:
+	npcskilleffect 21,10,75,173;
+	end;
+
+OnTimer9500:
+	npcskilleffect 21,10,80,170;
+	end;
+
+OnTimer10000:
+	npcskilleffect 21,10,63,186;
+	end;
+
+OnTimer10500:
+	npcskilleffect 21,10,74,187;
+	end;
+
+OnTimer11000:
+	npcskilleffect 21,10,72,182;
+	monster "mag_dun02",72,182,"Count Dracula",1389,1,"Dracula_Init::OnKilled";
+	stopnpctimer;
+	disablenpc "Dracula_Event";
+	end;
+}
diff --git a/npc/custom/events/hallow06.txt b/npc/custom/events/hallow06.txt
new file mode 100644
index 000000000..31085d169
--- /dev/null
+++ b/npc/custom/events/hallow06.txt
@@ -0,0 +1,125 @@
+//===== eAthena Script =======================================
+//= Custom Halloween Event 2006
+//===== By: ==================================================
+//= Stryker
+//===== Current Version: =====================================
+//= 1.2
+//===== Compatible With: =====================================
+//= Latest Svn
+//===== Description: =========================================
+//= Halloween Event Script
+//===== Additional Comments: =================================
+//= Version 1.1 - Added trick to script
+//= 1.2 fixed bugs, optimized. Now uses 1 var instead of 3 [Lupus]
+//============================================================
+
+
+prontera,151,190,5	script	Hallows' Eve Event	807,{
+	mes "[Hallows' Eve Event]";
+	if(Class == Job_Novice){
+		mes "I am sorry but you have to got a job to complete the event.";
+		emotion e_swt,1;
+		close;
+	}
+	if(EVENT_HALWN06&1 && EVENT_HALWN06&2){
+		mes "I am sorry but you have already completed the event.";
+		emotion e_sry;
+		close;
+	}
+	mes "Greetings fellow lively human.";
+	next;
+	mes "[Hallows' Eve Event]";
+	mes "Halloween is upon us and it is almost time to adventure out into places few dare go.";
+	next;
+	mes "[Hallows' Eve Event]";
+	mes "Trick or treat, which do you prefer?";
+	next;
+	menu "Trick",-, "Treat",L_Treat;
+
+	mes "[Hallows' Eve Event]";
+	if(EVENT_HALWN06&2){
+		mes "I'm sorry but you have already had a trick. Why don't you go pick a treat now.";
+		emotion e_sry;
+		close;
+	}
+	mes "Give me a min...";
+	next;
+	set BaseExp,BaseExp+BaseLevel*1000;
+	set EVENT_HALWN06,EVENT_HALWN06|2;
+
+	mes "[Hallows' Eve Event]";
+	mes "Here is your treat. Your Base EXP has been slightly increased.";
+	next;
+	mes "[Hallows' Eve Event]";
+	mes "I hope you enjoy your trick and Happy Halloween!";
+	close;
+
+L_Treat:
+	mes "[Hallows' Eve Event]";
+	if(EVENT_HALWN06&1){
+		mes "I'm sorry but you have already had a treat. Why don't you go pick a trick now.";
+		emotion e_sry;
+		close;
+	}
+	if(!(EVENT_HALWN06&4)){
+		mes "Great! This shall be so much fun.";
+		next;
+		mes "[Hallows' Eve Event]";
+		mes "I will be sending you on a scavenger hunt for items.";
+		next;
+		mes "[Hallows' Eve Event]";
+		mes "Bring back all the necessary items, and I will create you a treat.";
+		next;
+		mes "[Hallows' Eve Event]";
+		mes "Not just any normal treat either that you can eat, but it is something you can wear on your head.";
+		next;
+		mes "[Hallows' Eve Event]";
+		mes "But with all things made, some items are required first.";
+		mes "The list:";
+		mes "1 Hat,";
+		mes "30 Pumpkin, and";
+		mes "20 Black Piece of Cloth";
+		next;
+		mes "[Hallows' Eve Event]";
+		mes "Hurry along now.";
+		set EVENT_HALWN06,EVENT_HALWN06|4;
+		close;
+	}
+	mes "Did you get the items I requested or do you need to see the list again?";
+	next;
+	menu "Got'em",-, "Don't Have",L_Dont_Have, "See List",L_List;
+
+	mes "[Hallows' Eve Event]";
+	if((countitem(2220) < 1) || (countitem(535) < 30) || (countitem(7205) < 20)){
+		mes "You don't have enough items. Come back when you do.";
+		emotion e_sry;
+		close;
+	}
+	delitem 2220,1;
+	delitem 535,30;
+	delitem 7205,20;
+	getitem 5134,1;
+	set EVENT_HALWN06,EVENT_HALWN06|1;
+	mes "Good job! I hope you are happy with your item.";
+	emotion e_grat;
+	next;
+	mes "[Hallows' Eve Event]";
+	mes "Enjoy the rest of your halloween.";
+	emotion e_scissors,1;
+	close;
+
+L_Dont_Have:
+	mes "[Hallows' Eve Event]";
+	mes "Go back out and search for them. Would you like to view the list?";
+	next;
+	menu "No",-, "Yes",L_List;
+	close;
+
+L_List:
+	mes "[Hallows' Eve Event]";
+	mes "I require the following items:";
+	mes "1 Hat,";
+	mes "30 Pumpkin, and";
+	mes "20 Black Piece of Cloth.";
+	close;
+}
diff --git a/npc/custom/events/hyegun_event.txt b/npc/custom/events/hyegun_event.txt
new file mode 100644
index 000000000..e4837eb20
--- /dev/null
+++ b/npc/custom/events/hyegun_event.txt
@@ -0,0 +1,77 @@
+//===== eAthena Script =======================================
+//= HyeGun Event
+//===== By: ==================================================
+//= Synesthesia
+//===== Current Version: =====================================
+//= 1.0
+//===== Compatible With: =====================================
+//= Any Athena Version I think
+//===== Description: =========================================
+//= Event similar to iRO's Christmas event when searching for Antonios.
+//===== Additional Comments: =================================
+//= Drink Jakada!
+//============================================================
+
+//HyeGun Mob spawning
+anthell01,0,0,0,0	monster	Hyegun	1512,3,180000,30000,0
+mag_dun01,0,0,0,0	monster	Hyegun	1512,3,180000,30000,0
+alde_dun01,0,0,0,0	monster	Hyegun	1512,3,180000,30000,0
+in_sphinx1,0,0,0,0	monster	Hyegun	1512,3,180000,30000,0
+
+//Munak Quest
+pay_dun01,53,269,6	script	Munak	1026,{
+if(event_hyegun==3) goto Lfinished;
+mes "[^FF0000Munak^000000]";
+mes "Hello, kinda strange talking to a Munak huh?";
+mes "I'm a friendly Munak that wants to tell you something.";
+menu "Listen to her story",Lok,"Leave",Lno;
+
+	Lok:
+	mes "[^FF0000Munak^000000]";
+	mes "Well see our father ^666600HyeGun^000000 has been terrible to us Munaks.";
+	mes "We would like you to get revenge for what he has done to us.";
+	next;
+	mes "When you find him, kill him.";
+	mes "He will drop an item that you will have to bring to me to prove his death.";
+	mes "Bring me ^FF00003 ^008800Yggdrasil Dew^000000 and I'll give you a reward.";
+	mes "Remember, you may only do this quest ^FF00003 times.";
+	menu "Info about HyeGun",Lhyeinfo,"Give her the items",Litem,"Leave",Lno;
+
+	Lhyeinfo:
+	mes "[^FF0000Munak^000000]";
+	mes "- HyeGun looks like us but he's a tanish color type with long hair.";
+	mes "- He's been last seen in the first level of the 4 most popular dungeons.";
+	mes "He doesn't hang out here because there's so many of us.";
+	mes "Anything else?";
+	menu "Info about HyeGun",Lhyeinfo,"Give her the items",Litem,"Leave",Lno;
+
+	Litem:
+	mes "[^FF0000Munak^000000]";
+	mes "Ahh so you've completed the task so soon?";
+	mes "Good job";
+	mes "Let's see if you've got the right stuff.";
+	next;
+	if (countitem(7141) < 3)goto Lnoitem;
+	mes "Good job, here's your reward.";
+	next;
+	delitem 7141,3;
+	getitem 617,1;
+	set event_hyegun,event_hyegun+1;
+	close;
+
+	Lfinished:
+	mes "[^FF0000Munak^000000]";
+	mes "I'm sorry, you've already completed my task 3 times.";
+	close;
+
+	Lno:
+	mes "[^FF0000Munak^000000]";
+	mes "Okay then, when you feel brave enough, come on back.";
+	close;
+
+	Lnoitem:
+	mes "[^FF0000Munak^000000]";
+	mes "Hey, you don't have the Yggdrasil Dew.";
+	mes "Come back when you've gotten 3 of them.";
+	close;
+}
diff --git a/npc/custom/events/kings_items.txt b/npc/custom/events/kings_items.txt
new file mode 100644
index 000000000..4602877b4
--- /dev/null
+++ b/npc/custom/events/kings_items.txt
@@ -0,0 +1,178 @@
+//===== eAthena Script ======================================= 
+//= Event King Items
+//===== By: ================================================== 
+//= $ephiroth
+//===== Current Version: ===================================== 
+//= 1.0
+//===== Compatible With: ===================================== 
+//= eAthena Version
+//===== Description: ========================================= 
+//= Grand Circlet Quest combined with Excalibur Quest.
+//= Converted to eAthena format from Fusion.
+//= 2006/09/27: 1.0 Release and fully working. [$ephiroth]
+//============================================================
+
+prt_castle,80,170,4	script	King of Prontera	108,{
+	set @npcname$,"[King of Prontera]";
+
+	mes @npcname$;
+	mes "Hello can you help me?";
+	next;
+	menu "Sure, what can I do?",L_Sure,"No sorry I'm busy",L_Quit;
+
+L_Sure:
+	mes @npcname$;
+	mes "Thank you.";
+	mes "Well, my daughter next to me is a little rowdy";
+	mes "if you got her these items I'm sure she would calm down.";
+	mes "If you bring me these items I'll give you my crown or my sword";
+	mes "Both are very special.";
+	next;
+	menu "Ok what do you need?",L_Req,"I have the items",L_Have,"Forget it",L_Quit;
+
+L_Req:
+	mes @npcname$;
+	mes "If you could get me:";
+	mes "^00B6FF30 Chonchon doll^000000";
+	mes "^D5A50050 Poring doll^000000";
+	mes "^0080FF20 Yoyo doll^000000";
+	mes "^CC66331 3carat diamond^000000";
+	mes "^3131FF20 Illusion Flowers^000000";
+	mes "^AA00AA20 Singing Flowers^000000";
+	mes "I'll give you my crown.";
+	next;
+	mes @npcname$;
+	mes "If you could get me:";
+	mes "^0000881 Angel Band^000000";
+	mes "^4422FF1 Heaven Ring^000000";
+	mes "^AA00AA1 Emperium^000000";
+	mes "I'll give my sword.";
+	mes "Once you find those, come back to me.";
+	close;
+
+L_Have:
+	mes @npcname$;
+	mes "What item you want?";
+	next;
+	menu "Crown",L_crown,"Sword",L_sword;
+
+L_crown:
+	if(countitem(742)<30) goto L_Error; 
+	if(countitem(741)<50) goto L_Error1;
+	if(countitem(753)<20) goto L_Error2;
+	if(countitem(732)<1) goto L_Error3;
+	if(countitem(710)<20) goto L_Error4;
+	if(countitem(629)<20) goto L_Error5;
+	delitem 742,30;
+	delitem 741,50;
+	delitem 753,20;
+	delitem 732,1;
+	delitem 710,20;
+	delitem 629,20;
+	mes @npcname$;
+	mes "THANK YOU SOO MUCH!!";
+	mes "This will surely calm her down.";
+	mes "Let me just take the items from you.";
+	next;
+	mes @npcname$;
+	mes "As I promised here is my crown.";
+	getitem 5007,1;
+	next;
+	mes @npcname$;
+	mes "Well, I have to calm her down now.";
+	mes "Thanks again!";
+	close;
+L_sword:
+	if(countitem(2254)<1) goto L_NoAngel;
+	if(countitem(2282)<1) goto L_NoHeaven;
+	if(countitem(714)<1) goto L_NoEmp;
+	delitem 2254,1;
+	delitem 2282,1;
+	delitem 714,1;
+	mes @npcname$;
+	mes "THANK YOU SOO MUCH!!";
+	mes "This will surely calm her down.";
+	mes "Let me just take the items from you.";
+	next;
+	mes @npcname$;
+	mes "As I promised here is my sword.";
+	getitem 1137,1;
+	next;
+	mes @npcname$;
+	mes "Well, I have to calm her down now.";
+	mes "Thanks again!";
+	close;
+
+L_NoAngel:
+	mes @npcname$;
+	mes "Sorry but you must have at least one Angel Band.";
+	mes "Come back after you get ALL the items.";
+	close;
+
+L_NoHeaven:
+	mes @npcname$;
+	mes "Sorry but you must have at least one Heaven Ring.";
+	mes "Come back after you get ALL the items.";
+	close;
+
+L_NoEmp:
+	mes @npcname$;
+	mes "Sorry but you must have at least one Emperium.";
+	mes "Come back after you get ALL the items.";
+	close;
+
+L_Error:
+	mes @npcname$;
+	mes "Oh darn, you need 30 Chonchon Dolls.";
+	close;
+
+L_Error1:
+	mes @npcname$;
+	mes "Oh darn, you need 50 Poring dolls.";
+	close;
+
+L_Error2:
+	mes @npcname$;
+	mes "Oh darn, you need 20 Yoyo dolls.";
+	close;
+
+L_Error3:
+	mes @npcname$;
+	mes "Oh darn, you need one 3 Carat Diamond.";
+	close;
+
+L_Error4:
+	mes @npcname$;
+	mes "Oh darn, you need 20 Illusion Flowers.";
+	close;
+
+L_Error5:
+	mes @npcname$;
+	mes "Oh darn, you need 20 Singing Flowers.";
+	close;
+
+L_Quit:
+	mes @npcname$;
+	mes "Ok, that's fine, I'm sure someone else will help.";
+	close;
+}
+
+prt_castle,84,170,4	script	King's Daughter	62,{
+	set @npcname$,"[King's Daughter]";
+
+	mes @npcname$;
+	mes "Hmph, I hate my dad right now!!";
+	next;
+	menu "Why?",L_Why,"Ok...Whatever..",L_Quit;
+
+L_Why:
+	mes @npcname$;
+	mes "Well, he won't give me what I want!!";
+	mes "He's the King of Prontera, he should be able to get me ANYTHING!!!";
+	close;
+
+L_Quit:
+	mes @npcname$;
+	mes "FINE THEN Hmph!!";
+	close;
+}
diff --git a/npc/custom/events/p_track/p_track_core.txt b/npc/custom/events/p_track/p_track_core.txt
new file mode 100644
index 000000000..77b679b26
--- /dev/null
+++ b/npc/custom/events/p_track/p_track_core.txt
@@ -0,0 +1,43 @@
+//===== eAthena Script =======================================
+//= Poring Track Main NPCs
+//===== By: ==================================================
+//= erKURITA
+//===== Current Version: =====================================
+//= 0.0000000000000002
+//===== Compatible With: =====================================
+//= eAthena 1.0
+//===== Description: =========================================
+//= NPCs that has nothing to do with the race itself, but
+//= has important functions on the race itself.
+//===== Additional Comments: =================================
+//= 0.0000000000000002 Removed Duplicates [Silent]
+//============================================================
+p_track01,41,57,5	script	Lady#track1::P_track	845,{
+end;
+}
+
+p_track01,67,34,6	script	Erudite::P_Spectator1		107,{
+end;
+}
+
+p_track01,44,49,3	script	Edward	881,{
+end;
+}
+
+p_track01,27,47,3	script	Yuri#P_track	853,{
+end;
+}
+
+p_track02,30,45,3	script	Nagya	755,{
+end;
+}
+
+p_track02,42,49,3	script	Asgahrd	733,{
+end;
+}
+
+p_track02,67,33,1	script	Blacksmith#track1	726,{
+end;
+}
+
+p_track02,41,57,5	duplicate(P_track)	Lady#track2	845
diff --git a/npc/custom/events/p_track/p_track_warpers.txt b/npc/custom/events/p_track/p_track_warpers.txt
new file mode 100644
index 000000000..730dd2b0f
--- /dev/null
+++ b/npc/custom/events/p_track/p_track_warpers.txt
@@ -0,0 +1,73 @@
+//===== eAthena Script =======================================
+//= Poring Track Warpers
+//===== By: ==================================================
+//= erKURITA
+//===== Current Version: =====================================
+//= 0.0000000000000002
+//===== Compatible With: =====================================
+//= eAthena 1.0
+//===== Description: =========================================
+//= NPC's for the City of Hugel.
+//===== Additional Comments: =================================
+//= 0.0000000000000002 Removed Duplicates [Silent]
+//============================================================
+//| Warp-in npcs
+hugel,58,72,5	script	Yan#track1	86,{
+//callfunc "P_TrackEnt",npcname,map name;
+callfunc "P_TrackEnt","[Yan]","p_track01";
+end;
+}
+hugel,62,68,1	script	Yalmire#track1	86,{
+//callfunc "P_TrackEnt",npcname,map name;
+callfunc "P_TrackEnt","[Yalmire]","p_track02";
+end;
+}
+
+//| Warp-out npcs
+
+p_track01,76,36,2	script	Yan#track2	86,{
+end;
+}
+
+p_track02,76,36,2	script	Yalmire#track2	86,{
+end;
+}
+
+function	script	P_TrackEnt	{
+
+mes getarg(0);
+mes "Hi "+strcharinfo(0)+", Welcome to the Poring Track!";
+menu "Information",-,"I want to try it",L_Try,"Not today thanks",L_End;
+		next;
+		mes getarg(0);
+		mes "Bla blah, so fun";
+		close;
+	L_Try:
+		next;
+		mes getarg(0);
+		mes "Ok, the entrance fee is 500z, would you like to go in?";
+		menu "Yes Please",-,"No Thanks",L_End2;
+				if (Zeny < 500) {
+					next;
+					mes getarg(0);
+					mes "Sorry but you ain't got 500z, you can't enter";
+					close;
+				} else
+				next;
+				mes getarg(0);
+				mes "Here we go!";
+				close2;
+				set Zeny,Zeny-500;
+				warp getarg(1),75,41;
+				end;
+			L_End2:
+				next;
+				mes getarg(0);
+				mes "Oh well, you miss it";
+				close;
+	L_End:
+		next;
+		mes getarg(0);
+		mes "Ok, see you later!";
+		close;
+}
diff --git a/npc/custom/events/uneasy_cemetery.txt b/npc/custom/events/uneasy_cemetery.txt
new file mode 100644
index 000000000..06fe4a8f8
--- /dev/null
+++ b/npc/custom/events/uneasy_cemetery.txt
@@ -0,0 +1,134 @@
+//===== eAthena Script ======================================= 
+//= Uneasy Prontera Cemetery Quest (original script!)
+//===== By: ================================================== 
+//= Lupus
+//===== Current Version: ===================================== 
+//= 1.2a (Tested and fully working!)
+//===== Compatible With: ===================================== 
+//= eAthena Version 1.0
+//===== Description: ========================================= 
+//= A periodical quest of the Uneasy Cemetery (Kill undead / Prevent their appearance)
+//= Every day, at the midnight Prontera receive a wave of Undeads.
+//= They come from Uneasy Cemetery of Prontera. To protect the players
+//= from the undeads terror you may either kill the enemy. Or supply Mother Mathana
+//= with needed amount of Holy Water. Every citizen can take his part in the 
+//= saving of Prontera city. After some days of quiet life... the Cemetery strikes back.
+//===== Additional Comments: ================================= 
+//= 1.1 More advanced ver. Added some bonus the the one who'd kill the last walking undead
+//= 1.2 Added coords to the script to make label OmMobDead working
+//= 1.2a Changed item names to item IDs. [Samuray22]
+//============================================================ 
+
+
+prontera,3,3,3	script	Uneasy_Check	-1,{
+	end;
+
+OnHour00:
+	set $UNEASY_DL,$UNEASY_DL-1;
+	set $UNEASY_BL,$UNEASY_BL+30; //add need of HW for 30 bottles per day
+	if ($UNEASY_BL>666) set $UNEASY_BL,666; //keep needed bottles not <=666
+	if ($UNEASY_DL < 0) goto L_Start_Undead;
+//The Cemetery is OK yet.
+	disablenpc "Mother Mathana";
+	end;
+OnInit:
+	if ($UNEASY_DL >= 0) disablenpc "Mother Mathana";
+	end;
+
+OnHour06:
+	killmonsterall "prontera";	//The Sun kills undead in the morning
+	end;
+
+OnHour01:
+	if ($@UNEASY_MOB > 0) mapannounce "prontera","[Mother Mathana]: In the name of Odin, please finish these roaming undead leftovers!",0;
+	end;
+
+OnZombieDead:
+	set $@UNEASY_MOB,$@UNEASY_MOB-1;
+	if ($@UNEASY_MOB>0) end;
+	set $UNEASY_DL,0;
+	set $UNEASY_H$,strcharinfo(0);
+	if (Sex==1) mapannounce "prontera","[Mother Mathana]: Brave "+$UNEASY_H$+" has just killed the last undead in Prontera!",0;
+	if (Sex==0) mapannounce "prontera","[Mother Mathana]: Lady "+$UNEASY_H$+" has just killed the last undead in Prontera!",0;
+	set JobExp,JobExp+100;
+	set BaseExp,BaseExp+50;
+	end;
+
+L_Start_Undead:
+	killmonsterall "prontera";	//kills any left monsters
+	enablenpc "Mother Mathana";
+//call some monsters in the city
+	set $@UNEASY_MOB, 65;
+	areamonster "prontera",0,0,0,0,"Zombie",1015,30,"Uneasy_Check::OnZombieDead";
+//in the Cemetery
+	monster "prontera",268,349,"Zombie",1015,30,"Uneasy_Check::OnZombieDead";
+	monster "prontera",269,350,"Ghoul",1036,5,"Uneasy_Check::OnZombieDead";
+//announce
+	mapannounce "prontera","[Mother Mathana]: The cememtery has become restless!  In the name of Odin, hurry to the Sanctuary! Save the city of Prontera!",0;
+}
+
+prontera,257,313,5	script	Mother Mathana	79,{
+	mes "[Mother Mathana]";
+	if ($UNEASY_DL <= 0) goto L_Undead_Walk;
+	mes "I'm afraid there's something wrong with our old cemetery...";
+	if ($UNEASY_H$==strcharinfo(0)) mes "But thanks to you, "+$UNEASY_H$+", we'll be able to sleep " + $UNEASY_DL + " nights!";
+	if ($UNEASY_H$!=strcharinfo(0)) mes "But thanks to "+$UNEASY_H$+"'s support, we've got " + $UNEASY_DL + " easy nights!";
+	emotion 0;
+	close;
+
+L_Undead_Walk:
+	if ($UNEASY_DL == 0) mes "THEY could return tomorrow's night again!";
+	if ($UNEASY_DL == 0 && $UNEASY_H$==strcharinfo(0)) mes "Thank you, "+$UNEASY_H$+"! Now we'll manage to rest till the next midnight!";
+	if ($UNEASY_DL == 0 && $UNEASY_H$!=strcharinfo(0)) mes "But due to "+$UNEASY_H$+"'s help we'll manage to rest till the next midnight!";
+	mes "To calm down the restless cemetery, we should pour all these graves with the Holy Water. But our sisters and broters have run out of it.";
+	mes "Could you supply us with Holy Water?";
+	next;
+	menu "Yes, have all my Holy Water!",-, "Nope, I need it.",M_NO, "I don't have any.",M_DONT_HAVE;
+
+	if ( countitem(523)<1 ) goto M_DONT_HAVE;
+	set $UNEASY_BL,$UNEASY_BL-countitem(523);
+	delitem 523,countitem(523);
+
+	if ( $UNEASY_BL > 0 ) goto L_NEED_MORE;
+//set quiet days!!! no more undead for this period!
+	set $UNEASY_DL,5+((0-$UNEASY_BL)/30);
+	set $UNEASY_H$,strcharinfo(0);
+	mes "[Mother Mathana]";
+	mes "Thank you, "+$UNEASY_H$+"! Now we've got enough Holy Water!";
+	next;
+	mes "[Mother Mathana]";
+	mes "Upon pouring the cemetery with that water we'll get " + $UNEASY_DL + " safe nights!";
+	next;
+	killmonsterall "prontera";	//kills any left monsters
+	mes "[Mother Mathana]";
+	mes "See, "+ $UNEASY_H$ +"? They all are gone now!";
+	next;
+	mes "[Mother Mathana]";
+	mes "Our Church is going to thank you personally...";
+	next;
+	if (Sex==1) mapannounce "prontera","[Mother Mathana]: In the name of Odin we declare handsom "+$UNEASY_H$+" as a Prontera savior!",0;
+	if (Sex==0) mapannounce "prontera","[Mother Mathana]: In the name of Odin we declare beautiful "+$UNEASY_H$+" as a Prontera savior!",0;
+	mes "[Mother Mathana]";
+	mes "In the name of Odin we bless you and decently present a modest gift just from Mareusis' wine-cellar.";
+	getitem 505,1; //Blue_Potion
+	set JobExp,JobExp+100;
+	set BaseExp,BaseExp+50;
+	close;
+
+L_NEED_MORE:
+	mes "[Mother Mathana]";
+	mes "Thank you, good "+strcharinfo(0)+", but we still need " + $UNEASY_BL + " more Holy Water bottles.";
+	close;
+
+M_NO:
+	mes "[Mother Mathana]";
+	mes "I'm afraid the old cemetery is going out of control soon... Please, get us all the Holy Water you can get.";
+	close;
+
+M_DONT_HAVE:
+	mes "[Mother Mathana]";
+	mes "Alas! We still need " + $UNEASY_BL + " more bottles of Holy Water...  Why don't you go and ask other people for some extra Holy Water?";
+	mes "The old cemetery is going out of control soon...";
+	mes "Please, in the name of Odin, help Prontera city.";
+	close;
+}
diff --git a/npc/custom/events/valentinesdayexp.txt b/npc/custom/events/valentinesdayexp.txt
new file mode 100644
index 000000000..6d2b3355e
--- /dev/null
+++ b/npc/custom/events/valentinesdayexp.txt
@@ -0,0 +1,286 @@
+//===== eAthena Script =======================================
+//= Valentine Event Script + EXP bonus
+//===== By: ==================================================
+//= Lupus (based on Muad_Dib's work)
+//===== Current Version: =====================================
+//= 1.1
+//===== Compatible With: =====================================
+//= Any Athena Version 45xx+
+//===== Description: =========================================
+// Close to other official stValentine event (added white chocolate)
+// Custom: Handmade choco gives some EXP bonuses to married people
+//
+//===== Additional Comments: =================================
+//= WARNING!! To use this event, dicable original valentinesday.txt
+//= You can use this event from 12 till 16 February 8) [Lupus]
+//= 1.1 Removed Duplicates [Silent]
+//============================================================
+
+// Tine - Valentine Event Chocolate Even Guide ------------------
+prontera,156,172,4	script	Tine	58,{
+//  Debug info for item effects and tricky conditions 8)
+//	mes "@dsv: "+@dsv;
+//	mes "ispartneron()=="+ispartneron();
+//	mes "sex == "+sex;
+//	if(@dsv == gettime(3)+1) mes "@dsv == gettime(3)+1";
+
+	mes "[Tine]";
+	mes "The legend says that on 14th February... on the Day of Saint Valentine...";
+	mes "Only in Run-Midgard kingdom...";
+	next;
+	specialeffect 417;
+	mes "[Tine]";
+	mes "Some married chocolate lovers almost double their experience at trainings!";
+	mes "But everything isn't so simply...";
+	next;
+	menu "Wow! Tell me more!",M_INFO,"Marri... what?",-;
+
+	mes "[Tine]";
+	mes "Are you a single?";
+	mes "Today is a great date to ask your beloved half for marriage!";
+	next;
+	mes "[Tine]";
+	mes "The Marriage fee is ridiculous low these days!";
+	close;
+
+M_INFO:
+	mes "[Tine]";
+	mes "The magic effect posesses only handmade chocolate from grand-grand-grand-whoever recipes!";
+	next;
+	mes "[Tine]";
+	mes "It being known that Black Handmade Chocolate works on married guys... And the White one on the married girls!";
+	mes "If you lose your wedding ring... then alas, it won't work on you.";
+	next;
+	mes "[Tine]";
+	mes "On having a Chocolate, you should put off your ring then... put it back... And if your partner is online, then magc would last till the next hour!";
+	next;
+	mes "[Tine]";
+	mes "Rumors bark that guys and gals have +50% EXP bonuses on FIVE different races of the monsters... Exluding bloody bosses, of course.";
+	next;
+	mes "[Tine]";
+	mes "There's a fameous confectioner in the Castle of Prontera! He's the one you need.";
+	close;
+
+OnInit:
+	//559,Hand-made_Chocolate
+	setitemscript 559,"{ itemheal 50,50; if(sex==0 || @dsv == gettime(3)+1 || ispartneron()==0)end; set @dsv,gettime(3)+1; misceffect 113; }";
+	//560,Hand-made_White_Chocolate
+	setitemscript 560,"{ itemheal 50,50; if(sex || @dsv == gettime(3)+1 || ispartneron()==0)end; set @dsv,gettime(3)+1; misceffect 113; }";
+
+	//2634,Wedding_Ring_M,Wedding Ring,5,,10,0,,0,,0,127918079,7,1,136,,0,0,0,{ skill 334,1; skill 335,1; skill 336,1; }
+	setitemscript 2634,"{ skill 334,1; skill 335,1; skill 336,1; if(@dsv == gettime(3)+1 && ispartneron()){ bonus2 bExpAddRace,5,50; bonus2 bExpAddRace,6,50; bonus2 bExpAddRace,7,50; bonus2 bExpAddRace,8,50; bonus2 bExpAddRace,1,50; } }";
+	//2635,Wedding_Ring_F,Wedding Ring,5,,10,0,,0,,0,127918079,7,0,136,,0,0,0,{ skill 334,1; skill 335,1; skill 336,1; }
+	setitemscript 2635,"{ skill 334,1; skill 335,1; skill 336,1; if(@dsv == gettime(3)+1 && ispartneron()){ bonus2 bExpAddRace,0,50; bonus2 bExpAddRace,9,50; bonus2 bExpAddRace,2,50; bonus2 bExpAddRace,3,50; bonus2 bExpAddRace,4,50; } }";
+	end;
+}
+
+// Stephen - Valentine Event Chocolate seller ------------------
+alberta,26,243,4	script	Stephen#val1	58,{
+	mes "[Stephen]";
+	mes "Guess what I've got?";
+	mes "A tasty treat not easily found in Rune-Midgard....";
+	next;
+	mes "[Stephen]";
+	mes "Chocolate!";
+	mes "That's right, don't you love chocolate.... I do.";
+	mes "And you are in luck, because I'm selling them for only 5,000 zeny a piece!";
+	next;
+	menu "I want some chocolate!",M_CHOCO,"No thanks.",-;
+
+	mes "[Stephen]";
+	mes "You don't want any chocolate?";
+	mes "I'm telling you! You'll regret it!";
+	mes "You better get some now... you won't come across Chocolate like this ever again!";
+	mes "Think it over and visit me again sometime.";
+	close;
+
+M_CHOCO:
+	mes "[Stephen]";
+	mes "Hah!";
+	mes "I knew it!";
+	mes "But I can't sell you more then 5 at once....but, if you really need more....";
+	mes "you can come back again.";
+	mes "So how many do you want?";
+	next;
+	set @needmon,0;
+	input @flag_num;
+	if (@flag_num <= 0) goto L_NONE;
+	if (@flag_num > 5) goto L_ERR;
+	set @needmon,@flag_num*5000;
+	if (Zeny < @needmon) goto L_NOTENO;
+	set Zeny,Zeny - @needmon;
+	getitem 558,@flag_num;
+	mes "[Stephen]";
+	mes "There you go!";
+	mes "You can give that to someone as a gift, or enjoy it yourself!";
+	mes "Mmm....sweet chocolate...";
+	mes "Visit me anytime...!";
+	close;
+
+L_ERR:
+	mes "[Stephen]";
+	mes "I'm sorry but I can't give you that many.";
+L_NONE:
+	close;
+
+L_NOTENO:
+	mes "[Stephen]";
+	mes "I'm sorry but it seems you can't afford to buy these of me.";
+	close;
+}
+
+// Jainie -- Gives information about Valentine Event ------------------------
+alberta,29,243,4	script	Jainie#val1	53,{
+	mes "[Jainie]";
+	mes "You know what? The chocolate that my boyfriend sells are from me!";
+	mes "I made them by myself. Now I need some Milk for my special White Chocolate.";
+	next;
+	mes "[Jainie]";
+	mes "You know ... In cetain countries, there's a tradition of presenting chocolates to a person that you love...";
+	mes "They call it ^3355FFValentine's Day^000000.";
+	next;
+	mes "[Jainie]";
+	mes "So I gave him my delicious chocolate...";
+	mes "And then he made me cook a lot more...";
+	mes "And now he is selling them to everyone.";
+	mes "I guess he really enjoyed it.";
+	mes "But, I do feel good when people buy something I have made.";
+	next;
+	mes "[Jainie]";
+	mes "It would be great if you bought some too...";
+	mes "I will be making white chocolates for a while so...";
+	next;
+	menu "I want some white chocolate!",M_CHOCO,"No thanks.",-;
+
+	mes "[Jainie]";
+	mes "You don't like white chocolate?";
+	mes "Then buy some Stephen's black one!";
+	close;
+
+M_CHOCO:
+	mes "[Jainie]";
+	mes "I can't sell you more then 5 at once....but, if you really need more....";
+	mes "you can come back again.";
+	mes "So how many do you want? 1 portion is 4500z + 1 Milk.";
+	next;
+	set @needmon,0;
+	input @flag_num;
+	if (@flag_num == 0) goto L_NONE;
+	if (@flag_num > 5) goto L_ERR;
+	set @needmon,@flag_num*4500;
+	if (Zeny < @needmon) goto L_NOTENO;
+	if (countitem(519) < @flag_num) goto L_NOMILK;
+	set Zeny,Zeny - @needmon;
+	delitem 519,@flag_num;
+	getitem 561,@flag_num;
+	mes "[Jainie]";
+	mes "There you go!";
+	mes "You can give that to someone as a gift, or enjoy it yourself!";
+	mes "Mmm... sweet chocolate...";
+	mes "Visit me anytime...!";
+	close;
+
+L_ERR:
+	mes "[Jainie]";
+	mes "I'm sorry but I can't give you that many.";
+L_NONE:
+	close;
+
+L_NOTENO:
+	mes "[Jainie]";
+	mes "I'm sorry but it seems you can't afford to buy these of me.";
+	close;
+
+L_NOMILK:
+	mes "[Jainie]";
+	mes "You need "+@flag_num+" Milk for "+@flag_num+" portions of my special White Chocolate...";
+	close;
+}
+
+// Carl Orleans -- Valentine Event Chocolate maker ------------------
+prt_castle,54,34,4	script	Carl Orleans#val1	47,{
+	mes "[Carl Orleans]";
+	mes "Yes? What can I cook for you?";
+	next;
+	menu "Black handmade Chocolate, please",-,"I want a White handmade Chocolate...",M_WHITE,"I'm lost, sorry to bother you.",M_END;
+     
+	mes "[Carl Orleans]";
+	mes "Well, I just might be able to fulfill your needs...";
+	next;
+	if (countitem(558)<3) {
+		mes "[Carl Orleans]";
+		mes "I'm sorry you do not have enough Chocolate Bars to do this.";
+		if(rand(2))mes "They say Stephen from Alberta used to sell good Chocolate.";
+		close;
+	}
+	delitem 558,3;
+	mes "[Carl Orleans]";
+	mes "You got 3 pieces of pure chocolate I see.";
+	mes "Give them to me...";
+	next;
+	mes "[Carl Orleans]";
+	mes "Ok, now I will only create my special handmade chocolates if you promise to use it wisely.";
+	next;
+	mes "[Carl Orleans]";
+	mes "....Hmmmmmm.....";
+	mes "Well...";
+	next;
+	getitem 559,1;
+	mes "[Carl Orleans]";
+	mes "Here.";
+	if(rand(2))close;
+	mes "I hope you give it to someone special, because its a special chocolate.";
+	mes "As you know... only I can create this.";
+	next;
+	mes "[Carl Orleans]";
+	mes "Enjoy.";
+	close;
+
+M_WHITE:
+	mes "[Carl Orleans]";
+	mes "Well, I just might be able to fulfill your needs...";
+	next;
+	if (countitem(561)<3) {
+		mes "[Carl Orleans]";
+		mes "I'm sorry you do not have enough White Chocolate Bars to do this.";
+		if(rand(2))mes "They say Jainie from Alberta used to sell good White Chocolate.";
+		close;
+	}
+	delitem 561,3;
+	mes "[Carl Orleans]";
+	mes "You got 3 pieces of pure white chocolate I see.";
+	mes "Give them to me...";
+	next;
+	mes "[Carl Orleans]";
+	mes "Ok, now I will only create my special handmade chocolates if you promise to use it wisely.";
+	next;
+	mes "[Carl Orleans]";
+	mes "....Hmmmmmm.....";
+	mes "Well...";
+	next;
+	getitem 560,1;
+	mes "[Carl Orleans]";
+	mes "Here.";
+	if(rand(2))close;
+	mes "I hope you give it to someone special, because its a special chocolate.";
+	mes "As you know... only I can create this.";
+	next;
+	mes "[Carl Orleans]";
+	mes "Enjoy.";
+	close;
+
+M_END:
+	mes "[Carl Orleans]";
+	mes "Oh.. well, if you want me to make some of my special handmade Chocolate....";
+	mes "You will need to give me at least ^0000FF 3 Chocolates^000000 or ^0000FF 3 White Chocolates^000000.";
+	if(rand(2))close;
+	next;
+	mes "[Carl Orleans]";
+	mes "That's right, only ^0000FF 3 Chocolates^000000 or ^0000FF 3 White Chocolates^000000.";
+	mes "Bring them to me and you'll get what you came for.";
+	if(rand(2))close;
+	next;
+	mes "[Carl Orleans]";
+	mes "See You.";
+	close;
+}
diff --git a/npc/custom/events/xmas_rings_event.txt b/npc/custom/events/xmas_rings_event.txt
new file mode 100644
index 000000000..a5d442e06
--- /dev/null
+++ b/npc/custom/events/xmas_rings_event.txt
@@ -0,0 +1,193 @@
+//===== eAthena Script =======================================
+//= Karachun Event (Xmas Rings Quest)
+//===== By: ==================================================
+//= Lupus (1.0)
+//===== Current Version: =====================================
+//= 1.1
+//===== Compatible With: =====================================
+//= eAthena Version; 4880+ (with 'setItemScript' command)
+//===== Description: =========================================
+//= Custom event: Karachun (from 8 Dec till 8 Jan), X-Mas, HNY
+//===== Additional Comments: =================================
+//= 1.0 Tested, fully working. 1.0a a few typos fix
+//= 1.1 Readded Mdef +1 and  Luk +1 to Santa's Hat [Lupus]
+//============================================================
+
+
+prontera,156,174,4	script	Snower	713,{
+	mes "[Snower]";
+	if(Q_XMSRINGS==2){
+		mes "Oh.. is it true? You've helped my sis Sneewy? Thank you.";
+	}else if(Q_XMSRINGS==3){
+		mes "Snoowy's sent me a bird with a message. She told me about your help...";
+		mes "I'll tell you a secret of the magic rings.";
+		emotion e_no1;
+		next;
+		mes "[Snower]";
+		mes "They have magic power only from 8 December till 8 January.";
+		next;
+		mes "[Snower]";
+		mes "By the way, just put on Santa's Hat to discover their true power.";
+		next;
+		mes "[Snower]";
+		mes "If you put on both rings their power would be doubled.";
+		mes "Have a nice day!";
+		close;
+	}else{
+		mes "Hi! Two my sisters and I are preparing gifts for the whole 3 holidays!";
+	}
+	emotion e_sob;
+	next;
+	menu "Where are your sisters?",-, "What holidays?",M_PR,"What gifts?",M_WRAP,"May I help you?",M_QUEST;
+
+	mes "[Snower]";
+	mes "My younger sis Sneewy's left to some faraway land to prepare gifts for their poor children... I don't know where. You should ask my elder sis and her birdies.";
+	next;
+	mes "[Snower]";
+	mes "My elder sis? Her name's Snoowy. She's sailed to some green island... She's talking about some gifts for dolphins or something...";
+	close;
+
+M_PR:
+	mes "[Snower]";
+	mes "The whole three holidays? Well they come one after another!";
+	mes "^000080The Christmas^000000, ^FF0000Karachun^000000 and ^008000New Year Eve^000000!";
+	next;
+	mes "[Snower]";
+	mes "^FF0000Karachun^000000? Heh... This is an old pagans festival. They used to celebrate it before the appearance of HNY and XMas, you know.";
+	next;
+	goto M_QUEST;
+
+M_WRAP:
+	mes "[Snower]";
+	mes "My sisters say that all the gifts should look the same way. Or else some children might fight for fancy ones!";
+	next;
+	mes "[Snower]";
+	mes "Would you like me to wrap your fancy gift boxes with a gray paper?";
+	next;
+	menu "Wrap them, please!",-, "No, thanks.",M_QUEST;
+
+	set @prizes, countitem(664)+countitem(665)+countitem(666)+countitem(667);
+	if( @prizes == 0){
+		mes "[Snower]";
+		mes "I don't see any gifts in fancy boxes on you...";
+		if(countitem(644))mes "You've got only gray boxes.";
+		close;
+	}
+	delitem 664,countitem(664);
+	delitem 665,countitem(665);
+	delitem 666,countitem(666);
+	delitem 667,countitem(667);
+	getitem 644,@prizes;
+
+	mes "[Snower]";
+	mes "*shuffle* Here you go.";
+	next;
+
+M_QUEST:
+	mes "[Snower]";
+	mes "I wish you find my sisters ASAP... They need help.";
+	if(Q_XMSRINGS==0) set Q_XMSRINGS,1;
+	close;
+
+OnInit:
+//Santa's Hat
+	setitemscript 2236,"{ bonus bMdef,1; bonus bLuk,1; if(isequipped(2636,2637)){if(@xmr == gettime(2))end; set @xmr,gettime(2); misceffect 410; end;} if(isequipped(2636)){if(@xmr == gettime(2))end; set @xmr,gettime(2); misceffect 72;} if(isequipped(2637)){if(@xmr == gettime(2))end; set @xmr,gettime(2); misceffect 338;}}";
+//Gold Xmas Ring
+	setitemscript 2636,"{ bonus bLoseSPWhenUnequip,30; if(isequipped(2236)==0)end; if(getskilllv(28)){skill 51,4+isequipped(2637);}else{skill 28,1+4*isequipped(2637);} }";
+//Silver Xmas Ring
+	setitemscript 2637,"{ bonus bDamageWhenUnequip,40; if(isequipped(2236)==0)end; if(getskilllv(26)){skill 40,1;}else{skill 26,1+isequipped(2636);} }";
+	end;
+}
+
+louyang,224,249,4	script	Sneewy	717,{
+	mes "[Sneewy]";
+	if(Q_XMSRINGS==0){
+		mes "Hi! I'm waithing for my sister's birdy with mail...";
+		emotion e_sob;
+		close;
+	}
+	if(Q_XMSRINGS==1){
+		mes "I wish I had 4 more gray Gift Boxes for native children...";
+		emotion e_sob;
+		next;
+		mes "[Sneewy]";
+		mes "Oh, hello. Has my brother Snower told you everything?";
+		next;
+		menu "Here are your 4 Gift Boxes",-, "I don't know any Snowhatevers...",M_END;
+
+		mes "[Sneewy]";
+		if(countitem(644)<4){
+			mes "Gimme 4 gifts for poor kids... Wait, you haven't got 4 of them!";
+			emotion e_sry;
+			close;
+		}
+		set Q_XMSRINGS,2;
+		delitem 644,4;
+		getnameditem 2637,strcharinfo(0);
+		emotion e_kis2;
+		mes "Thank you! Here's my li'l something for you!";
+		next;
+		mes "[Sneewy]";
+		mes "By the way, if you put on 2 different rings then your holidays leveling would be easier!";
+		close;
+	}
+	emotion e_thx;
+	mes "Thanks again! No children will meet the holidays without the gifts!";
+	close;
+
+M_END:
+	mes "[Sneewy]";
+	mes "Pity... I've got a magic Santa's ring... I'd exchange it for 4 Gift Boxes...";
+	emotion e_swt;
+	close;
+}
+
+izlu2dun,133,160,2	script	Snoowy	714,{
+	mes "[Snoowy]";
+	if(Q_XMSRINGS==0){
+		mes "Helloooou! Do you know my bro and sis? How so? My brother Snower's well known in Prontera!! Just ask any child there.";
+		emotion e_hmm;
+		close;
+	}
+	if(Q_XMSRINGS==1){
+		mes "Darn... How could poor children be more important than the marine folks.. Am I wrong?";
+		next;
+		mes "[Snoowy]";
+		mes "Errr. Helloou there. My sister Sneewy's sent me a birdie message. The letter was wet and I couldn't read anything but some ending letters of her address...";
+		next;
+		mes "[Snoowy]";
+		mes "Look, it's something like 'yang' in the very end... Hmm... She must be misspelled 'Al Doo Boryang'...";
+		close;
+	}
+	if(Q_XMSRINGS==2){
+		mes "You've helped my sis? It's just great!";
+		next;
+		mes "[Snoowy]";
+		mes "But I too need 3 more gifts for my marine folk friends...";
+		next;
+		menu "Have these gifts!",-, "I need a li'l something in return",M_END;
+
+		mes "[Snoowy]";
+		if(countitem(644)<3){
+			mes "Oops!! You haven't got 3 gray gift boxes on you.";
+			emotion e_sry;
+			close;
+		}
+		set Q_XMSRINGS,3;
+		delitem 644,3;
+		getnameditem 2636,strcharinfo(0);
+		emotion e_kis;
+		mes "Thaank yoouu! Have this magic ring!";
+		close;
+	}
+	emotion e_thx;
+	mes "Oh... the whole marine folk send you their thanks! They love presents so much!!!";
+	if(rand(2))mes "Didn't you know that Santa's Hat reveals the real power of the rings?";
+	close;
+
+M_END:
+	mes "[Snoowy]";
+	mes "I'd exchange a GOLD magic ring for 3 gift boxes...";
+	emotion e_swt;
+	close;
+}