summaryrefslogtreecommitdiff
path: root/npc/008-1
diff options
context:
space:
mode:
Diffstat (limited to 'npc/008-1')
-rw-r--r--npc/008-1/_import.txt10
-rw-r--r--npc/008-1/_mobs.txt62
-rw-r--r--npc/008-1/_warps.txt11
-rw-r--r--npc/008-1/andra.txt24
-rw-r--r--npc/008-1/diryn.txt84
-rw-r--r--npc/008-1/dock.txt6
-rw-r--r--npc/008-1/george.txt25
-rw-r--r--npc/008-1/hinnak.txt263
8 files changed, 485 insertions, 0 deletions
diff --git a/npc/008-1/_import.txt b/npc/008-1/_import.txt
new file mode 100644
index 00000000..f517bb23
--- /dev/null
+++ b/npc/008-1/_import.txt
@@ -0,0 +1,10 @@
+// Map 008-1: Hurnscald outskirts
+// This file is generated automatically. All manually changes will be removed when running the Converter.
+map: 008-1.gat
+npc: npc/008-1/_mobs.txt
+npc: npc/008-1/_warps.txt
+npc: npc/008-1/andra.txt
+npc: npc/008-1/diryn.txt
+npc: npc/008-1/dock.txt
+npc: npc/008-1/george.txt
+npc: npc/008-1/hinnak.txt
diff --git a/npc/008-1/_mobs.txt b/npc/008-1/_mobs.txt
new file mode 100644
index 00000000..4aaccfdf
--- /dev/null
+++ b/npc/008-1/_mobs.txt
@@ -0,0 +1,62 @@
+// This file is generated automatically. All manually changes will be removed when running the Converter.
+// Hurnscald outskirts mobs
+
+008-1.gat,0,0,0,0 monster PinkFlower 1014,10,20,0,Mob008-1::On1014
+008-1.gat,0,0,0,0 monster Pinkie 1018,18,20,0,Mob008-1::On1018
+008-1.gat,0,0,0,0 monster SpikyMushroom 1019,18,20,0,Mob008-1::On1019
+008-1.gat,0,0,0,0 monster Fluffy 1020,5,30,0,Mob008-1::On1020
+008-1.gat,0,0,0,0 monster Mauve 1029,2,270000,180000,Mob008-1::On1029
+008-1.gat,0,0,0,0 monster SilkWorm 1035,2,60000,30000,Mob008-1::On1035
+008-1.gat,0,0,0,0 monster Clover 1037,2,0,1000,Mob008-1::On1037
+008-1.gat,0,0,0,0 monster Squirrel 1038,10,30,20,Mob008-1::On1038
+008-1.gat,0,0,0,0 monster Butterfly 1055,10,30,20,Mob008-1::On1055
+
+
+008-1.gat,0,0,0 script Mob008-1 -1,{
+On1014:
+ set @mobID, 1014;
+ callfunc "MobPoints";
+ break;
+
+On1018:
+ set @mobID, 1018;
+ callfunc "MobPoints";
+ break;
+
+On1019:
+ set @mobID, 1019;
+ callfunc "MobPoints";
+ break;
+
+On1020:
+ set @mobID, 1020;
+ callfunc "MobPoints";
+ break;
+
+On1029:
+ set @mobID, 1029;
+ callfunc "MobPoints";
+ break;
+
+On1035:
+ set @mobID, 1035;
+ callfunc "MobPoints";
+ break;
+
+On1037:
+ set @mobID, 1037;
+ callfunc "MobPoints";
+ break;
+
+On1038:
+ set @mobID, 1038;
+ callfunc "MobPoints";
+ break;
+
+On1055:
+ set @mobID, 1055;
+ callfunc "MobPoints";
+ break;
+
+ end;
+}
diff --git a/npc/008-1/_warps.txt b/npc/008-1/_warps.txt
new file mode 100644
index 00000000..8cc5b652
--- /dev/null
+++ b/npc/008-1/_warps.txt
@@ -0,0 +1,11 @@
+// This file is generated automatically. All manually changes will be removed when running the Converter.
+// Hurnscald outskirts warps
+
+008-1.gat,54,61 warp HurnscaldWestGate -1,1,009-1.gat,26,36
+008-1.gat,79,80 warp HurnscaldSouthGate 2,-1,009-1.gat,48,54
+008-1.gat,127,61 warp HurnscaldEastGate -1,0,009-1.gat,96,35
+008-1.gat,79,49 warp HurnscaldNorthGate 2,-1,009-1.gat,48,24
+008-1.gat,24,62 warp ToWoodland -1,2,011-1.gat,122,61
+008-1.gat,79,17 warp ToWoodlandMines 2,-1,018-1.gat,79,97
+008-1.gat,79,102 warp ToWoodland 2,-1,007-1.gat,68,23
+008-1.gat,132,101 warp ToWoodland 1,-1,007-1.gat,122,23
diff --git a/npc/008-1/andra.txt b/npc/008-1/andra.txt
new file mode 100644
index 00000000..e56cbbf5
--- /dev/null
+++ b/npc/008-1/andra.txt
@@ -0,0 +1,24 @@
+//
+
+008-1.gat,36,26,0 script Andra 201,{
+ mes "[Andra]";
+ mes "\"Hello, my name is Andra, what's yours?\"";
+ next;
+ input @name$;
+
+ mes "[Andra]";
+ mes "\"Hello, " + @name$ + "! What is your favorite number?\"";
+ next;
+ input @num;
+
+ if (@num == 5) goto L_Same;
+
+ mes "[Andra]";
+ mes "\"I don't like that one.\"";
+ close;
+
+L_Same:
+ mes "[Andra]";
+ mes "\"Mine too!\"";
+ close;
+}
diff --git a/npc/008-1/diryn.txt b/npc/008-1/diryn.txt
new file mode 100644
index 00000000..c5ab21a4
--- /dev/null
+++ b/npc/008-1/diryn.txt
@@ -0,0 +1,84 @@
+//This is a teleportation (warp) NPC. Its purpose is to offer expensive, fast trips throughout the world.
+
+008-1.gat,81,82,0 script Diryn the Traveler 103,{
+ mes "[Diryn]";
+ mes "\"Greetings. I am Diryn the Traveler, Assistant Councilor of Tulimshar and teleporter extraordinaire. Tulimshar is expanding our influence throughout the world, so I was sent here to aid all who are willing and able to take on the threats to our interests.\"";
+ next;
+ mes "\"The monsters of the world have grown out of control, harming people, trade and travel. Needless to say, Tulimshar is not happy with this problem. Our solution: Rally those powerful enough to combat the monster threat and send them to hot spots to challenge the monster threat head on. However, teleportation to these areas is not only extremely dangerous, but also highly expensive. Do you think you got what it takes?\"";
+ menu
+ "I sure do!", L_Diryn_Yes,
+ "No thank you", L_Diryn_No;
+ close;
+
+L_Diryn_Yes:
+ mes "[Diryn]";
+ mes "\"Excellent. I can send you to many places, but again, the fees are large. Where shall I send you?\"";
+ menu
+ "Druid Tree (1500 GP)", L_Diryn_Druid_Tree,
+ "Graveyard (1500 GP)", L_Diryn_Graveyard,
+ "Magic House (1000 GP)", L_Diryn_Magic_House,
+ "Terranite Cave (1500 GP)", L_Diryn_Terranite,
+ "Tulimshar Town Square (1000 GP)", L_Diryn_Tulimshar,
+ "Nivalis (1000 GP)", L_Diryn_Nivalis,
+ "Not Interested", L_Diryn_No;
+ close;
+
+L_Diryn_Druid_Tree:
+ if (zeny < 1500) goto L_NoMoney;
+ mes "[Diryn]";
+ mes "\"Be fearless!\"";
+ set zeny, zeny-1500;
+ warp "005-1.gat",73,36;
+ close;
+
+L_Diryn_Graveyard:
+ if (zeny < 1500) goto L_NoMoney;
+ mes "[Diryn]";
+ mes "\"Be fearless!\"";
+ set zeny, zeny-1500;
+ warp "027-1.gat",70,85;
+ close;
+
+L_Diryn_Magic_House:
+ if (zeny < 1000) goto L_NoMoney;
+ mes "[Diryn]";
+ mes "\"Be fearless!\"";
+ set zeny, zeny-1000;
+ warp "013-1.gat",45,92;
+ close;
+
+L_Diryn_Terranite:
+ if (zeny < 1500) goto L_NoMoney;
+ mes "[Diryn]";
+ mes "\"Be fearless!\"";
+ set zeny, zeny-1500;
+ warp "012-3.gat",445,65;
+ close;
+
+L_Diryn_Tulimshar:
+ if (zeny < 1000) goto L_NoMoney;
+ mes "[Diryn]";
+ mes "\"Be fearless!\"";
+ set zeny, zeny-1000;
+ warp "001-1.gat",44,70;
+ close;
+
+L_Diryn_Nivalis:
+ if (zeny < 1000) goto L_NoMoney;
+ mes "[Diryn]";
+ mes "\"Be fearless!\"";
+ set zeny, zeny-1000;
+ warp "020-1.gat",71,100;
+ close;
+
+L_Diryn_No:
+ mes "[Diryn]";
+ mes "\"Perhaps some day you will have the courage to help us. Enjoy your stay here in Hurnscald.\"";
+ close;
+
+L_NoMoney:
+ mes "[Diryn]";
+ mes "\"Sorry, you don't have enough. Maybe next time.\"";
+ close;
+
+}
diff --git a/npc/008-1/dock.txt b/npc/008-1/dock.txt
new file mode 100644
index 00000000..46aa5a92
--- /dev/null
+++ b/npc/008-1/dock.txt
@@ -0,0 +1,6 @@
+// The ferry dock
+
+008-1.gat,140,64,0 script #hurnscalddock 127,2,1,{
+ set @loc, DOCK_hurnscald;
+ callfunc "Ferry";
+}
diff --git a/npc/008-1/george.txt b/npc/008-1/george.txt
new file mode 100644
index 00000000..429fdbca
--- /dev/null
+++ b/npc/008-1/george.txt
@@ -0,0 +1,25 @@
+//
+
+008-1.gat,136,36,0 script George 138,{
+ if (getequipid(equip_head) == 617) goto L_Pirate;
+ if (getequipid(equip_head) == 622) goto L_Bandana;
+ if (getequipid(equip_head) == 621) goto L_EyePatch;
+ mes "[George the Pirate]";
+ mes "\"Arrrrh! 'Tis some kind of treasure map!\"";
+ close;
+
+L_Pirate:
+ mes "[George the Pirate]";
+ mes "\"Arrrrh! Ye be wearing a pirate's hat!\"";
+ close;
+
+L_Bandana:
+ mes "[George the Pirate]";
+ mes "\"Arrrrh! Ye remind me of my old first mate!\"";
+ close;
+
+L_EyePatch:
+ mes "[George the Pirate]";
+ mes "\"Arrrrh! Looks like ye lost an eye there!\"";
+ close;
+}
diff --git a/npc/008-1/hinnak.txt b/npc/008-1/hinnak.txt
new file mode 100644
index 00000000..4d17310c
--- /dev/null
+++ b/npc/008-1/hinnak.txt
@@ -0,0 +1,263 @@
+//#################################################################################
+//# #
+//# this script file contains the npc scripts for the quest to obtain a scythe. #
+//# #
+//# Needed: 10 Pink Antenna #
+//# #
+//# Reward: Scythe #
+//# #
+//#################################################################################
+
+//Farmer
+
+008-1.gat,101,30,0 script Hinnak 142, {
+ if (Inspector == 10) goto L_NohMask;
+
+L_No_NohMask:
+ if (QUEST_Scythe_state == 1) goto L_Exchange;
+ if (QUEST_Scythe_state == 2) goto L_ThanksAgain;
+ if (getequipid(equip_head) == 751) goto L_Intro_Hat;
+
+ mes "[Farmer Hinnak]";
+ mes "\"Argh! I hate them! I @#$% hate them! I @#$% hate these @#$% pinkies!\"";
+ next;
+
+ menu
+ "You need some anger control therapy.", -,
+ "Why do you hate them?", L_Reason;
+ close;
+
+L_Intro_Hat:
+ mes "The farmer lunges at you with a farming implement.";
+ next;
+ heal -50, 0;
+
+ menu
+ "I'm out of here.", -,
+ "Whoa, what are you doing?", L_Intro_Hat_Explain;
+ close;
+
+L_Intro_Hat_Explain:
+ mes "[Farmer Hinnak]";
+ mes "\"Sorry, you look like a pinkie. They've been destroying my fields, and I guess I got a bit worked up.\"";
+ next;
+ goto L_Help;
+
+L_Reason:
+ mes "[Farmer Hinnak]";
+ mes "\"These @#$% beasts are jumping around in my fields destroying all my harvest.";
+ mes "But they are too fast. I can't catch them.\"";
+ next;
+
+ menu
+ "Want me to help you?", L_Help,
+ "Well, life ain't fair.", -;
+ close;
+
+L_Help:
+ mes "[Farmer Hinnak]";
+ mes "\"Yes, you look quite fast. Maybe you can catch some of them. That will pay them a lesson.";
+ mes "Slay some of them and bring me 10 of their antennae.\"";
+ set QUEST_Scythe_state, 1;
+ next;
+
+ menu
+ "Sure, I'm on my way", -,
+ "How much is this worth to you?", L_Reward;
+ close;
+
+L_Reward:
+ mes "[Farmer Hinnak]";
+ mes "\"Well, I can't offer you much. But I got an old scythe laying around. Maybe you can use it as a weapon.\"";
+ close;
+
+L_Exchange:
+ if (getequipid(equip_head) != 751) goto L_Exchange_Start;
+ mes "The farmer glares at your hat.";
+ next;
+
+L_Exchange_Start:
+ mes "[Farmer Hinnak]";
+ mes "\"Have you got the 10 antennae?\"";
+ next;
+
+ menu
+ "Not yet, but I am working on it.", -,
+ "Sure, here they are!", L_Exchange_Exchange;
+ close;
+
+L_Exchange_Exchange:
+ if (countitem("PinkAntenna") < 10) goto L_Exchange_Notenough;
+ getinventorylist;
+ if (@inventorylist_count == 100 && countitem("PinkAntenna") > 10) goto L_Exchange_TooMany;
+ delitem "PinkAntenna", 10;
+ getitem "Scythe", 1;
+ set QUEST_Scythe_state, 2;
+ mes "[Farmer Hinnak]";
+ mes "\"Thank you very much. I've got something for you. My old scythe. Maybe you can use it as a weapon. It is a bit cumbersome but its strikes are deadly.\"";
+ close;
+
+L_Exchange_Notenough:
+ mes "[Farmer Hinnak]";
+ mes "\"It doesn't look like you do.\"";
+ close;
+
+L_Exchange_TooMany:
+ mes "[Farmer Hinnak]";
+ mes "\"Looks like you don't have room for this. Come back later to receive your reward. Hold on to the antennea until then.\"";
+ close;
+
+L_ThanksAgain:
+ if (getequipid(equip_head) == 751) goto L_ThanksHat;
+ mes "[Farmer Hinnak]";
+ mes "\"Good to see you again, and thanks again for helping me with the pinkies!\"";
+ next;
+ goto L_ThanksMenu;
+
+L_ThanksHat:
+ mes "[Farmer Hinnak]";
+ mes "\"That better be a trophy on your head.\"";
+ menu
+ "It is.", -;
+
+ mes "[Farmer Hinnak]";
+ mes "\"Good then. Thanks for your help with the pinkies.\"";
+
+L_ThanksMenu:
+ menu
+ "Sure, any time!", -,
+ "Anything else you want me to do?", -,
+ "You're welcome. Bye!", L_Bye;
+
+ mes "[Farmer Hinnak]";
+ mes "\"Actually, it's been a long day. If it's no trouble, could you get me a beer?\"";
+ next;
+
+ menu
+ "Here you are.", L_GiveBeer,
+ "Sure, I'll go get one. Bye!", L_Bye,
+ "You shouldn't drink while working!", -;
+
+ mes "[Farmer Hinnak]";
+ mes "\"Well, I'm done for the day, and I'm quite old enough to decide when I can have a beer, thank you!\"";
+ next;
+
+ menu
+ "Sorry... here you are.", L_GiveBeer,
+ "I don't have any.", L_NoBeer;
+
+L_GiveBeer:
+ if (countitem("Beer") < 1) goto L_NoBeer;
+ delitem "Beer", 1;
+ mes "[Farmer Hinnak]";
+ mes "Hinnak takes a sip.";
+ mes "\"Aaah! Nothing like a well-deserved beer after a long day of tending the crops!\"";
+ mes "\"Thanks, that was very kind of you!\"";
+ next;
+
+ mes "[Farmer Hinnak]";
+ mes "He takes another sip.";
+ mes "\"Thanks! You know, I had the strangest thing happen to me. I had this patch of ground that was really clumpy; lots of clay, you see.\"";
+ next;
+
+ mes "[Farmer Hinnak]";
+ mes "\"Right over there.\"";
+ mes "He points to a stretch of soft, raked ground.";
+ mes "\"Looks much better now, doesn't it? But how I got there is kind-a scary...\"";
+ next;
+
+ mes "[Farmer Hinnak]";
+ mes "\"I'd been trying to break it up for a while, but that kind of work is a pain. So my wife said that I should go and see the witch, just in case she knows something.\"";
+ next;
+
+ mes "[Farmer Hinnak]";
+ mes "\"And sure enough I ask the witch, and she has a look at it. 'Nothing I can do', she says, 'but I can ask a friend'.\"";
+ next;
+
+ mes "[Farmer Hinnak]";
+ mes "\"So the next day another witch shows up. Gorgeous woman, but when she looked at me, the scares went scuttling down my spine....\"";
+ mes "\"First thing she asked was if I'm a farmer. Said her friend had told her that I needed help.\"";
+ next;
+
+ mes "[Farmer Hinnak]";
+ mes "\"I show her what the problem is, and she tells me to go inside and wait.\"";
+ next;
+
+ mes "[Farmer Hinnak]";
+ mes "\"Hinnak drains his beer in one long sip, then hesitates.";
+ next;
+
+ mes "[Farmer Hinnak]";
+ mes "\"So I go inside. I'm barely in when it starts raining outside, pouring cats and mouboos!\"";
+ next;
+
+ mes "[Farmer Hinnak]";
+ mes "\"Not so weird, perhaps, except that it was been bright and sunny just a second before! So I rush out, my wife telling me to leave the witch alone, and I see her standing there in the middle of the rain...\"";
+ next;
+
+ mes "[Farmer Hinnak]";
+ mes "\"None of the raindrops touched her, as if they was afraid!\"";
+ next;
+
+ mes "[Farmer Hinnak]";
+ mes "\"Then she yells out some gobbledygook word, and out of the ground there comes a swarm of maggots, crawling and digging and climbing over each other's backs...\"";
+ next;
+
+ mes "[Farmer Hinnak]";
+ mes "\"And then she turns to me! Seeing her stare, for a moment there I think that she'll turn me into a pinkie, for sure...\"";
+ next;
+
+ mes "[Farmer Hinnak]";
+ mes "\"But all she says is, 'if you'd stayed inside, you wouldn't be wet now'.\"";
+ next;
+
+ menu
+ "Hahaha!", L_Sagatha_hahaha,
+ "Whoah, scary...", L_Sagatha_scary,
+ "What was that gobbledygook word?", L_Sagatha_word,
+ "I better go now.", -;
+ goto L_Bye;
+
+L_Sagatha_hahaha:
+ mes "[Farmer Hinnak]";
+ mes "\"Yeah, funny now... But you should've seen that stare! Ah, well, never mind.\"";
+ close;
+
+L_Sagatha_scary:
+ mes "[Farmer Hinnak]";
+ mes "\"Yeah, you could say that...\"";
+ mes "He stares into his empty beer jug, as if wishing it weren't empty yet.";
+ close;
+
+L_Sagatha_word:
+ mes "[Farmer Hinnak]";
+ mes "\"Oh, I can't be sure... but something like '" + getspellinvocation("summon-maggots") + "', I think.\"";
+ close;
+
+L_NoBeer:
+ mes "[Farmer Hinnak]";
+ mes "\"Ah... no beer? Oh well.\"";
+ close;
+
+L_Bye:
+ mes "[Farmer Hinnak]";
+ mes "\"Bye!\"";
+ close;
+
+L_NohMask:
+ menu
+ "Did you see anyone in a mask come by here at night?", L_NohMask_Mask,
+ "Did you see anyone with a large satchel come by here at night?", L_NohMask_Satchel,
+ "Hello", L_No_NohMask;
+ close;
+
+L_NohMask_Mask:
+ mes "[Farmer Hinnak]";
+ mes "\"No. It tends to be too dark to see a mask.\"";
+ close;
+
+L_NohMask_Satchel:
+ mes "[Farmer Hinnak]";
+ mes "\"Yes, I saw someone with a large sack on their back go to the mining camp.\"";
+ close;
+}
generated by cgit v1.2.3-70-g09d2 (git 2.46.0) at 2024-11-02 16:40:44 +0000