path: root/npc/merchants/milk_trader.txt

//===== eAthena Script =======================================
//= Milk Trader
//===== By: ==================================================
//= kobra_k88
//===== Current Version: =====================================
//= 1.2a
//===== Compatible With: =====================================
//= eAthena 7.15 +
//===== Description: =========================================
//= trades bottles for milk
//===== Additional Comments: =================================
//= Fully working
//= 1.1 Negative input bug fixed [Lupus]
//= 1.2 Raised the price to close zeny exploit [Lupus]
//= 1.2a Switched to Lupus's "loopless" technique.[kobra_k88]
//============================================================


// Milk Trader -------------------------------------------------------------
prontera,71,131,7	script	Milk Trader	86,{
	mes "[Milk Trader]";
	mes "If you bring me an empty bottle and 20 Zeny, I will exchange it for 1 bottle of milk.";
	next;
	menu "-Exchange as many as possible.",M_0, "-Let me set the amount.",M_1, "-Cancel",M_End;

	M_0:
		set @amount, 1000;
		if(zeny/20 < @amount) set @amount, zeny/20;
		if(countitem(713) < @amount) set @amount, countitem(713);
		if(@amount > 0) goto L_Milk;
		mes "[Milk Trader]";
		mes "..... Are you trying to make a fool of me.... ?";
		close;

	M_1:
		input @amount;
		if(@amount < 1 || @amount > 1000) goto M_End;
		if(countitem(713) < @amount) goto L_NoBottle;
		if(zeny < (@amount*20)) goto L_NoZeny;

	L_Milk:
		set zeny, zeny - (@amount*20);
		delitem 713, @amount;
		getitem 519, @amount;

	M_End:
		mes "[Milk Trader]";
		mes "Come back anytime.";
		close;

	L_NoBottle:
		mes "[Milk Trader]";
		mes "Ok, empty bottle please! Empty Bottle!!";
		mes "... Aww.. you don't have enough...?";
		close;

	L_NoZeny:
		mes "[Milk Trader]";
		mes "You need more zeny.";
		close;
}