1 files changed, 54 insertions, 0 deletions
diff --git a/world/map/npc/magic/level2-summon-pinkie.txt b/world/map/npc/magic/level2-summon-pinkie.txt
new file mode 100644
index 00000000..b91ec1d9
--- /dev/null
+++ b/world/map/npc/magic/level2-summon-pinkie.txt
@@ -0,0 +1,54 @@
+-|script|smpinkie|32767
+{
+    end;
+
+OnCast:
+    if(call("magic_checks")) end; 
+    if (Sp < 35) end;
+    if (getskilllv(SKILL_MAGIC) < .level) end;
+    if (getskilllv(.school) < .level) end;
+    if (countitem("PinkAntenna") < 1 || countitem("Root") < 1) end;
+    delitem "PinkAntenna", 1;
+    delitem "Root", 1;
+    set @_M_BLOCK, 1; // block casting, until the timer clears it
+    addtimer 20000, "Magic Timer::OnClear"; // set the new debuff
+    callfunc "adjust_spellpower";
+    set Sp, Sp - 35;
+    misceffect FX_MAGIC_BLUE, strcharinfo(0);
+    misceffect FX_PENTAGRAM_BUILDUP, strcharinfo(0);
+    callfunc "magic_exp";
+    set .@puppet$, "#"+strnpcinfo(0)+"#"+BL_ID;
+    set .@puppet, puppet(getmap(), POS_X, POS_Y, .@puppet$, 127);
+    set .count, (@spellpower/120)+1, .@puppet;
+    set .master, BL_ID, .@puppet;
+    set .lifetime, @spellpower*150, .@puppet;
+    addnpctimer 5000-(@spellpower*9), .@puppet$+"::OnSummon";
+    addnpctimer 6000, .@puppet$+"::OnDestroy";
+    end;
+
+OnSummon:
+    specialeffect FX_PENTAGRAM_BURST;
+    set .@i, 0;
+    set .@x, getnpcx();
+    set .@y, getnpcy();
+    set .@map$, strnpcinfo(3);
+    callsub S_SummonAll;
+    end;
+
+OnDestroy:
+    destroy;
+
+S_SummonAll:
+    summon .@map$, rand(.@x-2,.@x+2), rand(.@y-2,.@y+2), .master, 1018, 2, .lifetime;
+    set .@i, .@i + 1;
+    if (.@i < .count) goto S_SummonAll;
+    return;
+
+OnInit:
+    set .school, SKILL_MAGIC_ASTRAL;
+    set .invocation$, chr(MAGIC_SYMBOL) + "kalgina"; // used in npcs that refer to this spell
+    void call("magic_register", "OnCast");
+    set .level, 2;
+    set .exp_gain, 2;
+    end;
+}