1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
|
function|script|SelimDebug
{
set @w, 0;
mes "[Selim Debug]";
menu
"Debug item array.", L_DebugArrayExplain,
"Exit debug.", L_Return;
L_DebugArrayExplain:
mes "[How it works]";
mes "Click on the link to verify that it is the red variation of the item.";
mes "If, for example, you see [Skirt] then when you click on it you should see Red Skirt.";
next;
goto L_DebugArray;
L_DebugArray:
mes "[@@" + @items_new[@w] + "|" + @item_names$[@w] + "@@]";
set @w, @w + 1;
if(@w >= getarraysize(@items_new)) goto L_Return;
menu
"Next.", L_DebugArray,
"Exit debug.", L_Return;
L_Return:
return;
}
009-2,32,104,0|script|Selim|326
{
setarray @all_colours$, "red", "green", "dark blue", "yellow", "light blue", "pink", "black", "orange", "purple", "dark green";
cleararray @items$, "", getarraysize(@items$);
cleararray @item_names$, "", getarraysize(@item_names$);
cleararray @items_new, "", getarraysize(@items_new);
setarray @items_new, 2050, 2250, 2060, 2070, 2110, 2180, 2100, 2170, 2090, 2120, 2080, 2140, 2130, 2150, 2160, 2190, 2200, 2210, 2230, 2240, 5131, 2220, 5000, 5011, 5022, 5033, 5044, 5055, 5066, 5077, 5088, 5099;
setarray @items$, "CottonShirt", "CottonCloth", "VNeckSweater", "Turtleneck", "CottonShorts", "CottonTrousers", "CottonSkirt", "Miniskirt", "TankTop", "ShortTankTop", "SilkRobe", "CottonHeadband", "DesertHat", "CottonBoots", "CottonGloves", "RabbitEars", "WizardHat", "BowlerHat", "BowlerHatBrown", "FineDress", "ContributorShirt", "SorcererRobeRed", "SorcererRobeGreen", "SorcererRobeDarkBlue", "SorcererRobeYellow", "SorcererRobeLightBlue", "SorcererRobePink", "SorcererRobeBlack", "SorcererRobeOrange", "SorcererRobePurple", "SorcererRobeDarkGreen", "SorcererRobeWhite";
setarray @item_names$, "Cotton Shirt", "Cotton Cloth", "V-Neck Sweater", "Turtleneck Sweater", "Cotton Shorts", "Cotton Trousers", "Cotton Skirt", "Miniskirt", "Tank Top", "Short Tank Top", "Silk Robe", "Cotton Headband", "Desert Hat", "Cotton Boots", "Cotton Gloves", "Rabbit Ears", "Wizard Hat", "Bowler Hat", "Bowler Hat (brown)", "Fine Dress", "Contributor Shirt", "Red lined Sorcerer Robe", "Green lined Sorcerer Robe", "Dark Blue lined Sorcerer Robe", "Yellow lined Sorcerer Robe", "Light Blue lined Sorcerer Robe", "Pink lined Sorcerer Robe", "Black lined Sorcerer Robe", "Orange lined Sorcerer Robe", "Purple lined Sorcerer Robe", "Dark Green lined Sorcerer Robe", "White lined Sorcerer Robe";
if ((getgmlevel() >= 40 || debug) && (getequipid(equip_head) == 647 || getequipid(equip_head) == 725)) goto L_Debug;
goto L_Main;
L_Debug:
callfunc "SelimDebug";
close;
L_Main:
mes "[Selim]";
mes "\"Greetings, fair traveler. With what may I help you?\"";
menu
"Greetings, are you the store merchant?", L_ask_selim,
"But what are dyes and what purpose do they serve?", L_ask_dye,
"Can you dye something for me?", L_clothes_choice,
"Can you also remove color from clothing?", L_ask_bleach,
"About these sorcerer robes...", L_asksorcererrobe,
"Never mind.", L_Close;
L_ask_bleach:
mes "[Selim]";
mes "\"I'm afraid no.";
mes "For that, you would need to visit Candide in the Tulimshar marketplace.\"";
goto L_Main;
L_ask_selim:
mes "[Selim]";
mes "\"That is an honest mistake you have made.";
mes "However I am not the merchant, but rather a Master Dyer here to serve the good people of this town.";
mes "I dye things, upon request.\"";
menu
"But what are dyes and where can I get them?", L_ask_dye,
"Can you dye something for me?", L_clothes_choice,
"Can you also remove color from clothing?", L_ask_bleach,
"Good bye.", L_Close;
L_ask_dye:
mes "[Selim]";
mes "\"Dyes are special liquids used to add color to clothing. If you want me to dye something for you you will have to bring me some dye first.";
mes "Those behind me are nearly empty and won't last for your item.\"";
menu
"What do you mean, `bring you dye'?", L_explain_dye,
"Where would I get dye?", L_explain_dye,
"Good bye.", L_Close;
L_clothes_choice:
mes "[Selim]";
mes "\"What can I dye for you today?\"";
next;
callfunc "DynamicItemMenu$";
set @default_choice$, "";
set @item_del$, @item$;
set @item_new, @items_new[@index];
set @name$, @item_names$[@index];
cleararray @items$, "", getarraysize(@items$);
cleararray @item_names$, "", getarraysize(@item_names$);
if(@item$ == "") goto L_Close;
goto L_picked_item;
L_asksorcererrobe:
mes "[Selim]";
mes "\"Yes?\"";
next;
menu
"Do you think you can dye that line to a different color?", L_Next1;
L_Next1:
mes "[Selim]";
mes "\"Hum, I fear I can't do that. The area is too small and I can operate only on large ones.";
mes "But with the appropriate materials, maybe a talented tailor can make the change.\"";
next;
menu
"Oh, I see!", L_Next;
L_Next:
mes "[Selim]";
mes "\"Of course I can help you by dyeing the materials your tailor will want.";
mes "All I need is a piece of Cotton Cloth.\"";
set @item_del$, "CottonCloth";
set @item_new, 2250;
menu
"Sure. Here is one.", L_picked_item,
"I have to go pick that.", L_Close;
L_picked_item:
if (countitem(@item_del$) == 0) goto L_havenone;
goto L_colour;
L_colour:
mes "[Selim]";
mes "\"Excellent. Now, what color do you want?\"";
next;
setarray @items$, "RedDye", "GreenDye", "DarkBlueDye", "YellowDye", "LightBlueDye", "PinkDye", "BlackDye", "OrangeDye", "PurpleDye", "DarkGreenDye";
setarray @item_names$, "red", "green", "dark blue", "yellow", "light blue", "pink", "black", "orange", "purple", "dark green";
set @default_choice$, "I have no dye.";
callfunc "DynamicItemMenu$";
cleararray @items$, "", getarraysize(@items$);
cleararray @item_names$, "", getarraysize(@item_names$);
set @default_choice$, "";
if (@item$ == "") goto L_no_dye;
set @colour, @index;
set @vial, 690 + @colour;
goto L_finish;
L_no_dye:
mes "[Selim]";
mes "\"I would love to dye your " + @name$ + " for you, but you will have to bring me some dye first.";
mes "Those behind me are nearly empty and won't last for your item.\"";
next;
menu
"I wanted to dye a different item anyway.", L_clothes_choice,
"What do you mean, `bring you dye'?", L_explain_dye,
"Where would I get dye?", L_explain_dye,
"Never mind.", L_Close;
L_explain_dye:
if (QUEST_clothdyer_knowsdye < 1)
set QUEST_clothdyer_knowsdye, 1;
mes "[Selim]";
mes "\"Well, dye is very expensive, and since I don't charge adventurers anything, I can't give you any for free.";
mes "But most alchemists can make dye; perhaps you can find one around here.\"";
goto L_Close;
L_finish:
delitem @vial, 1;
delitem @item_del$, 1;
getitem @item_new + @colour, 1;
mes "[Selim]";
mes "\"Here's your " + @all_colours$[@colour] + " " + @name$ + "! Please let dry for a minute.\"";
goto L_Close;
L_havenone:
mes "[Selim]";
mes "\"You don't have any uncolored " + @name$ + "? That's unfortunate.";
mes "Would you like to dye something else?\"";
next;
goto L_clothes_choice;
L_Close:
mes "\"Farewell and good luck in your journeys!\"";
close2;
emotion EMOTE_WINK;
end;
}
|
