path: root/npc/quests/quests_amatsu.txt

//===== eAthena Script ======================================= 
//= Quest NPCs related to Amatsu
//===== By: ================================================== 
//= eAthena team & others? & MasterOfMuppets
//===== Current Version: ===================================== 
//= 1.2
//===== Compatible With: ===================================== 
//= eAthena 7.15 +
//===== Description: ========================================= 
//= Momotaro event, Sushi Quest, Amatsu Event
//===== Additional Comments: ================================= 
//= 1.0 Rewrote parts of other/momotaro.txt to make it work.
//=	I'm sorry for the mess, I couldn't do much better with
//=	the current code I had.
//= 1.1 Added Sushi Quest and Amatsu Event from cities/ [Evera]
//= 1.2 Fixed Momotaro Quest, thanks to .~Abism0~. [Lupus]
//============================================================ 

amatsu,223,235,4	script	Publisher	763,{
	if (event_momo > 4) goto Lfin;
	if ((event_momo >= 1) && (event_momo <= 4)) goto Lget;
	mes "[Publisher]";
	mes "Hello~~!!";
	mes "Our ^00B6FFScroll Publishing Company^000000";
	mes "is professionally publishing";
	mes "tales.";
	next;
	mes "[Publisher]";
	mes "We established";
	mes "^3366FFMomotaro Field Trip^000000";
	mes "to celebrate ^00B6FF<Momotaro Story>^000000";
	mes "selling over a million copies.";
	next;
	mes "[Publisher]";
	mes "Become Momotaro and eliminate";
	mes "Dokebis, just like in the story!";
	mes "There will also be rewards.";
	next;
	menu "What is Momotaro Story?!",-,"I want to try!",L1,"I'm busy right now...",L2;
		mes "[Publisher]";
		mes "Eh~!? How can you not know about";
		mes "Momotaro? Don't they have this";
		mes "tale in Rune-Midgard?? Well...";
		mes "Let me tell you the story.";
		next;
		mes "[Publisher]";
		mes "Long ago, there lived an old";
		mes "married couple. They were happy,";
		mes "but didn't have any children.";
		next;
		mes "[Publisher]";
		mes "One day, while old lady was doing";
		mes "the laundry, she found a humongous";
		mes "peach. She cut it in half and...";
		mes "'Poof!' There was a baby inside!";
		next;
		mes "[Publisher]";
		mes "The old man and lady were shocked.";
		mes "They decided to adopt that baby,";
		mes "and give him their love...";
		next;
		mes "[Publisher]";
		mes "That baby grew so fast, like that";
		mes "beanstalk from 'Jack and";
		mes "Beanstalk' and became a strong boy";
		mes "in only a few days.";
		next;
		mes "[Publisher]";
		mes "That's boy's name was...";
		mes "<Momotaro>!!!";
		mes "Momotaro traveled to eliminate";
		mes "dokebis that were harassing";
		mes "the towners.";
		next;
		mes "[Publisher]";
		mes "He became friends with";
		mes "^3151FFYoyo, Picky, and Desert Wolf^000000";
		mes "and eliminated all of the Dokebis.";
		mes "then he lived happily ever after";
		mes "with the old couple.";
		next;
		mes "[Publisher]";
		mes "How was it?";
		mes "Great, right?";
		mes "I mean, this story sold a million";
		mes "copies!";
		close;
L1:
		mes "[Publisher]";
		mes "Yay-! You look excited!";
		mes "You'll be ready to go soon.";
		mes "Please fill out this registration";
		mes "card.";
		next;
		mes "[Publisher]";
		mes ".................";
		mes "......Mm.....Let's see.....";
		mes ".............Good!";
		mes "Alright, then!";
		mes "Let it begin~~~!!!!!!!!!";
		mes "<Momotaro Field Trip>~!";
		close2;
		warp "ama_test",52,35;
		end;
L2:
		mes "[Publisher]";
		mes "Eh?";
		mes "...But there are sweet rewards";
		mes "waiting...";
		close;
Lget:
	mes "[Publisher]";
	mes "How was it? Did you enjoy the event?";
	mes "I hope the arrangements at the event hall allowed you to spend an enjoyable time there.";
	next;
	if (event_momo >= 1 && event_momo < 4)
	{
		switch(rand(1,10))
		{
		case 1: getitem 622,1; break; //rainbow carrot
		case 2: getitem 627,1; break; //sweet milk
		case 3: getitem 629,1; break; //singing flower
		case 4: getitem 632,1; break; //fatty chubby earthworm
		case 5: getitem 623,1; break; //earthworm the dude
		case 6: getitem 619,1; break; //unripe apple
		case 7: getitem 621,1; break; //bitter herb
		case 8: getitem 620,1; break; //orange juice
		case 9: getitem 625,1; break; //rusty iron
		case 10: getitem 624,1; break; //rotten fish
		}
	}

//Am Mut successful finish unknown
	if (event_momo == 4)
	{
		switch(rand(1,10))
		{
		case 1: getitem 659,1; break; //her heart
		case 2: getitem 633,1; break; //sweet potato
		case 3: getitem 634,1; break; //tropical banana
		case 4: getitem 639,1; break; //armlet of obedience
		case 5: getitem 636,1; break; //no recipient
		case 6: getitem 628,1; break; //well-dried bone
		case 7: getitem 637,1; break; //old broom
		case 8: getitem 635,1; break; //orc trophy
		case 9: getitem 626,1; break; //monster juice
		case 10: getitem 641,1; break; //contract in shadow
		}
	}
	set event_momo,5;
	mes "[Publisher]";
	mes "Well then, I will give you a small present which I have prepared.";
	mes "May the legend be widely loved also in the future......";
	close;
Lfin:
	mes "[Publisher]";
	mes "We have a nice weather today, don't we...... It is a perfect day to dry the futon.";
	close;
}
//=====================================================================
ama_test,50,44,4	script	Event Hall Staff	109,{
	mes "[Satoshi]";
	mes "Welcome to <Momotaro Field Trip>";
	next;
	mes "[Satoshi]";
	mes "I'm Satoshi who is in charge of the";
	mes "waiting room in <Momotaro Field";
	mes "Trip>.";
	next;
	mes "[Satoshi]";
	mes "Originally, I was working for the";
	mes "publishing company, but we lacked";
	mes "workers for the Field Trip...";
	mes "But working here is much better!";
	mes "Now I just watch people trying to";
	mes "accomplish the mission. Heh hehe~";
	next;
	mes "[Satoshi]";
	mes "..............";
	mes "Just kidding";
	mes "^111111*Wipes away sweat*^000000";
	next;
	mes "[Satoshi]";
	mes "Well, let me explain";
	mes "about the rules in the Field Trip";
	next;
	mes "[Satoshi]";
	mes "First of all...Did you hear";
	mes "about the story from the";
	mes "publisher?";
	next;
	menu "Yes",L1,"No",-;
		mes "[Satoshi]";
		mes "Eh? You can't just";
		mes "skip the story";
		mes "when you enter the field";
		mes "trip! I can't allow you to";
		mes "do that as a Momotaro's";
		mes "fan!!!";
		next;
		mes "[Satoshi]";
		mes "Please listen to the story";
		mes "from the publisher.";
		mes "Thank you.";
		mes "Bye~~";
		close2;
		warp "amatsu",223,230;
		end;
L1:
		mes "[Satoshi]";
		mes "Hehe...Good.";
		mes "Momotaro's Story is our";
		mes "pride. It's the best story EVER.";
		mes "Hahaha!!!";
		next;
		mes "[Satoshi]";
		mes "...Hmmhmm.";
		next;
		mes "[Satoshi]";
		mes "The Field Trip is simple.";
		mes "Go inside and eliminate";
		mes "Dokebis bravely!!!";
		mes "Just like Momotaro!!!";
		mes "Understand? Bravely!!!";
		next;
		mes "[Satoshi]";
		mes "In addition, there are three";
		mes "things you need to know.";
		next;
		mes "[Satoshi]";
		mes "First....";
		mes "You can't come back once you clear";
		mes "the field trip. Keep that in mind.";
		next;
		mes "[Satoshi]";
		mes "Secondly...";
		mes "Q-pet is prohibited";
		mes "inside of the field trip.";
		mes "if you are with a pet,";
		mes "please change it to egg status.";
		next;
		mes "[Satoshi]";
		mes "And finally...";
		mes "One person can be on the";
		mes "field trip for 6 minutes.";
		next;
		mes "[Satoshi]";
		mes "Well then, Please";
		mes "wait for you turn";
		mes "in the waitiSng room.";
		mes "Good luck in fighting!!";
		close;
OnInit:
	waitingroom "Event Hall Waiting Room",1,"Event Hall Staff::OnMax";
OnInitCopy:
	enablewaitingroomevent "Event Hall Staff";
	areawarp "ama_test",30,78,68,120,"amatsu",223,230;
	disablenpc "Manager#Momotaro";
	enablenpc "Grandpa#Momotaro";
	enablenpc "Grandma#Momotaro";
	donpcevent "#MomotaroTimer::OnStopTimer";
	killmonsterall "ama_test";
	end;
OnMax:
	warpwaitingpc "ama_test",51,85;
	disablewaitingroomevent "Event Hall Staff";
	disablenpc "Manager#Momotaro";
	enablenpc "Grandpa#Momotaro";
	enablenpc "Grandma#Momotaro";
	donpcevent "#MomotaroActivator::OnMomoInit";
	end;
}

ama_test,1,1,0	script	#MomotaroTimer	-1,{
OnStartTimer:
	initnpctimer;
	end;
OnTimer180000:
	if(!isloggedin($MomotaroRID))goto s_Cleanup;
	mapannounce "ama_test","Timer: 3 Minutes left.",8;
	end;
OnTimer300000:
	if(!isloggedin($MomotaroRID))goto s_Cleanup;
	mapannounce "ama_test","Timer: 1 Minute left.",8;
	end;
OnTimer360000:
	if(!isloggedin($MomotaroRID))goto s_Cleanup;
	mapannounce "ama_test","Timer: Beep- Beep- Beep- Time's up.",8;
OnTimer362500:
	areawarp "ama_test",30,78,68,120,"amatsu",223,230;
	goto s_Cleanup;


OnTimer20000:
OnTimer40000:
OnTimer60000:
OnTimer80000:
OnTimer100000:
OnTimer120000:
OnTimer140000:
OnTimer160000:
OnTimer200000:
OnTimer220000:
OnTimer240000:
OnTimer260000:
OnTimer280000:
OnTimer320000:
OnTimer340000:
	if(!isloggedin($MomotaroRID))goto s_Cleanup;
	end;

OnCleanUp:
s_Cleanup:
	stopnpctimer;
	set $Momotaro,0;
	set $MomoDokebi,0;
	set $MomoDokebi2,0;
	set $MomotaroRID,0;
	mapannounce "ama_test","The current player has exited. The waiting room will now open again.",8;
	disablenpc "Manager#Momotaro";
	donpcevent "Event Hall Staff::OnInitCopy";
	end;

OnStopTimer:
	stopnpctimer;
	end;

}

ama_test,51,85,0	script	#MomotaroActivator	139,1,1,{
	if($Momotaro)end;
	set $Momotaro,1;
	set $MomotaroRID,getcharid(3);
	areaannounce "ama_test",30,78,68,120,"Timer: The Timer has been activated. You have 6 minutes. Annihilate the monsters in time!",8;
	donpcevent "#MomotaroTimer::OnStartTimer";
	mes "[Grandpa]";
	mes "Arrrk!!!";
	next;
	mes "[Grandma]";
	mes "Honey!! Someone hacked my account";
	mes "and stole my equipment!!";
	next;
	mes "[Grandpa]";
	mes "Hmm. The Chief said the Dokebi";
	mes "earned 20 million zeny by hacking";
	mes "other's accounts...";
	next;
	mes "[Grandma]";
	mes "Dohhhhhhh!!!!";
	next;
	mes "[Grandpa]";
	mes "...Huh I've heard that somewhere";
	mes "before....";
	next;
	mes "[Grandpa]";
	mes "Anyway, Momotaro...";
	next;
	mes "[Grandpa]";
	mes "As you know, since we towners spends";
	mes "our time sitting and chatting,";
	mes "we can't kill Dokebis because we're";
	mes "low levels, so...Please do it for";
	mes "us.";
	next;
	mes "[Grandma]";
	mes "Momotaro...";
	mes "I really wanted to give you";
	mes "a handmade ^3151FFYummiest Red Poiton in";
	mes "the whole world^000000 ...but...";
	mes ".....I failed to make them ....";
	next;
	mes "[Grandma]";
	mes "...I'm sorry. I should have been";
	mes "leveling up before...^111111*Sob*";
	next;
	mes "[Grandma & Grandpa]";
	mes "So...Do me this favor, kid~";
	close2;
	initnpctimer;
	end;

OnTimer5000:
	stopnpctimer;
	set $MomoDokebi,0;
	set $MomoDokebi2,0;
	disablenpc "Grandpa#Momotaro";
	disablenpc "Grandma#Momotaro";
	monster "ama_test",47,101,"Dokebi",1110,1,"mobcount#momotaro::OnMobDead";
	monster "ama_test",51,101,"Dokebi",1110,1,"mobcount#momotaro::OnMobDead";
	monster "ama_test",55,101,"Dokebi",1110,1,"mobcount#momotaro::OnMobDead";
	monster "ama_test",55,97,"Dokebi",1110,1,"mobcount#momotaro::OnMobDead";
	monster "ama_test",55,93,"Dokebi",1110,1,"mobcount#momotaro::OnMobDead";
	monster "ama_test",53,91,"Dokebi",1110,1,"mobcount#momotaro::OnMobDead";
	monster "ama_test",49,91,"Dokebi",1110,1,"mobcount#momotaro::OnMobDead";
	monster "ama_test",45,96,"Dokebi",1110,1,"mobcount#momotaro::OnMobDead";
	monster "ama_test",45,99,"Dokebi",1110,1,"mobcount#momotaro::OnMobDead";
	end;

OnInit:
	set $Momotaro,0;
	set $MomoDokebi,0;
	set $MomoDokebi2,0;
	set $MomotaroRID,0;
	end;

}

ama_test,49,95,4	script	Grandpa#Momotaro	766,{

	mes "[Grandpa]";
	mes "Zzzzzz......";
	close;
}

ama_test,51,95,4	script	Grandma#Momotaro	761,{

	mes "[Grandma]";
	mes "Oh....!?";
	close;

}

ama_test,50,100,4	script	Manager#Momotaro	762,{

	if (event_momo >= 4) goto LSecondFin;
	mes "[Manager]";
	mes "Hoho, you did it...... I'm the manager here...... You are not an ordinary person, right? You did very well.";
	next;
	mes "[Manager]";
	mes "The Momotaro from the legend appears in this world!";
	mes "Hohohohoho!";
	next;
	menu "Is there some extra?",L1,"Thanks for nothing......",L2;
L1:
	mes "[Manager]";
	mes "Hohoho......";
	mes "This is maybe not really recomending......";
	mes "I think in your current condition the small demons can twirl you lightly around their fingers.";
	mes "......Hohoho......";
	next;
	mes "[Manager]";
	mes "......";
	mes "Just a joke.";
	next;
	mes "[Manager]";
	mes "Well then, you enjoyed the Momotaro Event Hall?";
	mes "Talk to the staff member, that you have met first, about our premium presents. He will give you some.";
	next;
	mes "[Manager]";
	mes "Whatever you encounter, never loose that strong spirit!";
	close2;
	set $Momotaro,0;
	set $MomoDokebi,0;
	set $MomoDokebi2,0;
	set $MomotaroRID,0;
	set event_momo,1;
	donpcevent "Event Hall Staff::OnInitCopy";
	warp "amatsu",223,230;
	disablenpc "Manager#Momotaro";
	end;
L2:
	mes "[Manager]";
	mes "!!!!!";
	mes "......Ho...Hohoho......";
	mes "You are an amusing fellow......";
	mes "Well...... One little suggestion from me to you.";
	next;
	mes "[Manager]";
	mes "Normally I would just kick you out, but...... I would like to see your true capabilities... Hohoho.";
	mes "As if I would look at my own young self. Hohohoho.";
	next;
	mes "[Manager]";
	mes "What do you think? I will give this one nonrecurring chance. It is the challenge of ^3355ffSecond Grade^000000 which is not officially available......";
	mes "But I warn you, this one will be difficult.";
	next;
	menu "Na, it is enough",L2_1,"I take the challenge",L2_2;
L2_1:
	mes "[Manager]";
	mes "Hoho......";
	mes "You got tired from the last fight?";
	mes "Well, ok...... Did you enjoy the Momotaro Event Hall? Talk to the staff member, that you have met first, about our premium presents. She will give you some.";
	next;
	mes "[Manager]";
	mes "Whatever you encounter, never loose that strong spirit!";
	next;
	set event_momo,2;
	goto LWarpOut;
L2_2:
	mes "[Manager]";
	mes "Hohoho, You like it more and more, right? This will be the last decisive battle. Show your power without regrets!";
	initnpctimer;
	close;
OnTimer5000:
	stopnpctimer;
	if(!isloggedin($MomotaroRID)){ donpcevent "#MomotaroTimer::OnCleanUp"; end; }
	attachrid($MomotaroRID);
	monster "ama_test",35,103,"Am Mut",1301,1,"mobcount2#momotaro::OnMobDead";
	monster "ama_test",56,111,"Am Mut",1301,1,"mobcount2#momotaro::OnMobDead";
	monster "ama_test",40,91,"Am Mut",1301,1,"mobcount2#momotaro::OnMobDead";
	misceffect 16;
	set event_momo,3;
	disablenpc "Manager#Momotaro";
	end;
LSecondFin:
	mes "[Manager]";
	mes "You are really strong... Wasn't it thrilling? Momotaro Event Hall can be really enjoyable, right?";
	mes "Ok now, talk to the staff member, that you have met first, about our premium presents. She will give you some.";
	close2;	
	set event_momo,4;
LWarpOut:
	mes "[Manager]";
	mes "Whatever you encounter, never loose that strong spirit!";
	close2;
	set $Momotaro,0;
	set $MomoDokebi,0;
	set $MomoDokebi2,0;
	set $MomotaroRID,0;
	warp "amatsu",223,230;
	donpcevent "Event Hall Staff::OnInitCopy";
	disablenpc "Manager#Momotaro";
	end;
OnStart:
	misceffect 215;
	if(!isloggedin($MomotaroRID)){ donpcevent "#MomotaroTimer::OnCleanUp"; end; }
	attachrid($MomotaroRID);
	mes "[Manager]";
	mes "Hohoho......";
	close;

}
//=======================================MobCount===============================-
ama_test,0,1,0	script	mobcount#momotaro	-1,{
OnMobDead:
	if ($MomoDokebi >= 8){
		areaannounce "ama_test",30,78,68,120,"Dokebi: I will be baaack~~~~!!!",8;
		attachrid($MomotaroRID);
		initnpctimer;
		end;
	}
	set $MomoDokebi,$MomoDokebi+1;
	set @mobrand,rand(4);
	if (@mobrand == 1) goto Lrand1;
	if (@mobrand == 2) goto Lrand2;
	if (@mobrand == 3) goto Lrand3;

	areaannounce "ama_test",30,78,68,120,"Dokebi: I'm sorry~~! Waaaaah~~",8;
	end;
Lrand1:
	areaannounce "ama_test",30,78,68,120,"Dokebi: !! IT'S A RAID!!!! RUN!!",8;
	end;
Lrand2:
	areaannounce "ama_test",30,78,68,120,"Dokebi: But I didn't even do anything baaaaad~!",8;
	end;
Lrand3:
	areaannounce "ama_test",30,78,68,120,"Dokebi: Ow, Ouch!!!",8;
	end;
OnTimer5000:
	donpcevent "mobcount2#momotaro::OnTimer5000";
	end;
}
//=======================================MobCount2==============================-
ama_test,50,101,0	script	mobcount2#momotaro	-1,{
OnMobDead:
	if ($MomoDokebi2 == 2) goto Lfin;
	set $MomoDokebi2,$MomoDokebi2+1;
	areaannounce "ama_test",30,78,68,120,"Am Mut: Ow, Ouch!!!",8;end;
Lfin:
	areaannounce "ama_test",30,78,68,120,"Am Mut: I'm sorry~~! Waaaaah~~",8;
	set event_momo,4;
	initnpctimer;
	end;
OnTimer5000:
	stopnpctimer;
	enablenpc "Manager#Momotaro";
	donpcevent "Manager#Momotaro::OnStart";
	end;

}

//============================================================
//====================================================== Sushi
//====================================================== Quest
ama_in01,162,17,0	script	Iron Chef	765,{
	if (ama_sushi == 1) goto LStart2;
	mes "[ShabuShabu]";
	mes "*Sighs* This is getting worse..";
	mes "Everyday more customers come,";
	mes "but I can never get";
	mes "enough material, even today.";
	mes "A lot of customers surely will be hungry?";
	next;
	mes "[ShabuShabu]";
	mes "*Sigh*, a customer. Welcome.";
	mes "As always, my homemade sashimi";
	mes "focuses on the freshness. What do you need?";
	next;
	menu "I want to buy shrimp sushi",L1,"I want to buy sashimi",L2,"Need some help!",L3,"Keep up the good work",-;
		mes "[ShabuShabu]";
		mes "Alright then, my sashimi";
		mes "are famous throughout the world! Their taste relies on its freshness, and no one else can make them.";
		mes "If you have a chance, come try a little sashimi!";
		close;
	L1:
		mes "[ShabuShabu]";
		mes "Alright! How much do you want?";
		mes "Unit price 700 zeny, but if you only want a taste,";
		mes "I'll give you a discount of 74 zeny,";
		mes "If you like the taste come back and find me later.";
		next;
		menu "I want the 700 zeny piece!",L1_1,"I want the 74 zeny sample!",L1_2,"I'll come eat next time",-;
			mes "[ShabuShabu]";
			mes "Alright then, my shrimp sushi";
			mes "are famous throughout the world! Their taste relies on its freshness, and no one else can make them.";
			mes "If you have a chance, come try a little sashimi!";
			close;
		L1_1:
			if (Zeny < 700) goto Lzeny;
			set Zeny,Zeny-700;
			getitem 551,10; //Sushi
			mes "[If you have a chance, come try a little sashimi!]";
			mes "Thank you very much";
			close;
		L1_2:
			if (Zeny < 74) goto Lzeny;
			set Zeny,Zeny-74;
			getitem 551,1; //Sushi
			mes "[If you have a chance, come try a little sashimi!]";
			mes "Thank you very much";
			close;
	L2:
		mes "[ShabuShabu]";
		mes "Alright! How much do you want?";
		mes "Unit price 350 zeny, but if you only want a taste,";
		mes "I'll just give you a discount of 37 zeny.";
		mes "If you like the taste come back and find me later";
		next;
		menu "I want the 350 zeny piece!",L2_1,"I want the 37 zeny sample",L2_2,"I'll come eat next time",-;
			mes "[ShabuShabu]";
			mes "Alright then, my sashimi";
			mes "are famous throughout the world! Their taste relies on its freshness, and no one else can make them.";
			mes "[If you have a chance, come try a little sashimi!]";
			close;
		L2_1:
			if (Zeny < 350) goto Lzeny;
			set Zeny,Zeny-350;
			getitem 544,10; //Raw Fish
			mes "[ShabuShabu]";
			mes "Thank you very much";
			close;
		L2_2:
			if (Zeny < 37) goto Lzeny;
			set Zeny,Zeny-37;
			getitem 544,1; //Raw Fish
			mes "[ShabuShabu]";
			mes "Thank you very much";
			close;
		Lzeny:
			mes "[ShabuShabu]";
			mes "You don't have enough zeny with you";
			close;
L3:
		mes "[ShabuShabu]";
		mes "Oh, any help is welcomed!!";
		mes "I was just worrying about not having enough material everyday.";
		mes "Do you want to hear my request?";
		mes "Of course I will pay you to help me.";
		next;

		set ama_sushi,1;
		mes "[ShabuShabu]";
		mes "Crab Shell.";
		mes "They are all out. I need them right now.";
		mes "So please find ^0000FF10Crab shells^000000.";
		mes "I can never find it when I need it.";
		mes "I'll be counting on you.";
		next;
		mes "[ShabuShabu]";
		mes "Then, please hurry! I'll be here";
		mes "waiting for you, please don't forget my request!";
		close;
LStart2:
	if (countitem(964)>=10) goto Lok;
	mes "[ShabuShabu]";
	mes "Man, don't have my materials ready?";
	mes "Oh no, you didn't forget it did you?";
	next;
	mes "[ShabuShabu]";
	mes "^0000FF10Crab shells^000000";
	mes "Don't forget again.";
	mes "You must help me find them!";
	close;
Lok:
	delitem 964,10; //Clam Shell
	getitem 551,20; //Sushi
	mes "[ShabuShabu]";
	mes "Hmm! Thank you so much";
	next;
	mes "[ShabuShabu]";
	mes "Here is my thanks, take it!";
	set ama_sushi,0;
	close;

}

//============================================================
//===================================================== Amatsu
//====================================================== Event
amatsu,189,166,4	script	Kouji	764,{
	mes "[Kuruchi]";
	mes "Lalala Lalala Lalalalalala..";
	mes "Lalala Lalala Lalalalalala..";
	next;
	if (event_amatsu == 2) goto L1;
	if ((event_amatsu == 3) || (event_amatsu == 4)) goto L2;
	if (event_amatsu == 5) goto L3;
	if (event_amatsu == 6) goto L4;
L0:
	mes "[Kuruchi]";
	mes "Hanging Under the Blue Sky's Blue Roof";
	mes "Shining on Blue Wall's Reflection on the Blue Lake";
	mes "Blue Hearting Containing a Blue Desire";
	mes "Blue, Blue Every thing's Blue";
	next;
	goto LEnd;
L1:
	mes "[Kuruchi]";
	mes "Monk, Monk, the fox is following me";
	mes "Because I have its favourite food";
	mes "Ramen noodle, my favourite too";
	mes "I can eat it three times a day";
	set event_amatsu,3;
	goto LEnd;
L2:
	mes "[Kuruchi]";
	mes "Monk, Monk, The Fox Is Following Me";
	mes "Shout At Him To Scare It Off!";
	mes "Voice Too Small So It Didn't Run Off";
	mes "Followed All The Way To North Side's Shrine!";
	set event_amatsu,4;
	goto LEnd;
L3:
	mes "[Kuruchi]";
	mes "Monk, Monk, The Fox Is Following Me";
	mes "Ramen noodles My Favorite";
	mes "But Now I am No Longer Afraid?";
	mes "I Shouted Loudly To Scare It Off!";
	goto LEnd;
L4:
	mes "[Kuruchi]";
	mes "The Town's Dock Has An Abandoned Boat!";
	mes "Everyone Forget That In The Ship";
	mes "Is Full Of Treasure And Gold";
	mes "A Boat That Is Feared By Everyone";
	goto LEnd;

LEnd:
	next;
	mes "[Kuruchi]";
	mes "Lalala Lalala Lalalalalala..";
	mes "Lalala Lalala Lalalalalala..";
	close;
}
//=====================================================================
amatsu,171,174,4	script	Guard Soldier#01	767,{
	if ((event_amatsu == 0) || (event_amatsu == 1)) goto L0;
	if (event_amatsu == 6) goto L1;
	if (event_amatsu == 7) goto L2;
	mes "[Guard Soldier]";
	mes "This area is where";
	mes "the Master's mother";
	mes "Is here for her treatment.";
	next;
	mes "[Guard Soldier]";
	mes "Although it's not much to talk about...";
	mes "She has been sick here for several months";
	mes "and started to live here";
	close;
L0:
	mes "[Guard Soldier]";
	mes "This is where the Master's mother stays at.";
	mes "Please keep quiet, we are also";
	mes "very worried watching this everyday";
	next;
	mes "[Guard Soldier]";
	mes "Why does this happen";
	mes "to our benign and wise Master...";
	mes "I don't understand, *sobs*...";
	close;
L1:
	mes "[Guard Soldier]";
	mes "What? Seems like something";
	mes "flew by...  Didn't you see? Oh...";
	mes "And I heard a loud noise... Scared the shit out of me";
	close;
L2:
	mes "[Guard Soldier]";
	mes "Our master should be alright now.";
	mes "We are also greatly relieved.";
	mes "You have no idea how worried we were... Phew.";
	close;
}
//=====================================================================
amatsu,164,174,4	script	Guard Soldier#02	767,{
	if (event_amatsu == 0) goto LOnce;
	if ((event_amatsu >= 2) && (event_amatsu <= 5)) goto L2;
	if (event_amatsu == 6) goto L3;
	if (event_amatsu == 7) goto L4;
	mes "[Guard Soldier]";
	mes "Hopefully she will return healthy soon...";
	mes "The Master has spent a lot of time";
	mes "taking care and worrying about her.";
	close;
LOnce:
	mes "[Guard Soldier]";
	mes "Do not enter here.";
	mes "This is where the master's mother is";
	mes "recuperating.";
	next;
	mes "[Guard Soldier]";
	mes "Although it's not much to talk about.";
	mes "But she has been sick here for several months";
	mes "and started to live here.";
	set event_amatsu,1;
	close;
L2:
	mes "[Guard Soldier]";
	mes "If you are invited by the Master...";
	mes "Please do come in.";
	mes "Up till today, many doctors came to diagnose but";
	mes "all their efforts seem futile.";
	close;
L3:
	mes "[Guard Soldier]";
	mes" Hey!";
	mes" What's that sound!?";
	mes" Where did it come from!?";
	close;
L4:
	mes "[Guard Soldier]";
	mes "The master's mother still";
	mes "hasn't fully recovered.. ";
	mes "Although, it seems to have turned for the better.";
	mes "But then again..";
	close;
}

//=====================================================================
ama_in01,22,111,0	script	Old Lady#01	761,{
	if (event_amatsu == 5) goto LStart2;
	if (event_amatsu == 6) goto LStart3;
	if (event_amatsu == 7) goto LStart4;
	mes "[...]";
	mes "^FF6060Clang Clannng! Clang Clannng!  Stupid humans again!";
	mes "Clang Clannng, Clang Clannng. Who is it? Is it human!?";
	mes "What do you need here! Hurry up";
	mes "Get out... Clang Clannng! Clang Clannng!^000000";
	next;
	mes "[...]";
	mes "^FF6060I have decided to live here till";
	mes "the Ishida Family line ends!";
	mes "Stop bothering me and get out! Clang Clannng!^000000";
	next;
	warp "amatsu",167,197;
	end;
LStart2:
	mes "[...]";
	mes "^FF0066Clang Clannng! Clang Clannng! Here comes another one!";
	mes "Stupid Humans! What do you want now";
	mes "Throw me out of here!?^000000";
	next;
	mes "[...]";
	mes "^FF0066Seems like you learned something somewhere,";
	mes "That's about all you can do";
	mes "You can't do anything to me!! Clang Clannng!^000000";
	next;
	menu "HAAAA!!",-;
	set @which,rand(2);
	if (@which == 1) goto Lfail;
	mes "[...]";
	mes "^FF0066Clang Clannng! Clang Clannng! Clang Clannng! This Bastard!";
	mes "He threw me out like this!";
	mes "Sick! Not fair!!^000000";
	next;
	mes "[...]";
	mes "^FF0066That god-damned Ishida that rendered me to this.";
	mes "I'll curse them forever! FOREVER!";
	mes "Human, you better be careful too!^000000";
	next;
	monster "ama_in01",22,112,"Fox",1180,1;
	killmonsterall "ama_in01";
	getitem 1022,1; //Nine Tails
	mes "[...]";
	mes "^FF0066Everything that Paul Shinaku did";
	mes "will sooner or later";
	mes "Bring about my downfall...^000000";
	mes "^CC3300Clangggggggggggg!!^000000";
	set event_amatsu,6;
	close;
Lfail:
	mes "[...]";
	mes "^FF0066Clang Clannng! Haha! Clang Clannng! Hahahaha!";
	mes "How dare you, wanting to throw me out!";
	mes "Get out of here!! Clang Clannng!^000000";
	next;
	warp "amatsu",167,197;
	end;
LStart3:
	mes "[Ishida Sauk]";
	mes "...*Sigh* Where from young man...?";
	mes "Did you get rid of the fox?";
	mes "Somehow I feel so tired, *sigh*...";
	next;
	mes "[Ishida Sauk]";
	mes "Thank you. Coming from another place";
	mes "and still has to endure through this.";
	mes "Very sorry... Sorry...";
	next;
	mes "[Ishida Sauk]";
	mes "I need to find my son.";
	mes "Tell him that I got rid of the fox...";
	mes "Thank you.";
	next;
	mes "[Ishida Sauk]";
	mes "Now I am getting very tired.";
	mes "I need to rest now, young man.....";
	mes "Go find my son...";
	close;
LStart4:
	mes "[Ishida Sauk]";
	mes "Oh, You are the you man who";
	mes "got rid of the fox... welcome.";
	mes "Sit here a while if you can...";
	next;
	mes "[Ishida Sauk]";
	mes "To be possessed by that fox...";
	mes "It is all my own fault...";
	mes "I didn't teach my child properly... *sigh*";
	mes "He was a good kid when he was small.";
	mes "It's all because I wasn't strict enough...";
	next;
	mes "[Ishida Sauk]";
	mes "Originally this town was small.";
	mes "Without a castle of this size either.";
	mes "But, my son got some zeny somehow";
	mes "and just start bringing them to me.";
	mes "Don't know what he did to get this zeny.";
	mes "And has to hide the truth from even me...";
	next;
	mes "[Ishida Sauk]";
	mes "Then starting building on the castle and town,";
	mes "and treated the townspeople fairly and nicely...";
	mes "If that was all, then there will be no problem.";
	mes "The problem came after he did some strange things...";
	next;
	mes "[Ishida Sauk]";
	mes "Yea, he angered the gods";
	mes "learning some weird spells somewhere.";
	mes "And started doing experimenting,";
	mes "Capturing the monsters,";
	mes "Doing bad things...";
	next;
	mes "[Ishida Sauk]";
	mes "And now, the monsters";
	mes "started to live in Amatsu...";
	mes "The gods became so angry even ";
	mes "the monks from the shrine";
	mes "don't know what to do.....";
	next;
	mes "[Ishida Sauk]";
	mes "They punished me as well...";
	mes "and sent a fox here, ";
	mes "hoping to give a warning,";
	mes "but my son didn't stop.";
	next;
	mes "[Ishida Sauk]";
	mes "If possible please stop my son.";
	mes "I am old and almost dead.";
	mes "I don't know what to do either...";
	mes "Please guard this peaceful town.";
	mes "I don't know what my son is smoking";
	mes "doing that kind of stuff...";
	close;
}
//=====================================================================
ama_in02,170,62,4	script	Soldier#02	767,{
	mes "[Kyro]";
	mes "My name is Kyro. In this town";
	mes "I handle all the administrative work.";
	mes "What type of service do you need?";
	next;
	menu "Please give me a pass",-,"I want to live here",L2,"Nothing",L3;

	if (event_amatsu == 7) goto L1_1;
		mes "[Kyro]";
		mes "The master said that the guests from the continent";
		mes "can move about freely,";
		mes "Without any";
		mes "permits or passes.";
		close;
L1_1:
	if (countitem(7160) == 0) goto L1_2;
		mes "[Kyro]";
		mes "I have already given you a pass.";
		close;
L1_2:
		mes "[Kyro]";
		mes "Did you lose the pass?";
		mes "If you want another pass";
		mes "you need to pay 10,000 zeny for registration fees.";
		next;
		menu "Get the pass",L1_2_1,"Maybe next time",-;
			mes "No problem!";
			mes "If you need anything please come talk to me again!";
			close;
L1_2_1:
		if (Zeny < 10000) goto LError;
		set Zeny,Zeny-10000;
		getitem 7160,1; //Feudal Lord Permit
		mes "[Kyro]";
		mes "Come, this is it.";
		mes "Please be careful and don't lose it again.";
		close;
LError:
		mes "[Kyro]";
		mes "You don't have enough zeny!";
		close;
L2:
		mes "[Kyro]";
		mes "This will be difficult, you can";
		mes "freely move around, but the master";
		mes "hasn't considered anything about immigration.";
		mes "But, you can stay as long as you want";
		close;
L3:
		mes "[Kyro]";
		mes "Then that's it for now...";
		mes "If there's anything else just tell me.";
		close;

}

//=====================================================================
ama_in02,115,177,7	script	Juro	767,{
	mes "[Juro]";
	mes "What are you here for?";
	mes "There is nothing much over here.";
	next;
	menu "Oh, really",-,"Please open the door for me",L2;

		mes "[Juro]";
		mes "The town has much more stuff.";
		mes "Have a wonderful time...";
		close;
L2:
	if (event_amatsu != 7) goto Lnoflag;
	if (countitem(7160) < 1) goto Llost;
		mes "[Juro]";
		mes "You already got the pass...";
		mes "Do you want to go in directly? Or";
		mes "Do you want me to explain first...?";
		next;
		menu "Direct access",-,"Listen to explanation",L2_2;

			mes "[Juro]";
			mes "Then, I will open the door for you.";
			mes "Please take care...";
			next;
			warp "ama_dun01",229,10;
			end;
L2_2:
			mes "[Juro]";
			mes "The inner space seems to be ";
			mes "protected by special spells.";
			mes "Those who wander in carelessly,";
			mes "become lost and will be assaulted";
			mes "mysteriously and die.";
			next;
			mes "[Juro]";
			mes "What I can tell you";
			mes "isn't all that much.";
			mes "I have not been inside.";
			mes "It's a mysterious place, its only proof is";
			mes "of existence is from the";
			mes "survivors that ventured inside";
			next;
			mes "[Juro]";
			mes "First of all.....";
			mes "'Don't believe in what you see.'";
			next;
			mes "[Juro]";
			mes "Second of all.....";
			mes "About the spells, they have their own rules.";
			mes "Everything has its own purpose,";
			mes "including the spells.";
			mes "Will you find some";
			mes "answers?";
			next;
			mes "[Juro]";
			mes "Then, I'll open the door for you.";
			mes "Please be careful...";
			next;
			warp "ama_dun01",229,10;
			end;
Llost:
		mes "[Juro]";
		mes "You don't have the pass";
		mes "so I cannot open the gate for you.";
		mes "Please understand.";
		close;
Lnoflag:
		mes "[Juro]";
		mes "What door are you talking about?";
		mes "In a place like this there won't";
		mes "be any doors as far as I know.";
		mes "You might have been mistaken.";
		next;
		mes "[Juro]";
		mes "There are more to see in town.";
		mes "I hope you have a good time...";
		close;
}
ama_dun01,229,7,0	script	Soldier#08	767,{
	mes "[Juro]";
	mes "Ready to leave?";
	next;
	menu "Leave",-,"Wait a little more",L1;
		mes "[Juro]";
		mes "Gogo!!";
		next;
		warp "ama_in02",119,181;
		end;
L1:
		mes "[Juro]";
		mes "Take care of yourself!";
		close;
}

//=====================================================================
ama_in02,200,176,4	script	Castle Owner	768,{
	if (event_amatsu == 1) goto LStart2;
	if ((event_amatsu >= 2) && (event_amatsu <=5)) goto LStart3;
	if (event_amatsu == 6) goto LStart4;
	if (event_amatsu == 7) goto LStart5;
	mes "[Ishida Yoshinake]";
	mes "What! An outsider?";
	mes "What do you need me for?? If it's nothing important";
	mes "Talk to you later...!";
	next;
	mes "[Ishida Yoshinake]";
	mes "Please leave! No matter who you are!!";
	mes "Right now I am in a VERY bad mood!";
	close;
LStart2:
	mes "[Ishida Yoshinaku]";
	mes "What! A visitor...? Oh, sorry";
	mes "But today I am not in the mood";
	mes "of seeing a visitor!";
	next;
	menu "I heard your mother is sick...",L1,"What a beautiful castle",L2,"Who are you?",L3;
L1:
	mes "[Ishida Yoshinaku]";
	mes "Oh... You are an expert pathologist?";
	mes "Oh yea, if you are a foreign expert";
	mes "I should be able to trust you...";
	mes "I guess...";
	next;
	mes "[Ishida Yoshinaku]";
	mes "Welcome, as you know";
	mes "I am the owner of the East Lake Castle";
	mes "My name is Ishida Yoshinaku,";
	mes "Nice to meet you.";
	next;
	mes "[Ishida Yoshinaku]";
	mes "To put it simple: my mother";
	mes "is not very healthy,";
	mes "of course you are here because of it";
	mes "Can you cure my ailing mother??";
	next;
	mes "[Ishida Yoshinaku]";
	mes "So many famous and talented";
	mes "Doctors has visited her already,";
	mes "But not only did they not cure her!!";
	mes "They worsened her condition!!";
	mes "so I kept feeling disappointed";
	next;
	mes "[Ishida Yoshinaku]";
	mes "You, being a foreign expert,";
	mes "may cure my mother's sickness!";
	mes "if you do, I will give you lots of zeny and rewards...";
	next;
	mes "[Ishida Yoshinaku]";
	mes "Please help her,";
	mes "my mother lives in the mansion outside of the castle,";
	mes "After you cure her";
	mes "Come see me again";
	set event_amatsu,2;
	close;
L2:
	mes "[Ishida Yoshinaku]";
	mes "Yes! Beautiful indeed! So what";
	mes "Do you want to do! Leave when you get";
	mes "bored of it! Man!";
	next;
	mes "[Ishida Yoshinaku]";
	mes "At a pressing time like this... *Sobs*...";
	mes "Leave when you become satisfied or bored!";
	close;
L3:
	mes "[Ishida Yoshinaku]";
	mes "...Talking about me? You don't know? Eh?";
	mes "I am this castle's master!";
	mes "Go ask around the soldiers outside";
	mes "If you are not sure!";
	next;
	mes "[if you are not sure]";
	mes "At a pressing time like this... *Sobs*...";
	mes "Leave when you become satisfied or bored!";
	close;
LStart3:
	mes "[Ishida Yushinaku]";
	mes "How is my mother?";
	mes "If you know the name of the sickness....";
	mes "Please tell me immediately...";
	mes "Argh... So worried!";
	mes "I can't sleep at night any longer!";
	next;
	mes "[Ishida Yushinaku]";
	mes "You are from the other continents,";
	mes "so you must know....";
	mes "now you are the only one I can trust";
	close;
LStart4:
	mes "[Ishida Yushinaku]";
	mes "WoW, you are great, I heard";
	mes "My mother is getting better already,";
	mes "Anyway, what sickness was it?";
	next;
	mes "[Ishida Yushinaku]";
	mes "Fox? The fox is the reason? ho...";
	mes "So it's not a sickness after all...!!";
	mes "Why didn't I think of it earlier!!!";
	next;
	mes "[Ishida Yushinaku]";
	mes "Damn fox, after it ran away,";
	mes "it tried to revenge like this...";
	mes "But now there is no other";
	mes "Way... hahaha! Hahahaha!";
	next;
	mes "[Ishida Yushinaku]";
	mes "Um, hmm, umm...";
	next;
	mes "[Ishida Yushinaku]";
	mes "Anyway, Thanks for your help!";
	mes "I think my mother will return to normal now...";
	mes "I want to show you my gratitude...";
	mes "What to do...";
	next;
	mes "[Ishida Yushinaku]";
	mes "Alright, I will give you this pass.";
	mes "As long as you have this pass,";
	mes "you can get into ANYWHERE";
	mes "In this town";
	next;
	set event_amatsu,7;
	getitem 7160,1; //Feudal Lord Permit
	mes "[Ishida Yushinaku]";
	mes "Although it's not such a great gift, but";
	mes "I believe you will have use for it someday...";
	mes "talk to 'Juro' For the details";
	close;
LStart5:
	mes "[Ishida Yushinaku]";
	mes "Hey... I hope you have a";
	mes "good time in Amatsu.....";
	mes "We always welcome the foreigners!";
	close;
}

ama_in01,180,173,2	script	Fox Mask	762,{
	if (event_amatsu == 4) goto LStart2;
	if (event_amatsu == 5) goto LStart3;
	mes "[Takikuwi]";
	mes "Hiya, outsider, this";
	mes "Shrine is left by a monk a long time ago.";
	mes "Sometimes I come here to play";
	mes "along with my friend Tokari";
	next;
	mes "[Takikuwi]";
	mes "If you are here to hide from the monsters,";
	mes "please do come in, no monsters";
	mes "can ever come in here!";
	mes "You can always take a short rest in here!";
	close;
LStart2:
	mes "[Takikuwi]";
	mes "Hiya, outsider, here to find me?";
	mes "Because of the fox bothering you?";
	mes "From your expression You seem to";
	mes "have had quite a bit of trouble";
	next;
	mes "[Takikuwi]";
	mes "Although usually the head monk";
	mes "should come to help himself, this shrine";
	mes "Has been deserted for a long time";
	next;
	mes "[Takikuwi]";
	mes "It is very hard to get rid of a fox in a person's body";
	mes "If there's alcohol and ramen noodle,";
	mes "It might be a little easier,";
	mes "But they are hard to find!";
	next;
	mes "[Takikuwi]";
	mes "Good thing I know quite a bit";
	mes "about the fox, I'll tell you";
	mes "some words of advice, although foxes";
	mes "are very tricky, and although they like to";
	mes "make fun of humans... but it is seldom";
	mes "for a fox to display hatred!";
	next;
	mes "[Takikuwi]";
	mes "In another word, if there is hatred";
	mes "human also did something wrong!!";
	mes "Which will hurt self,";
	mes "And sometimes unlucky things happen";
	mes "and to friend and family as well!";
	next;
	mes "[Takikuwi]";
	mes "Anyway, I've heard that when";
	mes "there's a strong animal then a fox will chased,";
	mes "away from the human.";
	mes "So try hard, and try summoning the animal spirit!";
	next;
	menu "Haaaa!!",-;
	mes "[Takikuwi]";
	mes "Very good, just repeating it will";
	mes "show the fox a strong spirit,";
	mes "and show results, but the best thing is";
	mes "to find out why the fox will enter the";
	mes "person's body, but if you do this";
	mes "it should help, more or less";
	set event_amatsu,5;
	close;
LStart3:
	mes "[Takikuwi]";
	mes "Don't forget, when you try summoning";
	mes "you must think about!";
	mes "A monster that is stronger than a fox";
	mes "or it would just be a futile effort!";
	mes "Remember....... Stronger than a fox....";
	close;
}